2

PROC SQL複数の連続したステートメントではなく、いくつかのコードを1つのステートメントに統合できるのではないかと思いますSQL。

こことここで提供されているのと同様に、マクロを使用して、調査の同意日における参加者の年齢を計算しています。マクロの機能のトラブルシューティングを試み、 ％sumマクロを使用して出生時の赤ちゃんの総体重をオンスで計算しました（これはうまく機能します...）。ただし、年齢を計算しようとすると、マクロは機能しません。

ただし、SQL新しいステートメントで マクロを使用すると、正常に機能します。

以下のコードは機能します：

%macro months(somedate,birth);
intck('month',&birth,&somedate) 
         - (day(&somedate) < day(&birth))
%mend months;

%macro days(somedate,birth);
intck('day',&birth,&somedate) 
         - (day(&somedate) < day(&birth))
%mend days;

%macro sum(part1, part2);
&part1*16 + &part2
%mend sum;


**********  bringing in data from outside tables  ;
proc sql;
  create table demos as
    select      x.*,    infcondt2 as c_dt, 
                y.*,    datepart(visitdt)   as v_dt format date9. ,
                        datepart(birthdt)   as b_dt format date9. ,
                        birthweightlbs as lbs,
                        birthweightoz as oz,

                        lbs*16 + oz as tot_oz,
                        %sum(lbs,oz) as tot_oz_m

    from    enrolled as x, 
            demographics as y

    where x.center = y.center and x.id = y.id  ;
    quit;

**********  calculating age in months and in days  ;
proc sql;
create table demos2 as
select  * ,
        %months(c_dt, b_dt) as age_m ,
        %days(c_dt, b_dt) as age_d 
from demos;
quit;


**********  creating age groupings by months: 0-3 and 3-6  ;
proc sql;
create table demos3 as
select  * ,
        case
          when age_m le 3 then 1
          when age_m le 6 and age_m gt 3 then 2
          else 3
          end as age_interval
from demos2;
quit;

それを単一のステートメントに統合する方法はありますか？何かのようなもの：

proc sql;
  create table demos as
    select      x.*,    infcondt2 as c_dt, 
                y.*,    datepart(visitdt)   as v_dt format date9. ,
                        datepart(birthdt)   as b_dt format date9. ,
                        birthweightlbs as lbs,
                        birthweightoz as oz,

                        lbs*16 + oz as tot_oz,
                        %sum(lbs,oz) as tot_oz_m,
                        %months(c_dt, b_dt) as age_m,
                        %days(c_dt, b_dt) as age_d, 
                        case
                            when age_m le 3 then 1
                            when age_m le 6 and age_m gt 3 then 2
                            else 3
                            end as age_interval

    from    enrolled as x, 
            demographics as y

    where x.center = y.center and x.id = y.id  ;
    quit;
4

2 に答える 2

3

calculated同じSQLステートメントで以前に作成されたフィールドを使用する場合は、キーワードを使用する必要があります。IE：

proc sql;
select age*2 as double_Age, calculated double_age/2 as normal_age from sashelp.class;
quit;

計算は、実際の計算がある場合、つまりb_Dtの場合にのみ必要です。c_dtはinfcondt2の名前変更にすぎないため、c_dt（またはinfcondt2）を同じ意味で使用でき、CALCUALTEDを使用することはできません。

data test;
input dt1 :date9. dt2 :date9.;
datalines;
01JAN2010 01FEB2011
01DEC2011 03FEB2012
;;;;
run;

%macro months(somedate,birth);
intck('month',&birth,&somedate) - (day(&somedate) < day(&birth))
%mend months;

proc sql;
create table test2 as
select dt1 -1 as b_dt, dt2 as c_dt, %months(calculated b_dt, c_dt) as third
from test;
quit;

とはいえ、9.2以降を使用している場合は、曜日を調整する必要はありません。INTCKのドキュメントを確認してください。オプションの引数があり（9.3ではMETHODと呼ばれ、9.2では別の名前で呼ばれていると思います）、個別の概念ではなく連続した月の概念を使用するように強制できます（月の最初の数は個別ですが、たとえば、デフォルトでは）。

また、DAYマクロのポイントがわかりません。DAYは整数であるだけでなく（通常の減算を使用して2つの数値を減算できます）、％monthのように日/日を減算するのはなぜですか？これは、先ほど説明したように、月の一部を修正するためのものであり、何日も必要ありません（いつか<出生の場合、間違った答えが返されます）。

正しいコードの例：

%macro months(somedate,birth);
intck('month',&birth,&somedate) 
         - (day(&somedate) < day(&birth))
%mend months;

%macro days(somedate,birth);
intck('day',&birth,&somedate) 
         - (day(&somedate) < day(&birth))
%mend days;

%macro sum(part1, part2);
&part1*16 + &part2
%mend sum;

data enrolled;
input
id infcondt2 :date9.
;
datalines;
1 01JAN2011
2 02JAN2011
3 03MAR2011
;;;;
run;
data demographics;
input
id
birthweightlbs
birthweightoz
birthdt :datetime17.
;
datalines;
1 8 14 04MAR2011:15:13:14
2 7 13 05MAR2011:15:13:14
3 6 15 06MAR2011:15:13:14
;;;;
run;


proc sql;
  create table demos as
    select      x.*,    infcondt2 as c_dt, 
                y.*,    datepart(birthdt)   as b_dt format date9. ,
                        birthweightlbs as lbs,
                        birthweightoz as oz,
                        lbs*16 + oz as tot_oz,
                        %sum(lbs,oz) as tot_oz_m,
                        %months(c_dt, calculated b_dt) as age_m,
                        c_dt - calculated b_dt as age_d, /* %days is almost certainly wrong here */
                        case
                            when calculated age_m le 3 then 1
                            when 3 le calculated age_m le 6 then 2
                            else 3
                            end as age_interval

    from    enrolled as x, 
            demographics as y

    where x.id = y.id  ;
    quit;
于 2013-01-07T16:53:15.567 に答える
3

変数に対して複雑なデータステップロジックを実行したい場合proc sql、私が知っている最善の方法proc fcmpは、マクロの代わりに関数を定義するために使用することです。

例えば

proc fcmp outlib=work.util.Dates;
    function months(somedate, birth);
        return (intck('month',&birth,&somedate) - (day(&somedate) < day(&birth)));
    endsub;
run;

options cmplib=work.util;


proc sql;
create table demos as
select      x.*,    infcondt2 as c_dt, 
            y.*,    datepart(visitdt)   as v_dt format date9. ,
                    datepart(birthdt)   as b_dt format date9. ,
                    birthweightlbs as lbs,
                    birthweightoz as oz,

                    lbs*16 + oz as tot_oz,                        
                    months(c_dt, b_dt) as age_m,
                    case
                        when age_m le 3 then 1
                        when age_m le 6 and age_m gt 3 then 2
                        else 3
                        end as age_interval

from    enrolled as x, 
        demographics as y

where x.center = y.center and x.id = y.id  ;
quit;

ステップ、、、およびその他の場所でmonths()作成した関数を使用することもできます。dataproc sql

于 2013-01-07T18:17:13.147 に答える