4

XML ファイルは次のようになります。

<?xml version="1.0" encoding="UTF-8"?>
<resource-data xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:noNamespaceSchemaLocation="resource-data.xsd">
  <class name="AP">
    <attributes>
      <resourceId>00 11 B5 1B 6D 20</resourceId>
      <lastModifyTime>20130107091545</lastModifyTime>
      <dcTime>20130107093019</dcTime>
      <attribute name="NMS_ID" value="DNMS" />
      <attribute name="IP_ADDR" value="10.11.141.111" />
      <attribute name="LABEL_DEV" value="00 11 B5 1B 6D 20" />
    </attributes>
        <attributes>
      <resourceId>00 11 B5 1B 6D 21</resourceId>
      <lastModifyTime>20130107091546</lastModifyTime>
      <dcTime>20130107093019</dcTime>
      <attribute name="NMS_ID" value="DNMS" />
      <attribute name="IP_ADDR" value="10.11.141.112" />
      <attribute name="LABEL_DEV" value="00 11 B5 1B 6D 21" />
    </attributes>
  </class>
</resource-data>

そして私のコード：

#!/usr/bin/perl

use Encode;
use XML::LibXML;
use Data::Dumper;

$parser = new XML::LibXML;
$struct = $parser->parse_file("d:/AP_201301073100_1.xml");

my $file_data = "d:\\ap.txt";
open IN, ">$file_data";

$rootel = $struct->getDocumentElement();
$elname = $rootel->getName();

@kids   = $rootel->getElementsByTagName('attributes');
foreach $child (@kids) {
  @atts = $child->getElementsByTagName('attribute');
  foreach $at (@atts) {
    $va = $at->getAttribute('value');
    print IN encode("gbk", "$va\t");
  }
  print IN encode("gbk", "\n");
}
close(IN);

私の質問は、XML ファイルが 80MB しかない場合、プログラムは非常に高速になりますが、XML ファイルがはるかに大きい場合、プログラムは非常に遅くなる可能性があるということです。誰かがこれをスピードアップするのを手伝ってくれますか?

4

5 に答える 5

6

を使用XML::Twigすると、解析中に検出された各<attributes>要素を処理し、不要になった XML データを破棄できます。

このプログラムは、必要なことを行うようです。

use strict;
use warnings;

use XML::Twig;
use Encode;

use constant XML_FILE => 'S:/AP_201301073100_1.xml';
use constant OUT_FILE => 'D:/ap.txt';

open my $outfh, '>:encoding(gbk)', OUT_FILE or die $!;

my $twig = XML::Twig->new(twig_handlers => {attributes => \&attributes});
$twig->parsefile('myxml.xml');

sub attributes {
  my ($twig, $atts) = @_;
  my @values = map $_->att('value'), $atts->children('attribute');
  print $outfh join("\t", @values), "\n";
  $twig->purge;
}

出力

DNMS  10.11.141.111 00 11 B5 1B 6D 20
DNMS  10.11.141.112 00 11 B5 1B 6D 21
于 2013-01-08T07:19:54.247 に答える
4

もう 1 つの可能性は、XML::LibXML::Readerを使用することです。SAX と同様に機能しますがlibxml、XML::LibXML と同じライブラリを使用します。

#!/usr/bin/perl
use warnings;
use strict;

use XML::LibXML::Reader;

my $reader = XML::LibXML::Reader->new(location => '1.xml');

open my $OUT, '>:encoding(gbk)', '1.out';

while ($reader->read) {
    attr($reader) if 'attributes' eq $reader->name
                     and XML_READER_TYPE_ELEMENT == $reader->nodeType;
}

sub attr {
    my $reader = shift;
    my @kids;
  ATTRIBUTE:
    while ($reader->read) {
        my $name = $reader->name;
        last ATTRIBUTE if 'attributes' eq $name;
        next ATTRIBUTE if XML_READER_TYPE_END_ELEMENT == $reader->nodeType;
        push @kids, $reader->getAttribute('value')
            if 'attribute' eq $name;
    }
    print {$OUT} join("\t", @kids), "\n";
}
于 2013-01-08T09:05:45.253 に答える
0

XML::SAX大きなXMLファイルの場合、DOMパーサーはXML構造全体をメモリ内に構築するため、のようなストリームベースのパーサーを使用する必要があります。

于 2013-01-08T07:22:37.087 に答える
0

これほど大きな XML ファイル (80 MB 以上) がある場合、ファイル全体をメモリに解析することはできません。まず、非常に遅く、次に、最終的にメモリ不足になり、プログラムがクラッシュします。

XML::Twigとコールバックを使用してコードを書き直すことをお勧めします。

于 2013-01-08T07:06:37.557 に答える
0

XML::Rulesを使用したさらに別の方法:

use strict;
use warnings;

use XML::Rules;
use Data::Dumper;

my @rules = (
  attribute => [ attributes => sub { print "$_[1]{value}\n"; return } ],
  _default => undef,
);

my $xr = XML::Rules->new( rules => \@rules );
my $data = $xr->parse($xml);
于 2013-01-08T18:13:57.060 に答える