7

ボタンを押すと、散布図を作成し、値および値としてSheet 1使用する散布図を作成しようとしています。A2:A11xB2:B11y

下部のコードを使用すると、値に基づいて散布図を作成できます(ここA1:B3から取得)。近いですが、私が探しているものとはまったく異なります。ニーズに合わせてこれを微調整するにはどうすればよいですか?

設定したので、必要な値に基づいてグラフが作成されましたが、オブジェクトとして表示することはできませんSheet 1。どうすればいいですか？.Location xlLocationAsObject動作しないようです。

Private Sub chartButton_Click()
    ActiveWorkbook.Charts.Add
    With ActiveWorkbook.ActiveChart
        'Data?
        .ChartType = xlXYScatter
        .SeriesCollection.NewSeries
        .SeriesCollection(1).Name = "=""Scatter Chart"""
        .SeriesCollection(1).XValues = "=Sheet1!$A$2:$A$11"
        .SeriesCollection(1).Values = "=Sheet1!$B$2:$B$11"

        'Location
        'DON'T KNOW WHAT TO PUT HERE
        '.location xlLocationAsObject doesn't work!

        'Titles
        .HasTitle = True
        .ChartTitle.Characters.Text = "Scatter Chart"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "X values"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Y values"
        .Axes(xlCategory).HasMajorGridlines = True

        'Formatting
        .Axes(xlCategory).HasMinorGridlines = False
        .Axes(xlValue).HasMajorGridlines = True
        .Axes(xlValue).HasMinorGridlines = False
        .HasLegend = False

    End With
End Sub
4

2 に答える 2

8

書かれたコードは、グラフとしてでChart Sheetはなく、としてグラフを追加しますWorksheet

これを試して：

交換

ActiveWorkbook.Charts.Add
With ActiveWorkbook.ActiveChart

と

Dim sh As Worksheet
Dim chrt As Chart

Set sh = ActiveWorkbook.Worksheets("Sheet1")
Set chrt = sh.Shapes.AddChart.Chart
With chrt

次に、その位置とサイズを次のように制御できます

    .ChartArea.Left
    .ChartArea.Top 
    .ChartArea.Height
    .ChartArea.Width
于 2012-12-10T04:21:36.450 に答える