3

私は自分が書いたアプリケーションを持っています、私は3つのスレッドを持っています。スレッド1、2、および3。

そして、番号1と2の2つのリスト。

スレッドNo.1はリストNo.1にデータを挿入します。

スレッドNo.2は、リストNo.1からデータを取得します。

スレッドNo.2はリストNo.2にデータを挿入します。

スレッドNo.3は、リストNo.2からデータを取得します。

スレッドが同時に実行されている場合、多くのCPUを占有します。データはリストに入力できます。2番目と3番目の実行中のスレッドは必要ありません。

新しいデータのリストにスレッドが挿入され、新しいデータ処理の作業を開始する必要があることを通知するにはどうすればよいですか？

あなたに到達するためのテクニックと効率的な方法は？

どうもありがとう。

4

2 に答える 2

2

これは、3つのスレッドからlist1とlist2に値を追加するサンプルです。

値がリストに入れられるたびに、Eventがトリガーされ、このイベントを処理するスレッドがリストの最後の値を引き出し、イベントフラグをクリアします。

イベントフラグがクリアされるまで、新しい値をリストに入れることはできません。

真ん中のスレッドは、最初のスレッドをストールさせるのではなく、新しい値の中間ストレージを作成します。

すべてのイベントは待機可能であるため、CPUを安心させることができます。

リストはスレッドセーフです。

program Project62;

{$APPTYPE CONSOLE}

uses
  System.SysUtils,
  System.Classes,
  System.SyncObjs,
  System.Generics.Collections;

Type
  TMyThread1 = Class(TThread)
    private
      fMySyncAddList : TSimpleEvent;
      fMyList : TThreadList<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(ASyncAddList: TSimpleEvent; AList: TThreadList<Integer>);
      procedure Execute; override;
  End;
  TMyThread2 = Class(TThread)
    private
      fMySyncAddList1,fMySyncAddList2 : TSimpleEvent;
      fMyList1,fMyList2 : TThreadList<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(ASyncAddList1,ASyncAddList2: TSimpleEvent; AList1,AList2 : TThreadList<Integer>);
      procedure Execute; override;
  End;
  TMyThread3 = Class(TThread)
    private
      fMySyncAddList2 : TSimpleEvent;
      fMyList2 : TThreadList<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(ASyncAddList2: TSimpleEvent; AList2 : TThreadList<Integer>);
      procedure Execute; override;
  End;


{ TMyThread1 }

constructor TMyThread1.Create( ASyncAddList : TSimpleEvent; AList: TThreadList<Integer>);
begin
  Inherited Create(false);
  fMySyncAddList := AsyncAddList;
  fMyList := AList;

end;

procedure TMyThread1.Execute;
var
  stateAcknowledged : boolean;
begin
  stateAcknowledged := true;
  while (not Terminated) do
  begin
    if stateAcknowledged then
    begin // Do some work and adda a value to list1
      fAddVal := Random(100);
      fMyList.Add(fAddVal);
      fMySyncAddList.SetEvent; // Signal a new addition
      stateAcknowledged := false;
      //ShowVal;
      Sleep(1000);
    end
    else begin
      stateAcknowledged := (fMySyncAddList.WaitFor(100) <> wrSignaled);
    end;
  end;
end;

{ TMyThread2 }

constructor TMyThread2.Create(ASyncAddList1, ASyncAddList2: TSimpleEvent;
  AList1, AList2: TThreadList<Integer>);
begin
  Inherited Create(false);
  fMySyncAddList1 := AsyncAddList1;
  fMySyncAddList2 := AsyncAddList2;
  fMyList1 := AList1;
  fMyList2 := AList2;    
end;

procedure TMyThread2.Execute;
var
  wr : TWaitResult;
  list : TList<Integer>;
  pulled : Boolean;
