1 
 B  C          D        H                    I
Age Years   Salary      Years               Bonus % 
50  12  $120,000.00 <5 years             0.00%
42  20  $40,000.00      5 to 10 years        20.00%
51  3   $97,000.00      11 to 15 years       30.00%
58  28  $105,000.00 16 to 20 years       40.00%
67  6   $78,000.00      20 to 25 years       50.00%
                       26 or more years     100.00%

次の条件に基づいてボーナスを計算する if ステートメントを作成しようとしています。ただし、私のステートメントは VALUE を返し続けます これが私が持っているものです

$K$1 = 50
=IF(B2<$K$1,0),IF(C2<5,0),IF(AND(C2>5,C2<10),D2*I3),IF(AND(C2>10,C2<15),D2*I4),IF(AND(C2>15,C2<20),D2*I5),IF(AND(C2>20,C2<25),D2*I6),IF(C2>25,D2*I7)

助けてください。

4

3 に答える 3

2

コンマで区切るのではなく、IF ステートメントをネストする必要があります。数式は次のようになります。

=IF(B2<$K$1,0, IF(C2<5,0, IF(AND(C2>5,C2<10),D2*I3, IF(AND(C2>10,C2<15),D2*I4, IF(AND(C2>15,C2<20),D2*I5, IF(AND(C2>20,C2<25),D2*I6, IF(C2>25,D2*I7)))))))

IF 関数のパラメーターはlogical_test、value_if_true、value_if_falseであるため、2 番目の IF ステートメントの結果はvalue_if_false最初の IF ステートメントの になります。

于 2013-01-10T16:25:20.217 に答える
1

私はLOOKUPアプローチを好みます-これを試してください

=IF(B2<K$1,0,LOOKUP(C2,{0,5,10,15,20,25},I$2:I$7)*D2)

于 2013-01-10T16:29:05.480 に答える
0

Excel でエラーが発生した場合、エラーのあるセルを選択すると感嘆符がポップアップ表示されます。その画像をクリックしてメニューを表示すると、計算手順を表示するオプションを選択できます。

そうすることで、どこが間違っているかを簡単に確認できます。どの IF ステートメントにも value_if_false が定義されていないため、Excel は最初の 2 つの IF ステートメントを評価した後に "FALSE, FALSE" を計算します。この問題を解決するには、閉じ括弧の位置を変更してください。

=IF(B2<$K$1,0,IF(C2<5,0,IF(AND(C2>5,C2<10),D2*$I$3,IF(AND(C2>10,C2<15),D2*$I$4,IF(AND(C2>15,C2<20),D2*$I$5,IF(AND(C2>20,C2<25),D2*$I$6,IF(C2>25,D2*$I$7)))))))

于 2013-01-10T16:26:31.253 に答える