14

学習課題として、Haskell でヒープソートを実装しようとしています。Stateヒープは単一の構造内でデータを移動することにかなり大きく依存しているため、これを行うにはモナドが正しい選択であると考えました（そしてdo表記法が役立つでしょう）。また、モナド全般についての理解を深めたいと思っています。

Learn You A Haskell (および他の多くのチュートリアル)のモナドの例では、State次のように定義されています。 State

newtype State s a = State { runState :: s -> (a,s) }

s -> (a,s)型の関数(他の引数でカリー化される場合とされない場合があります) をState値コンストラクターに渡す必要があります。したがって、私の関数は次のようになります。

pop :: Ord a => State (Heap a) a
pop = State pop'
pop' :: Ord a => Heap a -> (a, Heap a)
-- implementation of pop' goes here

push :: Ord a => a -> State (Heap a) ()
push item = State $ push' item
push' :: Ord a => a -> Heap a -> ((), Heap a)
-- implementation of push' goes here

これはコンパイルされず、次のエラーが発生します。

Not in scope: data constructor `State'
Perhaps you meant `StateT' (imported from Control.Monad.State)

のAPI ドキュメントを読むと、これらのチュートリアルが作成されて以来、モジュールから値コンストラクターが削除されているControl.Monad.Stateように見えます。State初心者として、私はドキュメンテーションが一目瞭然ではないことに気づきました。だから私の質問は：

  1. State値コンストラクターがなくなったと信じるのは正しいですか?
  2. 代わりに何を使用すればよいですか？
4

4 に答える 4

15
  1. はい、なくなりました。 に置き換えられましたStateT。(StateモナドはStateTモナド変換子の観点から定義されています。)
  2. state代わりに関数を使用する必要があります。

ただし、あなたのアプローチが正しいかどうかは疑問です。の実装方法を気にする代わりに、Statedo 表記とgetandput関数の使用を検討してください。

于 2013-01-04T12:22:10.107 に答える
12

State Monad に関連する本に示されている例の正しい実装は次のとおりです。

モナドスタック:

-- MonadicStack.hs (Learn You a Haskell for Great Good!)

import Control.Monad.State  

type Stack = [Int]

pop :: State Stack Int
-- The following line was wrong in the book:
-- pop = State $ \(x:xs) -> (x,xs)  
pop = do
 x:xs <- get
 put xs
 return x

push :: Int -> State Stack ()  
-- The following line was wrong in the book:
-- push a = State $ \xs -> ((),a:xs)
push a = do
 xs <- get
 put (a:xs)
 return ()

pop1 = runState pop [1..5]
push1 = runState (push 1) [2..5]

stackManip :: State Stack Int  
stackManip = do  
 push 3  
 a <- pop  
 pop  

stackManip1 = runState stackManip [5,8,2,1]  
stackManip2 = runState stackManip [1,2,3,4]  

stackStuff :: State Stack ()  
stackStuff = do  
 a <- pop  
 if a == 5  
  then push 5  
  else do  
   push 3  
   push 8  

stackStuff1 = runState stackStuff [9,0,2,1,0]  
stackStuff2 = runState stackStuff [5,4,3,2,1]

moreStack :: State Stack ()  
moreStack = do  
 a <- stackManip  
 if a == 100  
  then stackStuff  
  else return ()  

moreStack1 = runState moreStack [100,9,0,2,1,0]
moreStack2 = runState moreStack [9,0,2,1,0]

stackyStack :: State Stack ()  
stackyStack = do  
 stackNow <- get  
 if stackNow == [1,2,3]  
  then put [8,3,1]  
  else put [9,2,1]  

stackyStack1 = runState stackyStack [1,2,3]
stackyStack2 = runState stackyStack [10,20,30,40]

モナド乱数発生器:

-- MonadicRandomGenerator.hs (Learn You a Haskell for Great Good!)

import System.Random  
import Control.Monad.State  

randomSt :: (RandomGen g, Random a) => State g a  
-- The following line was wrong in the book:
-- randomSt = State random
randomSt = do
 gen <- get
 let (value,nextGen) = random gen
 put nextGen
 return value

randomSt1 = (runState randomSt (mkStdGen 1)) :: (Int,StdGen)
randomSt2 = (runState randomSt (mkStdGen 2)) :: (Float,StdGen)

threeCoins :: State StdGen (Bool,Bool,Bool)  
threeCoins = do  
 a <- randomSt  
 b <- randomSt  
 c <- randomSt  
 return (a,b,c)  

threeCoins1 = runState threeCoins (mkStdGen 33)
threeCoins2 = runState threeCoins (mkStdGen 2)

-- rollDie and rollNDice are not explained in the book LYAHFGG. 
-- But these functions are interesting and complementary:

rollDie :: State StdGen Int
rollDie = do 
 generator <- get
 let (value, newGenerator) = randomR (1,6) generator
 put newGenerator
 return value

rollDie1 = runState rollDie (mkStdGen 1)
rollDie2 = runState rollDie (mkStdGen 2)

rollNDice :: Int -> State StdGen [Int]
rollNDice 0 = do
 return []
rollNDice n = do
 value <- rollDie
 list <- rollNDice (n-1)
 return (value:list)

rollNDice1 = runState (rollNDice 10) (mkStdGen 1)
rollNDice2 = runState (rollNDice 20) (mkStdGen 2)
于 2013-05-23T04:54:58.127 に答える