1

ストレートXSLT1.0では、文字列変数をXPath式として使用することはできません。

しかし、可能な式がすべて「/ book / chapter/verse」や「/year/ make / model / style」のように単純である場合（子軸のみ、要素ノードのみ、述語なし）、キーを作成することは可能ですか？キー文字列はそのパスですか？何かのようなもの

<xsl:key name="elementByPath" match="*" use="path()" />

もしそうなら、あなたは持つことができます

select=key(elementByPath, $var)

ここで、$varは「/book / chapter/verse」のような文字列にすることができます。

ただし、ストレートXSLT 1.0にはpath（）関数がありません。:(

でパスを取得するのは簡単です

 <xsl:for-each select="ancestor-or-self::*">
      <xsl:text>/</xsl:text>
      <xsl:value-of select="name()"/>
 </xsl:for-each>

しかし、それはキーの@useには入りません。:(

可能な式（多くはありますが）が単純な場合に、変数XPath式で要素を選択する別の方法はありますか？

4

2 に答える 2

1

何かをすることができます：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pPath1" select="'/books/book/title'"/>
 <xsl:param name="pPath2" select="'/books/book/description'"/>

 <xsl:key name="kElemByPath" match="*"
  use="concat('/', name(ancestor-or-self::*[last()])
             ,'/', name(ancestor-or-self::*[last()-1])
             ,'/', name(ancestor-or-self::*[last()-2])
             )"/>

 <xsl:template match="/">
   <xsl:copy-of select="key('kElemByPath', $pPath1)"/>
==========&#xA;<xsl:text/>
   <xsl:copy-of select="key('kElemByPath', $pPath2)"/>
 </xsl:template>
</xsl:stylesheet>

この変換が次のXMLドキュメントに適用される場合：

<books>
    <book isbn="1590593049">
        <title>Extending Flash MX 2004</title>
        <description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
    </book>
    <book isbn="0132149184">
        <title>Java Software Solutions</title>
        <description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>
    </book>
</books>

必要な正しい結果が生成されます。

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
<description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>

「パス」内のロケーションステップの最大数がわかっている場合は、この例のようにキーを定義できます。ロケーションステップの数が少ない式は、必要な数のスラッシュで終了する必要があります。

于 2012-12-30T23:04:13.790 に答える
1

または、文字列のブルートフォースを再帰的に解析するのはどうですか？

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output omit-xml-declaration="yes" indent="yes"/>


<xsl:param name="pPath1" select="'books/book/title'"/>
<xsl:param name="pPath2" select="'books/book/description'"/>


<xsl:template match="/">
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath1" />
    </xsl:call-template>
    <xsl:text>==========&#xA;</xsl:text>
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath2" />
    </xsl:call-template>        
</xsl:template>


<xsl:template name="elementsByPath"> 
    <xsl:param name="path" />
    <xsl:choose>
        <xsl:when test="contains($path,'/')">
            <xsl:for-each select="*[name()=substring-before($path,'/')]"> 
                <xsl:call-template name="elementsByPath">
                    <xsl:with-param name="path" select="substring-after($path,'/')" />
                </xsl:call-template>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="*[name()=$path]" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="*">
    <xsl:copy-of select="." /><xsl:text>&#xA;</xsl:text>

</xsl:template>

</xsl:stylesheet>

その変換をDimitreのサンプルXMLに適用すると、正しい結果が得られます。

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.
    </description>
<description>
        Complete book full of case studies on business solutions and design concepts while building mission critical
        business applications.
    </description>

私はそれがうまくいくと思います。。。

于 2012-12-30T23:26:48.277 に答える