3

サイズNのラテン方格を見つけるためにPrologでプログラムを書こうとしています。

私は今これを持っています：

delete(X, [X|T], T).
delete(X, [H|T], [H|S]) :-
   delete(X, T, S).

permutation([], []).
permutation([H|T], R) :-
   permutation(T, X),
   delete(H, R, X).

latinSqaure([_]).
latinSquare([A,B|T], N) :-
   permutation(A,B),
   isSafe(A,B),
   latinSquare([B|T]).

isSafe([], []).
isSafe([H1|T1], [H2|T2]) :- 
   H1 =\= H2, 
   isSafe(T1, T2).
4

3 に答える 3

2

SWI-Prologライブラリの使用：

:- module(latin_square, [latin_square/2]).
:- use_module(library(clpfd), [transpose/2]).

latin_square(N, S) :-
    numlist(1, N, Row),
    length(Rows, N),
    maplist(copy_term(Row), Rows),
    maplist(permutation, Rows, S),
    transpose(S, T),
    maplist(valid, T).

valid([X|T]) :-
    memberchk(X, T), !, fail.
valid([_|T]) :- valid(T).
valid([_]).

テスト：

?- aggregate(count,S^latin_square(4,S),C).
C = 576.

コードを編集し、タイプミスを削除して修正すると、ジェネレーターではなくベリファイアになりますが、（削除されたコメントのssBarBeeで示されているように）隣接していない行でテストが欠落しているため、欠陥があります。ここで修正されたコード

delete(X, [X|T], T).
delete(X, [H|T], [H|S]) :-
    delete(X, T, S).

permutation([], []).
permutation([H|T], R):-
    permutation(T, X),
    delete(H, R, X).

latinSquare([_]).
latinSquare([A,B|T]) :-
    permutation(A,B),
    isSafe(A,B),
    latinSquare([B|T]).

isSafe([], []).
isSafe([H1|T1], [H2|T2]) :-
    H1 =\= H2,
    isSafe(T1, T2).

といくつかのテスト

?- latinSquare([[1,2,3],[2,3,1],[3,2,1]]).
false.

?- latinSquare([[1,2,3],[2,3,1],[3,1,2]]).
true .

?- latinSquare([[1,2,3],[2,3,1],[1,2,3]]).
true .

それが間違っている最後のテストに注意してください、false代わりに与えるべきです。

于 2012-12-16T23:03:55.133 に答える
1

私はより良い解決策を持っています.@CapelliCコードは、Nの長さが5を超える正方形に対して非常に長い時間がかかります.

:- use_module(library(clpfd)).

make_square(0,_,[]) :- !.
make_square(I,N,[Row|Rest]) :-
   length(Row,N),
   I1 is I - 1,
   make_square(I1,N,Rest).

 all_different_in_row([]) :- !.
 all_different_in_row([Row|Rest]) :-
    all_different(Row),
    all_different_in_row(Rest).


all_different_in_column(Square) :-
   transpose(Square,TSquare),
   all_different_in_row(TSquare).   

all_different_in_column1([[]|_]) :- !.
all_different_in_column1(Square) :-
   maplist(column,Square,Column,Rest),
   all_different(Column),
   all_different_in_column1(Rest).


   latin_square(N,Square) :-
   make_square(N,N,Square),
   append(Square,AllVars),
   AllVars ins 1..N,
   all_different_in_row(Square),
   all_different_in_column(Square),
   labeling([ff],AllVars).
于 2016-01-20T10:03:18.763 に答える