0

Rod Strougo と Ray Wenderlich の「Learning Cocos2D」という本を読んでいて、Cocos2d-Box2d を使って独自の iOS ゲームを作成することにしました。今、解決できない問題があります。CCLayer を継承する Box2dLayer というクラスを作成し、Box2dLayer を継承する Level1Layer クラスを作成しました。画面にレンダリングする2つの異なるタイプのbox2dボディができるまで、すべてがうまくいきました。ゲームを開始するたびに、-[Box2DLayer update:] メソッドで失敗し、次のようになります。 Thread 1: EXC_BAD_ACCESS(code=1, address= 0xsomething); 1 - [Box2DLayer update:] 行 sp.position... 2 - [CCScheduler update:] 行entry->impMethod( entry->target, updateSelector, dt );

そして、ここに私のコードがあります:

//Box2DSprite.h
@interface Box2DSprite : CCSprite
{
    b2Body *body;
}
@property (assign) b2Body *body;
@end

//Box2DSprite.mm

@implementation Box2DSprite
@synthesize body;
-(void)dealloc
{

    body = NULL;
    [super dealloc];
}
@end

//Box2DLayer.h
@interface Box2DLayer : CCLayer
{
    b2World *world;
    GLESDebugDraw *debugDraw;
    b2MouseJoint *mouseJoint;
    b2Body *groundBody;
}
-(void)setupGround;
@end

//Box2DLayer.mm

@implementation Box2DLayer
-(id)init
{
    if (self = [super init]) {
        [self scheduleUpdate];
        [self setupWorld];
        [self setupDebugDraw];
        [self setupGround];
        self.isTouchEnabled = YES;
    }
    return self;
}

- (void)setupWorld {
    b2Vec2 gravity = b2Vec2(0.0f, -10.0f);
    world = new b2World(gravity);
    //world->SetContinuousPhysics(true);
}

-(void) draw {    
    ccGLEnableVertexAttribs( kCCVertexAttribFlag_Position );
    kmGLPushMatrix();
    world->DrawDebugData();
    kmGLPopMatrix();
}

- (void)setupDebugDraw {
    debugDraw = new GLESDebugDraw(PTM_RATIO *[[CCDirector sharedDirector] contentScaleFactor]);
    world->SetDebugDraw(debugDraw);
    debugDraw->SetFlags(b2Draw::e_shapeBit);
}
- (void)registerWithTouchDispatcher {
    [[[CCDirectorIOS sharedDirector] touchDispatcher]  addTargetedDelegate:self priority:0
                                                           swallowsTouches:YES];
}
-(void)update:(ccTime)dt {
    int32 velocityIterations = 3;
    int32 positionIterations = 2;
    world->Step(dt, velocityIterations, positionIterations);
    for(b2Body *b = world->GetBodyList(); b != NULL; b = b->GetNext())
    {
        if (b->GetUserData() != NULL) {
            Box2DSprite *sp = (Box2DSprite *) b->GetUserData();
            sp.position = ccp(b->GetPosition().x * PTM_RATIO*RETSIZE,b->GetPosition().y * PTM_RATIO*RETSIZE);
            sp.rotation = CC_RADIANS_TO_DEGREES(b->GetAngle() * -1);
        }
    }
}
-(void)setupGround{
    CGSize winSize = [[CCDirector sharedDirector] winSize];
    b2BodyDef groundBodyDef;

    groundBodyDef.type = b2_staticBody;
    groundBodyDef.position.Set(0, 10/RETSIZE/PTM_RATIO);
    groundBody = world->CreateBody(&groundBodyDef);
    CCSprite *gsprite = [CCSprite spriteWithFile:@"ground.png"];
    groundBody->SetUserData(gsprite);

    b2EdgeShape groundBox;

    groundBox.Set(b2Vec2(0,0), b2Vec2(winSize.width/PTM_RATIO/RETSIZE-150/PTM_RATIO,0));
    groundBody->CreateFixture(&groundBox,0);

}
-(BOOL)ccTouchBegan:(UITouch *)touch withEvent:(UIEvent *)event{
    CGPoint touchLocation = [touch locationInView:[touch view]];
    touchLocation = [[CCDirector sharedDirector] convertToGL:touchLocation];
    touchLocation = [self convertToNodeSpace:touchLocation];

    b2Vec2 locationWorld = b2Vec2(touchLocation.x/PTM_RATIO/RETSIZE, touchLocation.y/PTM_RATIO/RETSIZE);

    b2AABB aabb;
    b2Vec2 delta = b2Vec2(1.0/PTM_RATIO/RETSIZE, 1.0/PTM_RATIO/RETSIZE);
    aabb.lowerBound = locationWorld - delta;
    aabb.upperBound = locationWorld + delta;
    SimpleQueryCallback callback(locationWorld);
    world->QueryAABB(&callback, aabb);

    if (callback.fixtureFound) {
        b2Body *body = callback.fixtureFound->GetBody();

        b2MouseJointDef joint;
        joint.bodyA = groundBody;
        joint.bodyB = body;
        joint.target = locationWorld;
        joint.maxForce = 100*body->GetMass();
        joint.collideConnected = true;

        mouseJoint = (b2MouseJoint *)world->CreateJoint(&joint);
       // body->SetAwake(false);
        return YES;
    }

}

