1

XSLT 1.0 で解析しようとしている Javascript を含む HTML ページがあります。Javascript 内の URL を変更して、相対パスではなく絶対パスにしたいと考えています。

Javascript コードは大まかに次のようになります。

<html>
    <head>
        <script>
            function login() {
                window.location = '{@myBase}/myloginpage';
            }
        </script>
    </head>

    <body>
     ...
    </body>
</html>

「{@myBase}」を自分のドメインに置き換えたいです。私はコースから大きく外れていると感じています。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   xmlns:proxy="java:senselogic.sitevision.portlet.proxy.web.ProxyFunctions" 
   extension-element-prefixes="proxy">


   <xsl:import href="template.xsl"/>

    <xsl:template match="//script/text()">
        <xsl:variable name="mypath">
          <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text"><xsl:value-of select="{@myBase}"/></xsl:with-param>
            <xsl:with-param name="replace">{@myBase}</xsl:with-param>
            <xsl:with-param name="by">http://www.mydomain.com</xsl:with-param>
          </xsl:call-template>
        </xsl:variable>
    </xsl:template>    



    <xsl:template name="string-replace-all">
      <xsl:param name="text" />
      <xsl:param name="replace" />
      <xsl:param name="by" />
      <xsl:choose>
        <xsl:when test="contains($text, $replace)">
          <xsl:value-of select="substring-before($text,$replace)" />
          <xsl:value-of select="$by" />
          <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text"
            select="substring-after($text,$replace)" />
            <xsl:with-param name="replace" select="$replace" />
            <xsl:with-param name="by" select="$by" />
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$text" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:template>    
</xsl:stylesheet>
4

1 に答える 1

2

実際、あなたはそれほど遠くありません。

まず、呼び出しテンプレート<xsl:variable name="mypath">の結果を保持する変数を定義していますが、実際には何もしていません。変数宣言でラップする必要はまったくないと思います。

次に、テキストパラメータに正しい値を渡していません。これを行う代わりに

<xsl:with-param name="text"><xsl:value-of select="{@myBase}"/></xsl:with-param>

これを行う

<xsl:with-param name="text"><xsl:value-of select="."/></xsl:with-param>

または、さらに良いことに、これは次のとおりです。

<xsl:with-param name="text" select="."/>

このXSLTを試してください

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:proxy="java:senselogic.sitevision.portlet.proxy.web.ProxyFunctions" extension-element-prefixes="proxy">
    <xsl:param name="domain" select="'http://www.mydomain.com'"/>

    <xsl:template match="//script/text()">
        <xsl:call-template name="string-replace-all">
            <xsl:with-param name="text" select="."/>
            <xsl:with-param name="replace" select="'{@myBase}'" />
            <xsl:with-param name="by" select="$domain"/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template name="string-replace-all">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="by"/>
        <xsl:choose>
            <xsl:when test="contains($text, $replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$by"/>
                <xsl:call-template name="string-replace-all">
                    <xsl:with-param name="text" select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="by" select="$by"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

（ドメインもパラメーターに設定したことに注意してください）

XHTML に適用すると、次のように出力されます。

<html>
<head>
<META http-equiv="Content-Type" content="text/html">
<script>
            function login() {
                window.location = 'http://www.mydomain.com/myloginpage';
            }
        </script></head>
<body>
     ...
    </body>
</html>
于 2012-12-11T11:07:32.987 に答える