2

だから、私は本当に立ち往生していて、それが正しいアプローチではないと考え始めています。次の文字列について考えてみます。"[APPLE| ORANGE] PEAR"ここでのロジックは、「APPLEが文字列の場合、その色を取得します。ELSEORANGEが文字列の場合、その色を取得します。ELSEは空の文字列を返します。 "。

HelloWorldを正常に動作させることができました。1.ANTLRに文字列の条件付きロジックを理解させるのに苦労しています。2. ANTLRが識別子ごとにgetColor（）を呼び出すのに苦労しています。任意のヘルプやガイダンスをいただければ幸いです。私は現在、煙霧で走っています。

grammar Test;

@header {
  package org.mytest.Test;
}

@members {
    private String answer = "";

    private void getColor(String fruit)
    {
        //Use java reflection to get Fruit class and invoke method getColor()
        answer = fruit.color;
    }

}

 @lexer::header {
  package org.mytest.Test;
}


/*------------------------------------------------------------------
 * PARSER RULES
 *------------------------------------------------------------------*/

row returns [List<String> list]
@init {list = new ArrayList<String>();}
  :  a=value {list.add($a.val);} (WS b=value {list.add($b.val);})* (EOF)
  ;

conditionalString    returns [String color]:
                (
                a=IDENTIFIER (WS IDENTIFIER)* {getColor($a.text); } 
                )
                {$color=answer;};

//Get the text string for the matched identifier?
value returns [String val]  :  IDENTIFIER {val = $IDENTIFIER.text;}  ;


/*------------------------------------------------------------------
 * LEXER RULES
 *------------------------------------------------------------------*/

IDENTIFIER  :   ('A'..'Z')+;


WS : ( '\t' | ' ')+     { $channel = HIDDEN; } ;

理想的な使用法は以下のとおりです。「コンテキスト」引数は、リソースハンドルになります。ANTLが各トークンの処理方法を認識できるように、コンストラクターを手動で編集してコンテキストを渡します。

TestLexer lex = new TestLexer(new ANTLRStringStream("[APPLE|ORANGE] PEAR"));
CommonTokenStream tok = new CommonTokenStream(lex);
TestParser par = new TestParser(context,tok);
System.out.println(par.conditionalString());
4

1 に答える 1

1

これがあなたが求めているものに近いと私が思う文法です。指定したとおりにケースのみを処理します。[id|id|id]は単純な条件付きでidあり、条件外はそのまま評価されます。

Fruit.g

grammar Fruit;

@parser::members { 

    private StringBuilder output = new StringBuilder();
    private java.util.HashMap<String, String> colors = new java.util.HashMap<String, String>();

    public void addColor(String fruit, String color){
        colors.put(fruit, color);
    }

    private void printColor(String fruit){
        if (colors.containsKey(fruit)){
            output.append(colors.get(fruit));
            output.append(" ");
        } else { 
            output.append("(no color for ").append(fruit).append(")");
        }
    }

    private void printColor(Token id){
        printColor(id.getText());
    }

    private void evaluateCondition(java.util.List<Token> tokens){
        for (Token token : tokens){
            String fruit = token.getText();
            if (colors.containsKey(fruit)){
                printColor(fruit);
                break;
            }
        }
    }
}

conditionalString returns [String result]
@after { result = output.toString();}
            : expr
            ;

expr        : cond_expr+
            ;

cond_expr   : ID
            {printColor($ID);}
            | LSQB values+=ID (OR values+=ID)* RSQB
            {evaluateCondition($values);}
            ;

OR          : '|';
LSQB        : '[';
RSQB        : ']';
ID          : ('A'..'Z')+;
WS          : ('\t'|' ')+ {skip();};

これがテストクラスです。パーサーのメソッドaddColorは、テストを簡素化するために存在します。たとえば、果物の「ORANGE」の色が「orange」で、入力文字列が「ORANGE ORANGE」の場合、出力は「orangeorange」であると予想されます。

FruitTest.java

public class FruitTest {

    public static void main(String[] args) throws Exception {
        CharStream input = new ANTLRStringStream("[APPLE|ORANGE] PEAR");
        FruitLexer lexer = new FruitLexer(input);
        CommonTokenStream tokens = new CommonTokenStream(lexer);

        FruitParser parser = new FruitParser(tokens);

        parser.addColor("APPLE", "red");
        parser.addColor("ORANGE", "orange");
        parser.addColor("PEAR", "yellow");

        String result = parser.conditionalString();

        if (lexer.getNumberOfSyntaxErrors() > 0 || parser.getNumberOfSyntaxErrors() > 0){
            throw new Exception("Syntax errors encountered!");
        }

        System.out.println(result);
    }
}

テストケース1：たくさんの果物

  • APPLE=赤
  • オレンジ=オレンジ
  • PEAR=黄色

入力： [APPLE|ORANGE] PEAR
出力：red yellow

テストケース2：たくさんの果物

  • オレンジ=オレンジ
  • PEAR=黄色

入力： [APPLE|ORANGE] PEAR
出力：orange yellow

Test Case 3: Low on fruit

  • PEAR = yellow

Input: [APPLE|ORANGE] PEAR
Output: yellow

Test Case 4: Hunger strike (no fruit colors defined)

Input: [APPLE|ORANGE] PEAR
Output: (no color for PEAR)

Since PEAR is not part of a conditional, it's expected to be defined.

于 2013-01-11T04:08:45.130 に答える