begin
  pulled := false;
  while (not Terminated) do
  begin
    if pulled then // Add a value to list2
    begin
      wr := fMySyncAddList2.WaitFor(0);
      if (wr <> wrSignaled) then
      begin
        fMyList2.Add(fAddVal);
        fMySyncAddList2.SetEvent; // Signal a new addition
        pulled := false;
      end
      else Sleep(100);
    end
    else begin // Wait for a new value in list1
      wr := fMySyncAddList1.WaitFor(INFINITE);
      if Terminated then
        Exit;
      if (wr = wrSignaled) then
      begin
        // Pull out the value
        list := fMyList1.LockList;
        try
          fAddVal := list.Last;
        finally
          fMyList1.UnlockList;
        end;
        // All clear
        pulled := true;
        fMySyncAddList1.ResetEvent;
        //ShowVal;
      end;
    end;
  end;
end;

{ TMyThread3 }

constructor TMyThread3.Create(ASyncAddList2: TSimpleEvent;
  AList2: TThreadList<Integer>);
begin
  Inherited Create(false);
  fMySyncAddList2 := AsyncAddList2;
  fMyList2 := AList2;
end;

procedure TMyThread3.Execute;
var
  wr : TWaitResult;
  list : TList<Integer>;
begin
  while not Terminated do
  begin
    wr := fMySyncAddList2.WaitFor(INFINITE);
    if Terminated then
      Exit;
    if (wr = wrSignaled)  then // Wait for signal
    begin
      // Pull out the value
      list := fMyList2.LockList;
      try
        fAddVal := list.Last;
        //ShowVal;
      finally
        fMyList2.UnlockList;
      end;
      // Clear event
      fMySyncAddList2.ResetEvent;
    end;
  end;
end;

var
  list1,list2 : TThreadList<Integer>;
  syncList1,syncList2 : TSimpleEvent;
  thread1 : TMyThread1;
  thread2 : TMyThread2;
  thread3 : TMyThread3;
begin
  list1 := TThreadList<Integer>.Create;
  list2 := TThreadList<Integer>.Create;
  syncList1 := TSimpleEvent.Create(Nil,True,False,'',false);
  syncList2 := TSimpleEvent.Create(Nil,True,False,'',false);
  thread3 := TMyThread3.Create(syncList2,list2);
  thread2 := TMyThread2.Create(syncList1,syncList2,list1,list2);
  thread1 := TMyThread1.Create(syncList1,list1);
  Try
    WriteLn('Press [Enter] key to stop.');
    ReadLn;

  Finally
    thread3.Terminate;
    syncList2.SetEvent; // Wake up call
    thread3.Free;
    thread2.Terminate;
    syncList1.SetEvent; // Wake up call
    thread2.Free;
    thread1.Free;
    syncList1.Free;
    syncList2.Free;
    list1.Free;
    list2.Free;
  End;
end.

TThreadedQueue2つのがスレッド間で情報を転送する例を追加しました。スレッドは、代わりに整数の内部リストを保持します。@DavidHeffernanが指摘しているように、コードははるかに単純です。 

program Project63;

{$APPTYPE CONSOLE}

uses
  System.SysUtils,
  System.Classes,
  System.SyncObjs,
  System.Generics.Collections;

Type
  TMyThread1 = Class(TThread)
    private
      fMyList : TList<Integer>;
      fMyQueue : TThreadedQueue<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(AQueue : TThreadedQueue<Integer>);
      procedure Execute; override;
  End;
  TMyThread2 = Class(TThread)
    private
      fMyList1,fMyList2 : TList<Integer>;
      fMyQueue1,fMyQueue2 : TThreadedQueue<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(AQueue1,AQueue2: TThreadedQueue<Integer>);
      procedure Execute; override;
  End;
  TMyThread3 = Class(TThread)
    private
      fMyList : TList<Integer>;
      fMyQueue : TThreadedQueue<Integer>;
      fAddVal : Integer;
    public
      Constructor Create(AQueue : TThreadedQueue<Integer>);
      procedure Execute; override;
  End;

constructor TMyThread1.Create( AQueue : TThreadedQueue<Integer>);
begin
  Inherited Create(false);
  fMyQueue:= AQueue;
  fMyList := TList<Integer>.Create;
