perl - MojoX::Sessions の Cookie の有効期限を設定するにはどうすればよいですか?

Question

expires()またはに与える有効期限の値に関係なくexpires_delta()、Cookie の有効期限は常に 1 時間です。セッションと Cookie の有効期限が一致するように変更するにはどうすればよいですか?

Answer 1

私は vti の作品が好きですが、そのディストリビューションは時代遅れに見え、過去に置き換えられました。今日、セッションの有効期限を設定する標準的な方法はMojolicious::Sessionsで説明されています:

default_expiration

my $time  = $sessions->default_expiration;
$sessions = $sessions->default_expiration(3600);

セッションが期限切れになるまでのデフォルトの時間 (秒単位) 。デフォルトは3600です。有効期限のタイムアウトは、リクエストごとに更新されます。値を 0 に設定すると、ブラウザ ウィンドウが閉じられるまでセッションが持続されますが、これにはセキュリティ上の影響があります。さらに制御するには、expirationとexpiresセッションの値を使用することもできます。

# Expiration date in epoch seconds from now (persists between requests)
$c->session(expiration => 604800);

# Expiration date as absolute epoch time (only valid for one request)
$c->session(expires => time + 604800);

# Delete whole session by setting an expiration date in the past
$c->session(expires => 1);

動作することを確認するために、小さなテスト スクリプトを作成しました。

#!/usr/bin/env perl

use Mojolicious::Lite;
use Time::Local 'timegm';

# set some session variable
get '/test' => sub {
    my $self = shift;
    $self->session(
        expires => timegm(0, 0, 0, 4, 4, 142), # star wars day '42
        foo     => 42,
    );
    $self->render_text('foo is set');
};

use Test::More;
use Test::Mojo;
use Mojo::Cookie::Response;
my $t = Test::Mojo->new;

$t->get_ok('/test')->status_is(200)->content_is('foo is set');
my $cookies = Mojo::Cookie::Response->parse($t->tx->res->headers->set_cookie);
is $cookies->[0]->expires, 'Sun, 04 May 2042 00:00:00 GMT', 'right expire time';

done_testing;

出力：

ok 1 - get /test
ok 2 - 200 OK
ok 3 - exact match for content
ok 4 - right expire time
1..4