12

プロトコル バッファを使用するプロジェクトをビルドするための autoconf および automake ルールの良い例を探しています。ビルド プロセスにプロトコルを追加する最良の方法はありますか?

4

2 に答える 2

17

configure.ac

protobuf ライブラリに関する限り、それは を使用しているため、マクロpkg-configを使用して参照するのがおそらく最善です。PKG_CHECK_MODULES

PKG_CHECK_MODULES(PROTOBUF, protobuf >= 2.4.0)
AC_SUBST(PROTOBUF_LIBS)
AC_SUBST(PROTOBUF_CFLAGS)
AC_SUBST(PROTOBUF_VERSION)

protocパス内のコマンドを確認します。パスにあることを確認するための非常に基本的なチェックは次のとおりです。

AC_CHECK_PROG([PROTOC], [protoc], [protoc])
AS_IF([test "x${PROTOC}" == "x"],
    [AC_MSG_ERROR([ProtoBuf compiler "protoc" not found.])])

protocまたは、ユーザーが--with-protoc=/path/to/protoc環境変数を使用して別の変数を指定できるようにしPROTOCます。

# ProtoBuf compiler.
# First, specify with --with-protoc=/path/of/protoc.
# Or, specify with env variable PROTOC.
# If neither of the above, find it in the path.
#AC_MSG_CHECKING([for ProtoBuf compiler protoc])
AC_ARG_WITH([protoc],
    [AS_HELP_STRING([--with-protoc=/path/of/protoc],
        [Location of the protocol buffers compiler protoc. Defaults to looking on path.])],
    [PROTOC="$withval"],
    [ AS_IF([test "x${PROTOC}" == "x"],
        [AC_PATH_PROG([PROTOC], [protoc], [no])])
    ]
)
#AC_MSG_RESULT([${PROTOC}])
AS_IF([test "${PROTOC}" == "no"], [AC_MSG_ERROR([ProtoBuf compiler "protoc" not found.])])

Makefile.am

protoファイルを構築するルールを追加します。

%.pb.cc %.pb.h: %.proto
    $(PROTOC) --proto_path=$(srcdir) --cpp_out=$(builddir) $^

でprotobufソースファイルを指定しますdist_noinst_DATA。.tar.gzこれは、 で作成されたソース配布ファイルに確実にバンドルされるようにするために必要make distです。

dist_noinst_DATA = whatever.proto

@builddir@(注: autoconf/automake の新しいバージョンでは、代わりに使用する必要がある場合があります$(builddir)。)

生成されたファイルをnodist_プレフィックスと$(builddir)パスで指定します。

nodist_myprog_SOURCES = $(builddir)/whatever.pb.cc $(builddir)/whatever.pb.h

そしてそれらをきれいにするためにmake clean：

MOSTLYCLEANFILES = whatever.pb.cc whatever.pb.h

BUILT_SOURCESビルドされたヘッダー ファイルの依存関係を処理するために使用します。

BUILT_SOURCES = whatever.pb.h

コンパイラ フラグは、(VPATH ビルドで機能するために) ヘッダー ファイルを見つけるためにビルド ディレクトリを参照する必要がある場合があります。

AM_CPPFLAGS += -I$(builddir)
于 2013-08-20T07:09:25.983 に答える
7

これはうまくいくようです：

configure.ac:

AC_ARG_WITH([protobuf-libdir],
    [AS_HELP_STRING([--with-protobuf-libdir=LIB_DIR],
        [location of the protocol buffers libraries, defaults to /usr/lib])],
    [PROTOBUF_LIBDIR="$withval"],
    [PROTOBUF_LIBDIR='/usr/lib'])
AC_SUBST([PROTOBUF_LIBDIR])

LDFLAGS="$LDFLAGS -L$PROTOBUF_LIBDIR"

AC_CHECK_LIB([protobuf], [main], [], [AC_MSG_ERROR([cannot find protobuf library])])

AC_ARG_WITH([protoc],
    [AS_HELP_STRING([--with-protoc=PATH],
        [location of the protoc protocol buffer compiler binary, defaults to protoc])],
    [PROTOC="$withval"],
    [PROTOC='protoc'])
AC_SUBST([PROTOC])

Makefile.am:

%.pb.cc %.pb.h: %.proto
    $(PROTOC) --proto_path=$(dir $^) --cpp_out=$(dir $^) $^

次に、.pb.cc ファイルを SOURCES に追加します。

于 2012-12-19T00:31:59.993 に答える