1

そのため、LEGIT Office 2013 アクティベーターを作成しています。これは正規キーを使用し、/act スクリプトを実行してアクティベートします。

x32 ビットまたは x64 ビットの Office を確認するために、コマンドで ospp.vbs というファイルを検索しました。x86 で見つかった場合は x32 であり、プログラム ファイルで見つかった場合は x64 です。しかし、x32 内で見つからなかった場合は、次のステップに進みますが、/microsoft が予期されていなかったことが通知され、終了しますか? これが私のCMDファイルです：

@echo off
echo.Microsoft Office 2013 Activator
pause >nul
cls
NET SESSION >nul 2>&1
IF %ERRORLEVEL% EQU 0 (
    goto :Start
) ELSE (
echo.
echo.
echo.
echo.           ERROR: YOU ARE NOT AN ADMIN!
ECHO.   PLEASE RUN THIS TOOL AS AN ADMIN IN ORDER FOR IT TO WORK PROPERLY
ECHO.              PRESS ANY KEY TO EXIT THE TOOL
PAUSE >NUL
EXIT
)

:Start
type "C:\program files (x86)\microsoft office\office15\ospp.vbs" >NUL 2>NUL
if %ERRORLEVEL% EQU 0 (
echo.x32 Office 2013 on x64 Machine Found.
echo.Why did you get x32 Office on an x64 Machine?
echo.Preparing to activate...
pause >nul
cls
goto :x32
) ELSE (
goto :x64check
)
:x64check
type "C:\program files\microsoft office\office15\ospp.vbs" >NUL 2>NUL
if %ERRORLEVEL% EQU 0 (
    echo.x64 Office 2013 on x64 Machine Found 
echo.or
echo.x32 Office 2013 on x32 Machine Found
echo.Preparing to Activate...
pause >nul
cls
goto :x64
) ELSE (
echo.Office 2013 Could not be found on this machine...
echo.Are you sure Office 2013 is installed?
echo.If it is installed , search for ospp.vbs in C:\program Files (x86)\Microsoft Office\Office 15\
pause >nul
cls
)

:x32
cd "C:\program files (x86)\microsoft office\Office15\"
cls
cscript ospp.vbs /remhst
cls
cscript ospp.vbs /act
cls
cscript ospp.vbs /dstatus
pause >nul
echo Check the Above to see if Activation succeded or press any key to open winword and check it maunally.
pause >nul
start winword

:x64
cd "C:\program files\microsoft office\Office15\"
cls
cscript ospp.vbs /remhst
cls
cscript ospp.vbs /act
cls
cscript ospp.vbs /dstatus
pause >nul
echo Check the Above to see if Activation succeded or press any key to open winword and check it maunally.
pause >nul
start winword

私の問題がどこにあるか教えてください。ありがとう！

4

1 に答える 1

3

そのエラー メッセージの理由は次の行です。

echo.If it is installed , search for ospp.vbs in C:\program Files (x86)\Microsoft Office\Office 15\

閉じ括弧)は、 のスコープの終わりとして解釈されていelseます。かっこをリテラルとして使用し、引用符に含まれていない場合は、かっこをエスケープします。

echo.If it is installed , search for ospp.vbs in C:\program Files ^(x86^)\Microsoft Office\Office 15\
于 2013-01-09T16:22:25.103 に答える