3

FortranでHDF5テーブルを使用したいのですが、問題が発生しています。例は役に立ちますが、Cの例のみが提供されています。

私の問題の一部は、必要なオフセットとサイズをどのように処理するかです。gfortranを使用すると、 sizeofとlocを使用できる場合がありますが、これらはgfortran固有の拡張機能です。新しいバージョンのFortranにはc_locとc_sizeofがあり、これが役立つ可能性がありますが、おそらくそれらはc変数でのみ機能しますか？

また、chunk_sizeがどうあるべきかわかりません。

FWIW、以下の醜いコードはlocとsizeofを使用しています。コンパイルして実行しますが、エラーが発生します（hdf5ファイルには何も入れられません）。

 size:                    8
 offsets:                    0                    4
 types:           0           0
 initialized
 file open
HDF5-DIAG: Error detected in HDF5 (1.8.8) thread 140636908803840:
  #000: ../../../src/H5Tcompound.c line 370 in H5Tinsert(): not a datatype
    major: Invalid arguments to routine
    minor: Inappropriate type
 table created

したがって、オフセットは意味がありますが、タイプは実際には意味がありません。

どんな助けでもいただければ幸いです。ありがとう。

module tdef
  type blarg
    integer :: arg
    real    :: blah
  end type
end

PROGRAM H5_TABLE

  use tdef
  USE HDF5
  use h5lt
  use h5tb

  IMPLICIT NONE

  INTEGER(HID_T) :: file_id
  INTEGER     ::   error
  integer(HSIZE_T) :: nfields, nrecords
  integer(SIZE_T)  :: type_size
  type(blarg) :: test
  character(len=4), dimension(2) :: field_names = (/' arg', 'blah'/)
  integer(SIZE_T), dimension(2) :: field_offset
  integer(HID_T), dimension(2) :: field_types
  integer(HSIZE_T) ::  chunk_size = 1
  integer :: compress = 0

  nfields  = 2
  nrecords = 2

  type_size = sizeof(test)
  print *, "size:", type_size

  field_offset(1) = loc(test%arg) - loc(test)
  field_offset(2) = loc(test%blah) - loc(test)
  print *, "offsets:", field_offset

  field_types(1) = H5T_NATIVE_INTEGER
  field_types(2) = H5T_NATIVE_REAL
  print *, "types:", field_types

  CALL h5open_f(error)
  print *, "initialized"

  CALL h5fcreate_f("cpt.h5", H5F_ACC_TRUNC_F, file_id, error)
  print *, "file open"

  call h5tbmake_table_f('Table Title', file_id, "Steps", nfields, &
            nrecords, type_size, field_names, field_offset, &
            field_types, chunk_size, compress, error) 
  print *, "table created"

  CALL h5fclose_f(file_id, error)

  CALL h5close_f(error)

END PROGRAM H5_TABLE
4

1 に答える 1

3

これは非常に単純な問題であることがわかります。

H5T_NATIVE_INTEGER と H5T_NATIVE_REAL を使用した後、h5open_f を呼び出します。ただし、h5open_f が呼び出されるまで、これらの 2 つには適切な値が割り当てられません。最初に h5open_f を呼び出すと、問題が解決します。

于 2012-12-17T19:22:01.977 に答える