windows - TPageControlはインデックスを取得します

Question

オブジェクトがあるページの番号を取得するにはどうすればよいですか？例：最初のページにButton1があり、2番目のページにButton2がある場合、ActivePageIndexのないButton1があるページの番号を取得するにはどうすればよいですか？ありがとう。

Answer 1

特定のクラスの最も近い親を見つけたいと思うことは非常に一般的です。それで、それはまさにそれをする機能を作るために配当を支払います。

function GetParentWithClass(Control: TControl; 
  ClassType: TWinControlClass): TWinControl;
begin
  Result := Control.Parent;
  while Assigned(Result) and not (Result is ClassType) do
    Result := Result.Parent;
end;

これを配置したら、それを使用して現在の問題を解決できます。

var
  PageIndex: Integer;
  TabSheet: TTabSheet;
.....
TabSheet := GetParentWithClass(Control, TTabSheet) as TTabSheet;
PageIndex := TabSheet.PageIndex;

このように懸念を分離すると、他の設定で利用できるようにGetParentWithClassなります。

Answer 2

Function GetPageIndexOfControl(c:TControl):Integer;
begin
   Result := -1;
   While Assigned(c.Parent) and not (c is TTabsheet) do c := c.Parent;
   if Assigned(c) then
     if c is TTabsheet then
       Result := TTabsheet(c).PageIndex;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
 Showmessage(IntToStr(GetPageIndexOfControl(Button1)));    
end;

Answer 3

これを試して：

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Button1.Parent is TTabSheet then
    ShowMessage(IntToStr(TTabSheet(Button1.Parent).PageIndex));
end;

ボタンがタブシートに直接ある場合（パネルやその他のコントロールがない場合）に機能します。パネルがある場合は、親チェーンをたどって、親がTTabSheetであるかどうかを確認できます。

procedure TForm1.Button1Click(Sender: TObject);
var
  Ctrl: TWinControl;
begin
  Ctrl := Button1.Parent;
  while Assigned(Ctrl) do
  begin
    if Ctrl is TTabSheet then
    begin
      ShowMessage(IntToStr(TTabSheet(Ctrl).PageIndex));
      Break;
    end
    else
      Ctrl := Ctrl.Parent;
  end;
end;

Answer 4

Generics繰り返さないようにするのが好きです

PageIndex := TComponentUtil.GetParent<TTabSheet>( MyControl ).PageIndex;

そのようなクラスで

unit ComponentUtils;

interface

uses
  Classes, Controls;

type
  TComponentUtil = class abstract
    class function GetOwner<T : TComponent>( AComponent : TComponent ) : T;
    class function GetParent<T : TWinControl>( AControl : TControl ) : T;
  end;

implementation

{ TComponentUtil }

class function TComponentUtil.GetOwner<T>( AComponent : TComponent ) : T;
var
  LOwner : TComponent;
begin
  LOwner := AComponent.Owner;

  while Assigned( LOwner ) and not ( LOwner is T ) do
    LOwner := LOwner.Owner;

  Result := T( LOwner );
end;

class function TComponentUtil.GetParent<T>( AControl : TControl ) : T;
var
  LParent : TWinControl;
begin
  LParent := AControl.Parent;

  while Assigned( LParent ) and not ( LParent is T ) do
    LParent := LParent.Parent;

  Result := T( LParent );
end;

end.

Answer 5

ここに示されている追加が求められていない限り、私は追加します他の答えです

Function GetPageIndexOfControl(c:TControl;var PageControl:TPageControl):Integer;
begin
   Result := -1;
   While Assigned(c.Parent) and not (c is TTabsheet) do c := c.Parent;
   if Assigned(c) then
     if c is TTabsheet then
       begin
         Result := TTabsheet(c).PageIndex;
         PageControl := TTabsheet(c).PageControl;
       end;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
  pc:TPageControl;
  i:Integer;
begin
 I := GetPageIndexOfControl(Button1,PC);
 if (i>-1) and Assigned(PC) then
    begin
      PC.ActivePageIndex := i;
      if Assigned(PC.OnChange) then PC.OnChange(PC);
    end;
end;