end;

procedure TMyThread1.Execute;
begin
  while (not Terminated) do
  begin
    Sleep(1000); // Simulate some work
    fAddVal := Random(100);
    fMyList.Add(fAddVal);
    fMyQueue.PushItem(fAddVal); // Signal a new addition
  end;
  fMyList.Free;
end;

constructor TMyThread2.Create(AQueue1,AQueue2: TThreadedQueue<Integer>);
begin
  Inherited Create(false);
  fMyQueue1 := AQueue1;
  fMyQueue2 := AQueue2;
  fMyList1 := TList<Integer>.Create;
  fMyList2 := TList<Integer>.Create;
end;

procedure TMyThread2.Execute;
var
  queueSize : Integer;
begin
  while (not Terminated) do
  begin
    if (fMyQueue1.PopItem(queueSize,fAddVal) = wrSignaled) and 
       (not Terminated) then
    begin
      fMyList1.Add(fAddVal);
      // Do some work and send a new value to next thread
      fMyQueue2.PushItem(fAddVal);
      fMyList2.Add(fAddVal);
      
    end;
  end;
  fMyList1.Free;
  fMyList2.Free;
end;

constructor TMyThread3.Create(AQueue : TThreadedQueue<Integer>);
begin
  Inherited Create(false);
  fMyQueue := AQueue;
  fMyList := TList<Integer>.Create;
end;

procedure TMyThread3.Execute;
var
  queueSize : Integer;
begin
  while not Terminated do
  begin
    if (fMyQueue.PopItem(queueSize,fAddVal) = wrSignaled) and 
       (not Terminated) then
    begin
      fMyList.Add(fAddVal);
      // Do some work on list
      
    end;
  end;
  fMyList.Free;
end;

var
  queue1,queue2 : TThreadedQueue<Integer>;
  thread1 : TMyThread1;
  thread2 : TMyThread2;
  thread3 : TMyThread3;
begin
  queue1 := TThreadedQueue<Integer>.Create;
  queue2 := TThreadedQueue<Integer>.Create;
  thread3 := TMyThread3.Create(queue2);
  thread2 := TMyThread2.Create(queue1,queue2);
  thread1 := TMyThread1.Create(queue1);
  Try
    WriteLn('Press [Enter] key to stop.');
    ReadLn;

  Finally
    thread3.Terminate;
    queue2.PushItem(0); // Wake up call
    thread3.Free;
    thread2.Terminate;
    queue1.PushItem(0); // Wake up call
    thread2.Free;
    thread1.Free;
    queue1.Free;
    queue2.Free;
  End;
end.
于 2013-01-12T22:08:52.190 に答える
1

最初に頭に浮かぶのはセマフォです。セマフォは、内部にカウンターがある同期プリミティブです。1つのスレッドがカウンターをデクリメントしようとし、ゼロの場合、スレッドはブロックします（つまり、スケジュールされておらず、CPUを消費せず、無害に待機します）。別のスレッドがカウンターをインクリメントし、ブロックされたスレッドを続行させます。

リストごとにセマフォがある場合があるため、消費スレッドは読み取り前にセマフォをデクリメントし、プロデューサースレッドは書き込み後にセマフォをインクリメントします。

世話をする別のことがあります：別のスレッドがそれを変更している間、あるスレッドがリストからデータを取得することは許可されていますか？リスト（または一般的なコレクション）の実装方法によって異なるため、ドキュメント内のリストの「スレッドセーフ」について何かを見つけてください。たぶん、別の同期プリミティブが必要です：mutex。ミューテックスはスレッドによって「取得」されてから「解放」され、複数のスレッドがミューテックスをロックしようとすると、そのうちの1つが待機する必要があります。ここでは、このミューテックスを保持した状態で変更と読み取りを行った、リストごとに1つのミューテックスが適切な場合があります。

于 2013-01-12T16:08:20.990 に答える