3

私はこのようなものを実装しようとしています：

mymin (x:[]) = x
mymin (x:y:xs) = mymin ((if x < y then x else y):xs)

mysort [] = []
mysort (x) = mymin x (mysort othervalues)

私はこのコードが間違っていることを知っていますが、それはただの考えです。残りの値を、再帰を返す最小値と連結するにはどうすればよいですか。入力は次のようになります

mysort [7,9,3,7,1,2]

[1,**7,9,3,7,2**]
[1,2,**7,9,3,7**]
[1,2,3,**7,9,7**]
[1,2,3,7,**7,9**]
[1,2,3,7,7,**9**]
[1,2,3,7,7,9]
4

3 に答える 3

6

選択ソートを実装しようとしていると思います。

myminリストの残りの要素とともに最小要素を返す方がよいでしょう。

mymin :: Ord a => [a] -> (a,[a])
mymin [x] = (x,[])
mymin (x:xs) = let (min,rest) = mymin xs
    in if x < min then (x,min:rest) else (min,x:rest)

mysort :: Ord a => [a] -> [a]
mysort [] = []
mysort xs = let (min,rest) = mymin xs
    in min:mysort rest
于 2012-12-10T08:55:17.120 に答える
2

リストから分の最初の出現を削除し、それを残りの前に連結する必要があります

mymin :: (Ord a) => [a] -> a
mymin [x] = x 
mymin (x:y:xs) | x < y     = mymin (x:xs)
               | otherwise = mymin (y:xs)

myremove :: (Eq a) => a -> [a] -> [a] 
myremove x []  = [] 
myremove x (y:ys) | x == y    = ys
                  | otherwise = y: myremove x ys 

mysort :: (Ord a) => [a] -> [a] 
mysort []  = [] 
mysort [x] = [x] 
mysort xs  = x : mysort (myremove x xs) where x = mymin xs
于 2012-12-10T09:48:05.510 に答える
0

Satvikの答えに基づいて、次のように書くことで明示的な再帰を避けることができmyminます

mymin :: Ord a => [a] -> (a, [a])
mymin (x : xs) = foldr f (x, []) xs where
  f z (y, ys) = if y < z then (y, z : ys) else (z, y : ys)
于 2012-12-11T07:53:07.820 に答える