2

私は xslt が初めてで、何度も試みた後、以下を解決できません。

変更できないデータを含む xml データ ファイルがあります。たとえば、以下の単純な xml ファイルは次のとおりです。

<?xml version="1.0" encoding="UTF-8"?>
<sales>
    <sale>
        <year>2012</year>
        <amount>200</amount>
    </sale>
    <sale>
        <year>2012</year>
        <amount>180</amount>
    </sale>
    <sale>
        <year>2010</year>
        <amount>120</amount>
    </sale>
</sales>

販売データを年ごとにグループ化し、金額を合計して、年間の合計金額を取得したいのですが、これで問題ありません。

xml ファイルには 2012 年と 2010 年のデータがありますが、2011 年のデータはありません。

2011 年の出力を 0 にしたいので、2010 年、2011 年、および 2012 年すべての出力があります。

実際には xls を使用してグラフを作成しますが、この単純な例では出力として html を使用しています。Altova XMLSpy を使用して xls をテストし、結果の html ドキュメントを確認しています。

これは、HTML でデータをグループ化して表示するために作成した単純な xls コードです。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/">
  <html>
  <body>
  <table border="1">
    <tr>
      <th>Year</th>
      <th>Amount</th>
    </tr>
    <xsl:for-each-group select="sales/sale" group-by="year">
      <xsl:sort select="year"/>
      <tr>
        <td><xsl:value-of select="year"/></td>
        <td><xsl:value-of select="sum(current-group()/amount)"/></td>
      </tr>
    </xsl:for-each-group>
  </table>
  </body>
  </html>
</xsl:template>

</xsl:stylesheet>

xml ファイルに対して Altova XMLSpy を使用してこれを実行すると、ブラウザー ウィンドウに以下のように表示されます。3 行の小さなテーブル、タイトル付きのヘッダー、2 行のデータ、1 つは 2012 年用、もう 1 つは 2010 年用です。スタックオーバーフローの新しいユーザーとして画像をまだ使用できないため、表示できるソース HTML コードを次に示します。ブラウザで。

<html>
    <body>
        <table border="1">
            <tr>
                <th>Year</th>
                <th>Amount</th>
            </tr>
            <tr>
                <td>2010</td>
                <td>120</td>
            </tr>
            <tr>
                <td>2012</td>
                <td>380</td>
            </tr>
        </table>
    </body>
</html>

出力に 2010 年、2011 年、2012 年の範囲のデータが表示されるように、xls を使用して金額が 0 の 2011 年の行を作成できますか?

xls で年をハードコーディングできないことに注意してください。欠落している年を導き出す必要があります。

通常、ソース xml ファイルに必要なすべてのデータが含まれていることを確認しますが、この場合は不可能です。

どんな助けにも感謝します。

敬具

セル

4

2 に答える 2

3

ここに解決策があります：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:output method="html" indent="yes"/>

<xsl:key name="sale-by-year" match="sale" use="xs:integer(year)"/>

<xsl:template match="/">
  <html>
  <body>
  <table border="1">
    <tr>
      <th>Year</th>
      <th>Amount</th>
    </tr>
    <xsl:variable name="doc" select="/"/>
    <xsl:for-each select="min(sales/sale/year/xs:integer(.)) to max(sales/sale/year/xs:integer(.))">
      <xsl:variable name="sales-of-year" select="key('sale-by-year', ., $doc)"/>
      <tr>
        <td>
          <xsl:value-of select="."/>
        </td>
        <td>
          <!--  <xsl:value-of select="if ($sales-of-year) then sum($sales-of-year/amount) else 0"/> -->
          <xsl:value-of select="sum($sales-of-year/amount)"/>
        </td>
       </tr>
     </xsl:for-each>

  </table>
  </body>
  </html>
</xsl:template>

</xsl:stylesheet>
于 2012-12-16T10:13:19.373 に答える
0

I. 少し短い XSLT 2.0 :

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kSalesByYear" match="sale" use="year"/>
 <xsl:variable name="vDoc" select="/"/>

 <xsl:template match="/">
  <html>
    <body>
          <table border="1">
            <tr>
              <th>Year</th>
              <th>Amount</th>
            </tr>
        <xsl:for-each select=
         "min(/*/*/year/xs:integer(.)) to max(/*/*/year/xs:integer(.))">
         <tr>
           <td><xsl:sequence select="."/></td>
           <td><xsl:sequence select=
            "sum(key('kSalesByYear',string(.),$vDoc)/amount)"/></td>
         </tr>
        </xsl:for-each>
      </table>
    </body>
   </html>
 </xsl:template>
</xsl:stylesheet>

Ⅱ．XSLT 1.0 ソリューション:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kSalesByYear" match="sale" use="year"/>
 <xsl:variable name="vDoc" select="/"/>

 <xsl:variable name="vMinMax">
  <xsl:for-each select="/*/*/year">
   <xsl:sort/>
   <xsl:if test="position()=1">
    <xsl:value-of select="."/>
   </xsl:if>
   <xsl:if test="position()=last()">
    <xsl:value-of select="concat('|',.)"/>
   </xsl:if>
  </xsl:for-each>
 </xsl:variable>

 <xsl:variable name="vMin" select="substring-before($vMinMax, '|')"/>
 <xsl:variable name="vMax" select="substring-after($vMinMax, '|')"/>

 <xsl:template match="/">
  <html>
    <body>
          <table border="1">
            <tr>
              <th>Year</th>
              <th>Amount</th>
            </tr>
        <xsl:for-each select=
         "(document('')//node()|document('')//@*|document('')//namespace::*)
           [not(position() > $vMax - $vMin +1)]
         ">
         <xsl:variable name="vYear" select="$vMin + position() -1"/>

         <xsl:for-each select="$vDoc">
             <tr>
               <td><xsl:value-of select="$vYear"/></td>
               <td><xsl:value-of select=
                "sum(key('kSalesByYear',$vYear)/amount)"/></td>
             </tr>
         </xsl:for-each>
        </xsl:for-each>
      </table>
    </body>
   </html>
 </xsl:template>
</xsl:stylesheet>

上記の 2 つの変換のいずれかが、提供された XML ドキュメントに適用される場合:

<sales>
    <sale>
        <year>2012</year>
        <amount>200</amount>
    </sale>
    <sale>
        <year>2012</year>
        <amount>180</amount>
    </sale>
    <sale>
        <year>2010</year>
        <amount>120</amount>
    </sale>
</sales>

必要な正しい結果が生成されます。

<html>
   <body>
      <table border="1">
         <tr>
            <th>Year</th>
            <th>Amount</th>
         </tr>
         <tr>
            <td>2010</td>
            <td>120</td>
         </tr>
         <tr>
            <td>2011</td>
            <td>0</td>
         </tr>
         <tr>
            <td>2012</td>
            <td>380</td>
         </tr>
      </table>
   </body>
</html>
于 2012-12-16T19:51:04.140 に答える