5

イベントの日付の列があります。（たとえば、A1：A100）

ここで、数式を使用して、2013年1月に発生したイベントの数を検索または表示したいと思います。

何か案は ？

4

4 に答える 4

1

式を補助関数FREQUENCYと一緒に使用します。MONTH

  1. 結果表に 1 ～ 12 の数字を入力します (例: D1:D12)。
  2. 隣接する 12 個のセル (例では E1:E12) を選択し=FREQUENCY(MONTH(A1:A1000),D1:D12)、数式を配列数式として入力します (つまりCtrl-Shift-Enter、 の代わりに を押しますEnter) 。

年ごとに分けたい場合は、列 D のキーと数式を変更してキーを導出する必要がMONTH(A1:A1000)ありMONTH(A1:A1000)&"-"&YEAR(A1:A1000)ますTEXT(A1:A1000,"MM-YY")。

于 2013-01-13T21:22:53.837 に答える
1

必要なのは配列数式です。入力方法から「CSE」数式と呼ばれることもあります。

宛先セルを選択して選択します。次に、数式バーに次のように入力します。

=SUM(IF((A1:A100>=DATEVALUE("1/1/2013"))*(A1:A100<=DATEVALUE("31/1/2013")),1,0))

[enter] の代わりに、[ctrl]+[shift]+[enter] を押します。

なぜMSがあなたにCSEのことをさせているのか、 私は本当に理解していません-確かに、それが配列式であることはフォーマットから明らかですか?

于 2013-01-11T04:39:40.263 に答える
1

Countifs間のレコードを検索するために使用するのはどうstart and end dateですか? 日付を入力するか、日付を含む 2 つのセルを指定することができます。使用している Excel のバージョンは不明ですがCountIfs、2003 以降ではサポートされていません。

=COUNTIFS(A2:A100,">="&C2,A2:A100,"<="&C3)

また

=COUNTIFS(A2:A100,">=1/1/2013",A2:A100,"<=31/1/2013")
于 2013-01-11T05:04:07.483 に答える
0

いくつかのアイデア：

  • SUMPRODUCT 式を使用して、月ごとに集計します。例を参照してください: http://www.contextures.com/xlFunctions04.html#SumProduct

  • ピボット テーブルを使用します。

    列 B を追加します=month(a1)。記入してください。すべての s の列 C を追加します1。

    A、B、C のヘッダー名を指定します: Date, Month, Count.

    A、B、C に基づいてピボット テーブルを挿入します。これで、月ごとに簡単に合計できます。

  • 数式 (探している月が正確にわかっている場合):

    おそらく、次のような数式で列 B を埋めてください: =if(and(month(a1)=1,year(a1)=2013),1,0)、次にsum()列 B?

  • 統合機能を使用します。見てみましょう: http://www.techrepublic.com/blog/window-on-windows/use-consolidate-to-summarize-excel-data-without-sorting/6521

于 2013-01-11T04:10:53.417 に答える