sas - SAS マクロを使用して Windows ディレクトリからファイル名のリストをパイプする

Question

以下のマクロを修正して、マクロ パラメータを dir コマンドの「場所」引数として受け入れるようにしようとしています。ただし、ネストされた引用符の問題により、正しく解決できません。%str(%') の使用は機能せず、何らかの理由で関数の引用も機能しません。

ファイルパスにスペースが含まれていない場合(例: C:\temp\withnospace)、中間引用符が必要ないため、マクロは正常に機能します。ただし、スペースを含むファイルパス(「C:\temp\with space\」など) でこのマクロが機能する必要があります。

助けてください！

%macro get_filenames(location)
   filename pipedir pipe   "dir &location. /b " lrecl=32767;
   data filenames;
     infile pipedir truncover;
     input line $char1000.;
   run;
%mend;

%get_filenames(C:\temp\)              /* works */
%get_filenames('C:\temp\with space')  /* doesnt work */

Answer 1

PIPEを使用せずに同じ結果を達成する別の方法を次に示します。

%macro get_filenames(location);
filename _dir_ "%bquote(&location.)";
data filenames(keep=memname);
  handle=dopen( '_dir_' );
  if handle > 0 then do;
    count=dnum(handle);
    do i=1 to count;
      memname=dread(handle,i);
      output filenames;
    end;
  end;
  rc=dclose(handle);
run;
filename _dir_ clear;
%mend;

%get_filenames(C:\temp\);           
%get_filenames(C:\temp\with space);
%get_filenames(%bquote(C:\temp\with'singlequote));

Answer 2

次のいくつかの変更を行うと、コードが機能します。

%macro get_filenames(location);  %*--(1)--*;
   filename pipedir pipe "dir ""%unquote(&location)"" /b" lrecl=32767; %*--(2)--*;
   data filenames;
     infile pipedir truncover;
     input filename $char1000.;
     put filename=;
   run;
   filename pipedir clear;  %*--(3)--*;
%mend;

%get_filenames(d:\)          
%get_filenames(d:\your dir)  %*--(4)--*;

(1)%macroセミコロンでステートメントを終了します。

(2) マクロ変数の解決を二重引用符と%unquote;で囲みます。

(3) ファイルハンドルをクリアして解放します。と

(4) 入力パラメータを一重引用符にしないでください。必要に応じて、代わりにマクロ引用符を使用してください。

Answer 3

このページの最後のサンプルに基づいて、filenameステートメントの代わりに試してください

%let filrf=pipedir;
%let rc=%sysfunc(filename(filrf,%bquote(dir "&location" /b),pipe));

引用符を使用せずにマクロを呼び出します。

%get_filenames(c:\temp\with spaces);

マクロ引用も試しましたが、うまくいきませんでした。

Answer 4

これは、Windows ベースのディレクトリ リストを sas データ セットにプルする簡単なマクロです。

%macro DirList(dir);

/* %if &SUBDIR eq %then %let subdir=/s; */ /*** &SUBDIR が定義されていません ****/
filename dirpipe pipe "dir &DIR.\*.* /s /-c";

data dir_list(label="ディレクトリ一覧 [&DIR.]" drop=re_: _line_ date time);
  形式パス
         ファイル $250。
         ModDT datetime19.
         サイズ16。
         _line_ $32000. ;

  _N_ = 1 の場合は実行します。
    re_path=prxparse("/(.+)のディレクトリ/");
    re_subd=prxparse("/(\d\d\/\d\d\/\d\d\d\d)\s+(\d\d:\d\d [A|P]M)\s+\ s+(\S.*)/");
    re_file=prxparse("/(\d\d\/\d\d\/\d\d\d\d)\s+(\d\d:\d\d [A|P]M)\s+( \d+)\s+(\S.*)/");
    re_: パスを保持します。
    終わり;

  infile dirpipe lrecl=32000; 入力; _line_ = _infile_;

  lengthn(_line_)=0 の場合は削除します。
  そうしないと
  if prxmatch(re_path, _line_) then do;
    パス = prxposn(re_path, 1, _line_);
    終わり;
  そうしないと
  if prxmatch(re_subd, _line_) then do;
    date=input(prxposn(re_subd, 1, _line_), mmddyy10.);
    time=input(prxposn(re_subd, 2, _line_), time6.);
    ModDT=dhms(日付, 0, 0, 時間);
    File=prxposn(re_subd, 3, _line_);
    サイズ = .D; /*サブディレクトリのレコードをマーク*/
    ファイルが ('.', '..') にない場合、出力します。
    終わり;
  そうしないと
  if prxmatch(re_file, _line_) then do;
    date=input(prxposn(re_file, 1, _line_), mmddyy10.);
    time=input(prxposn(re_file, 2, _line_), time6.);
    ModDT=dhms(日付, 0, 0, 時間);
    size=input(prxposn(re_file, 3, _line_), 16.);
    file=prxposn(re_file, 4, _line_);
    出力;
    終わり;
走る;
ファイル名 dirpipe クリア;
％繕う;

そして、これが彼らが呼ばれる方法です

%dirlist(c:);
%dirlist(c:\temp);

ベース ディレクトリを指定する場合、末尾のバックスラッシュがないことに注意してください。C:ありませんC:\。

Answer 5

元のマクロをこのように呼び出すとうまくいきます

%get_filenames(""C:\Program Files"")

%macroもちろん、ステートメントの最後にセミコロンを追加する必要がありました。

ディレクトリにコンマが含まれていると、悪いことが起こります。修正するには、%str()マクロを使用します

%get_filenames(%str(C:\temp\comma, fail))

Answer 6

これは、引用と引用解除の順序を解読するものです。

%let command =%unquote(%str(%')dir "&baseDir.data\*txt"%str(%'));

filename datain pipe &command;

ここで、マクロ変数 basedir にはスペースを含めることができ、ファイル名にもスペースを含めることができます。この %unquoteandの組み合わせ%str(%')は、頻繁に使用されるマクロ イディオムです。

「自分のディレクトリに一重引用符があるとどうなりますか?」

この状況を処理するには、次のようなマクロ引用関数が必要%bquote(); です。上記の例を続けると、次のようになります。

%let command =%unquote(%str(%')dir "%bquote(&baseDir.data\*txt)"%str(%'));

するべきです。

この種の質問が無限に繰り返されるのを避けるために、Ian Whitlock の論文「マクロ引用の真剣な考察」を参照してください。

他にも（たくさん）ありますが、これが最も広く引用されています。ちょっとしたメモ: Ian Whitlock によるものは、おそらく価値があります。彼は明確に書いており、SAS の問題に対する彼の理解は素晴らしいものです。

Answer 7

これは、純粋なマクロ コード バージョンです。また、ファイル (フォルダーではなく) についてのみ知りたいことを指定し、基本的なフィルターを指定することもできます。ファイルのリストを区切り形式で返しますが、必要に応じて SQL 挿入を使用してこれらをデータセットに簡単に挿入できます (例は含まれていますがテストされていません - SAS アクセス atm はありません)。別のマクロ、データセット、SQL ステートメントなど、どこからでも呼び出すことができます。これら 2 つのマクロをマクロ自動呼び出しライブラリに追加するだけで、すぐに使用できます。

以下に2つのマクロがあります。%file_list マクロには、%isdir マクロが必要です。マクロは上記のものより少し大きく複雑ですが、はるかに柔軟です。さらに、エラーチェックを提供します。

/******************************************************************************
** PROGRAM:  ISDIR.SAS
**
** DESCRIPTION: DETERMINES IF THE SPECIFIED PATH EXISTS OR NOT.
**              RETURNS: 0 IF THE PATH DOES NOT EXIST OR COULD NOT BE OPENED.
**                       1 IF THE PATH EXISTS AND CAN BE OPENED.
**
** PARAMETERS: iPath: THE FULL PATH TO EXAMINE.  NOTE THAT / AND \ ARE TREATED
**                    THE SAME SO &SASDIR/COMMON/MACROS IS THE SAME AS
**                    &SASDIR\COMMON\MACROS.
**
******************************************************************************/

%macro isDir(iPath=,iQuiet=1);
  %local result dname;

  %let result = 0;

  %if %sysfunc(filename(dname,&iPath)) eq 0 %then %do;
    %if %sysfunc(dopen(&dname)) %then %do;
      %let result = 1;
    %end;
    %else %if not &iQuiet %then %do;
      %put ERROR: ISDIR: %sysfunc(sysmsg());
    %end;
  %end;
  %else %if not &iQuiet %then %do;
    %put ERROR: ISDIR: %sysfunc(sysmsg());
  %end;

  &result

%mend;

%put %isDir(iPath=&sasdir/common/macros);
%put %isDir(iPath=&sasdir/kxjfdkebnefe);
%put %isDir(iPath=&sasdir/kxjfdkebnefe, iQuiet=0);
%put %isDir(iPath=c:\temp);

/******************************************************************************
** PROGRAM:  FILE_LIST.SAS
**
** DESCRIPTION: RETURNS THE LIST OF FILES IN A DIRECTORY SEPERATED BY THE
**              SPECIFIED DELIMITER. RETURNS AN EMPTY STRING IF THE THE 
**              DIRECTORY CAN'T BE READ OR DOES NOT EXIST.
**
** PARAMETERS: iPath      : THE FULL PATH TO EXAMINE.  NOTE THAT / AND \ ARE 
**                          TREATED THE SAME SO &SASDIR/COMMON/MACROS IS THE 
**                          SAME AS &SASDIR\COMMON\MACROS. WORKS WITH BOTH UNIX 
**                          AND WINDOWS.
**             iFilter    : SPECIFY A BASIC FILTER TO THE FILENAMES, NO REGULAR 
**                          EXPRESSIONS OR WILDCARDS.
**             iFiles_only: 0=RETURN FILES AND FOLDERS
**                          1=RETURN FILES ONLY.
**             iDelimiter : SPECIFY THE DELIMITER TO SEPERATE THE RESULTS BY.
******************************************************************************/
/*
** TODO: DOESNT CATER FOR MACRO CHARS IN FILENAMES. FIX SOMETIME.
** TODO: IMPROVE THE FILTER. JUST A SIMPLE IF STATEMENT AT THE MOMENT.
*/
%macro file_list(iPath=, iFilter=, iFiles_only=0, iDelimiter=|);
  %local result did dname cnt num_members filename;

  %let result=;

  %if %sysfunc(filename(dname,&iPath)) eq 0 %then %do;

    %let did = %sysfunc(dopen(&dname));
    %let num_members = %sysfunc(dnum(&did));

    %do cnt=1 %to &num_members;
      %let filename = %sysfunc(dread(&did,&cnt));
      %if "&filename" ne "" %then %do;
        %if &iFiles_only %then %do;
          %if not %isDir(iPath=&iPath/&filename) %then %do;
            %if "&iFilter" ne "" %then %do;
              %if %index(%lowcase(&filename),%lowcase(&iFilter)) %then %do;
                %let result = &result%str(&iDelimiter)&filename;
              %end;
            %end;
            %else %do;
              %let result = &result%str(&iDelimiter)&filename;
            %end;
          %end;
        %end;
        %else %do;
          %if "&iFilter" ne "" %then %do;
            %if %index(%lowcase(&filename),%lowcase(&iFilter)) %then %do;
              %let result = &result%str(&iDelimiter)&filename;
            %end;
          %end;
          %else %do;
            %let result = &result%str(&iDelimiter)&filename;
          %end;
        %end;
      %end;
      %else %do;
        %put ERROR: (CMN_MAC.FILE_LIST) FILE CANNOT BE READ.;
        %put %sysfunc(sysmsg());
      %end;
    %end;

  %end;
  %else %do;
    %put ERROR: (CMN_MAC.FILE_LIST) PATH DOES NOT EXIST OR CANNOT BE OPENED.;
    %put %sysfunc(sysmsg());
  %end;

  /*
  ** RETURN THE RESULT.  TRIM THE LEADING DELIMITER OFF THE FRONT OF THE RESULTS.
  */
  %if "&result" ne "" %then %do;
    %substr(&result,2)
  %end;

%mend; 



**
** EXAMPLES - HAVENT TESTED THE LAST TWO YET BUT THEY SHOULD WORK IF SYNTAX IS CORRECT
*;

%put %file_list(iPath=c:\temp);

%put %file_list(iPath=c:\xxdffsds);

%put %file_list(iPath=c:\rob\SASDev\, iFilter=a);

%put %file_list(iPath=c:\rob\SASDev\,iFiles_only=1);

%put %file_list(iPath=/tmp/unix_sasdir,iFiles_only=1);

data x;
  file_list = "%file_list(iPath=c:\temp)";
run;

proc sql noprint;
  insert into my_table values ("%file_list(iPath=c:\temp,iDelimiter=%str(","))");
quit;

Answer 8

この小さなマクロを使用します

%macro getdir(dir=,redirect=, switch=);
    options noxwait xsync;
    %if %length(&switch)=0 %then %let switch=b;
    data _null_; 
      xcmd='dir "' || "&dir" || '"' || "/&switch " || ">" || "&redirect";
      put 'generated the following command: ' xcmd=; 
      rc=system(xcmd);
      put 'result code of above command: ' rc=;
    run;
%mend getdir;

サンプルコール

%getdir(dir=c:\temp\,redirect=c:\temp\dir.txt) *run;

バッチで実行していて、ジョブがない場合option noxwait xsync、オペレーターの応答を待ってサーバー上でジョブがハングします。