-(void)ccTouchMoved:(UITouch *)touch withEvent:(UIEvent *)event{
    CGPoint touchLocation = [touch locationInView:[touch view]];
    touchLocation = [[CCDirector sharedDirector]
                     convertToGL:touchLocation];
    touchLocation = [self convertToNodeSpace:touchLocation];
    b2Vec2 locationWorld = b2Vec2(touchLocation.x/PTM_RATIO/RETSIZE, touchLocation.y/PTM_RATIO/RETSIZE);
    if (mouseJoint) {
        mouseJoint->SetTarget(locationWorld);        
    }

}

-(void)ccTouchEnded:(UITouch *)touch withEvent:(UIEvent *)event{
    if (mouseJoint) {
        world->DestroyJoint(mouseJoint);
        mouseJoint = NULL;
        }
}
-(void) dealloc
{
    if (world) {
        delete world;
        world = NULL;

    }
    if (debugDraw) {
        delete debugDraw;
        debugDraw = NULL;
    }
    [super dealloc];
}
@end

update メソッド内の for ループでプログラムがクラッシュします。for ループをコメント アウトすると、すべてが機能することに注意してください。ただし、スプライトは box2D 本体に接続されません。

答えられない場合は、何が問題なのか、考えられる問題のリストを教えてください。ありがとう！

4

2 に答える 2

0

こんにちはエラーはそれがメモリの問題であると言います。そこにないものにアクセスしようとしています。2つのこと; あなたのコードでは、スプライトボディが世界に接続されているところはどこにも見当たりません。次に、Box2dSpriteクラスのbodyプロパティが割り当てられているのに、保持されるべきではないのはなぜですか。

于 2013-01-06T20:26:21.630 に答える
0

最後に、私は問題を解決しました！更新したい本体が静的でないかどうかを確認する必要がありました。これですべて正常に動作します。修正された更新方法は次のようになります。

-(void)update:(ccTime)dt {
    int32 velocityIterations = 3;
    int32 positionIterations = 2;
    world->Step(dt, velocityIterations, positionIterations);
    for(b2Body *bdy = (world->GetBodyList()); bdy != NULL; bdy = bdy->GetNext())
    {
        if (bdy->GetType()!=b2_staticBody && bdy->GetUserData() != NULL) {
            Box2DSprite *sp = (Box2DSprite *) bdy->GetUserData();
            sp.position = ccp(bdy->GetPosition().x * PTM_RATIO*RETSIZE,bdy->GetPosition().y * PTM_RATIO*RETSIZE);
            sp.rotation = CC_RADIANS_TO_DEGREES(bdy->GetAngle() * -1);

        }
    }
}
于 2013-01-07T14:56:57.797 に答える