4 
<t>
  <rendition xml:id="b">color: blue</rendition>
  <rendition xml:id="r">color: red</rendition>

  <tagUsage gi="p" render="b" />
  <tagUsage gi="emph" render="r" />
</t>

tagUsage 要素の @gi に基づいてレンディション要素に XSL 1.0 キーを作成し、rendition/@xml:id を tagUsage/@render に結合するにはどうすればよいですか? 何かのようなもの

<xsl:key name="rendition-by-tagName" 
         match="rendition" 
         use="//tagUsage[@xml:id of rendition = @render of tagUsage]/@gi" />

そのため、"p" を指定すると、キーは blue を返しrenditionます。「emph」を指定すると、キーは red を返しますrendition。

4

2 に答える 2

4

使用:

 <xsl:key name="kRendByUsageGi" match="rendition"
  use="../tagUsage[@render=current()/@xml:id]/@gi"/>

完全な検証は次のとおりです。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:key name="kRendByUsageGi" match="rendition"
  use="../tagUsage[@render=current()/@xml:id]/@gi"/>

 <xsl:template match="/">
  <xsl:copy-of select="key('kRendByUsageGi', 'p')/text()"/>
========
  <xsl:copy-of select="key('kRendByUsageGi', 'emph')/text()"/>
 </xsl:template>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、次のようになります。

<t>
  <rendition xml:id="b">color: blue</rendition>
  <rendition xml:id="r">color: red</rendition>

  <tagUsage gi="p" render="b" />
  <tagUsage gi="emph" render="r" />
</t>

必要な正しい結果が生成されます。

color: blue
========
  color: red
于 2012-12-21T04:33:59.417 に答える
1

2 番目の key() を使用する次のコードは xsltproc で動作することがわかったので、それがターゲット プロセッサである場合、これが役立つはずです。ただし、サクソンでは機能しません。 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:key name='kTagUsage' match='tagUsage' use='@render'/>
  <xsl:key name="kRendByUsageGi" match="rendition"
    use="key('kTagUsage', @xml:id)/@gi"/>


  <xsl:template match="/">
    <xsl:copy-of select="key('kRendByUsageGi', 'p')/text()"/>
    ========
    <xsl:copy-of select="key('kRendByUsageGi', 'emph')/text()"/>
  </xsl:template>
</xsl:stylesheet>
于 2012-12-28T16:40:48.450 に答える