0

私はXSLTの初心者であり、XSLTを使用してJavaを介してXMLをXMLに変換します。

ソースXML：

<Response>
    <Data>
        <Book name="A" value="1"/>
        <Book name="B" value="2"/>
        <Book name="C" value="1"/>
    </Data>
    <Result>
        <Prices>
            <Price type="A" value="100"/>
            <Price type="B" value="60"/>
            <Price type="C" value="40"/>
        </Prices>
    </Result>
</Response>

XSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/">
        <xsl:element name="Books">
            <xsl:variable name="BookType" select="//@type" />
            <xsl:attribute name="Total">
                <xsl:value-of select="sum(//Price[@type=$BookType]/@value)"/>
            </xsl:attribute>
        </xsl:element>
    </xsl:template>
</xsl:stylesheet>

出力XML：

<Books Total="200"/>

期待される出力XML：

<Books Total="260"/>

ソースXMLでは、本とその価格を受け取りませんが、関連性はありません。

<Price>タグは1冊の本の価格を示します。すべての本の合計金額を以下のように計算する必要があります

Price of one book x no of books
For A : 100 x 1 = 100
For B : 60 x 2  = 120
For C : 40 x 1  = 040
------------------------
Total Price is  = 260

助けてください。

4

1 に答える 1

1

最も簡単なアプローチは、「price * qty」値を含む変数に一時的な構造を構築し、exslt:node-set拡張関数を使用してそれらの値を合計することです。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:exslt="http://exslt.org/common"
                exclude-result-prefixes="exslt">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="/">
    <xsl:variable name="subTotals">
      <xsl:for-each select="/Response/Data/Book">
        <totalPrice>
          <xsl:value-of select="@value *
            /Response/Result/Prices/Price[@type = current()/@name]/@value" />
        </totalPrice>
      </xsl:for-each>
    </xsl:variable>
    <Books Total="{sum(exslt:node-set($subTotals)/totalPrice)}" />
  </xsl:template>
</xsl:stylesheet>

拡張関数を使用せずに純粋なXSLT1.0でこれを行うことは可能ですが、それはかなり面倒であり、テンプレートのチェーンにアキュムレータパラメーターを渡す必要があります。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="/">
    <Books>
      <xsl:apply-templates select="/Response/Data/Book[1]" />
    </Books>
  </xsl:template>

  <xsl:template match="Book">
    <xsl:param name="runningTotal" select="0" />
    <xsl:variable name="thisBookTotal" select="@value *
       /Response/Result/Prices/Price[@type = current()/@name]/@value" />
    <xsl:choose>
      <xsl:when test="following-sibling::Book">
        <!-- There are more books, process the next one, passing an updated
             running total -->
        <xsl:apply-templates select="following-sibling::Book[1]">
          <xsl:with-param name="runningTotal" select="$runningTotal + $thisBookTotal" />
        </xsl:apply-templates>
      </xsl:when>
      <xsl:otherwise>
        <!-- There are no more books, produce the final total -->
        <xsl:attribute name="Total">
          <xsl:value-of select="$runningTotal + $thisBookTotal" />
        </xsl:attribute>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>
于 2012-12-13T12:36:35.417 に答える