delphi - カスタム スタイル (デルファイ) でキャンバスに線を引く

Question

キャンバスにいくつかの線を描く必要がありますが、カスタムスタイルを使用する必要があり、ソリッド、ドットなどの標準スタイルはありません...

たとえば、「__ . __ . _ 」または「 . _ . _ . _ . _」のように線を引く必要があります。私の行はすべてダッシュとドットの組み合わせであり、ダッシュの長さとダッシュ、ドットの幅も設定する必要があります。

GDI+や他の外部ライブラリを使いたくない...

それを行う簡単な方法はありますか？

Answer 1

プレーンな GDI でこれを行うことができます。

procedure TForm1.FormPaint(Sender: TObject);
const
  pattern: array[0..3] of cardinal = (10, 1, 1, 1);
var
  lb: TLogBrush;
  pen, oldpen: HPEN;
begin
  lb.lbStyle := BS_SOLID;
  lb.lbColor := RGB(255, 0, 0);
  pen := ExtCreatePen(PS_COSMETIC or PS_USERSTYLE, 1, lb, length(pattern), @pattern);
  if pen <> 0 then
    try
      oldpen := SelectObject(Canvas.Handle, pen);
      Canvas.MoveTo(0, 0);
      Canvas.LineTo(ClientWidth, ClientHeight);
      SelectObject(Canvas.Handle, oldpen);
    finally
      DeleteObject(pen);
    end;
end;

Answer 2

LineDDA APIを使用することもできます。確かにペンのスタイリング (Andreas Rejbrand のアドバイスによる) の方がはるかに高速ですが、LineDDA を使用すると、線の一部を異なる色で描画できます。

var
  DottedLineDrawCounter: Integer;

procedure DDAProc(AX, AY: Integer; ACanvas: TCanvas); stdcall;
begin
  if DottedLineDrawCounter mod 4 = 0 then
    ACanvas.Pixels[AX, AY] := clRed
  else
    ACanvas.Pixels[AX, AY] := clBlack;
  Inc(DottedLineDrawCounter);
end;

...
begin
  // Usage
  DottedLineDrawCounter := 0;
  LineDDA(X1, Y1, X2, Y2, @DDAProc, LPARAM(Canvas));
end;