delphi - Delphiのダブルからバイト配列

Question

double値をそのバイト表現に変換する簡単な方法はありますか？私は次のようなポインタを使用してみました：

var
  double_v:double;
  address:^double;
....
double_v:=100;
address:=@double_v;

しかし、私のすべての概念：アドレスから8バイトを読み取る方法、「AV」で終わります。

Answer 1

バリアントレコードを使用する

Type
  TDoubleAndBytes = Record
    case boolean of
      false : (dabDouble : Double);
      true  : (dabBytes : Array [0..7] Of Byte);
  end;

double値をdabDoubleに割り当て、dabBytesを介してバイトを読み取ります

var
  myVar : TDoubleAndBytes;
  i : integer;

begin
  myVar.dabDouble := 100;
  for i:=0 to 7 do write(myVar.dabBytes[i]);

Answer 2

XE3には、単純型のレコードヘルパーがありますTDoubleHelper。

これは機能します：

var
  d : Double;
  i : Integer;
begin
  d := 100.0;
  for i := 0 to 7 do
    WriteLn(d.Bytes[i]);
end;

XE2にはTDoubleRec、高度なレコードである宣言があります。

例：

var
  dRec : TDoubleRec;
  i : Integer;
begin
  dRec := 100.0;
  for i := 0 to 7 do
    WriteLn(dRec.Bytes[i]);
end;

doubleのバイトにアクセスするためのもう1つの一般的なオプションは、typecast：を使用することです。

type
  TDoubleAsByteArr = array[0..7] of byte;
var
  d : Double;
  i : Integer;
begin
  d := 100.0;
  for i := 0 to 7 do
    WriteLn(TDoubleAsByteArr(d)[i]);
end;

Answer 3

「絶対」の使用例2つ..。

関数として使用

function GetDoubleByte(MyDouble: Double; Index: Byte): Byte;
var
  Bytes: array[0..7] of Byte absolute MyDouble;
begin
  Result := Bytes[Index];
end;



procedure TForm1.Button1Click(Sender: TObject);
var
 MyDouble:Double;
 DoubleBytes:Array[0..7] of Byte absolute MyDouble; // direct local use
begin
  MyDouble := 17.123;
  ShowMessage(IntToStr(DoubleBytes[0])); // local usage

  ShowMessage(IntToStr(GetDoubleByte(MyDouble,0))); // via function call

end;