awk - Converting months between numeric and number using awk

Question

In a past paper for an exam I have the question:

Months can be represented in different ways, for example as numbers (1, 2, …, 12), or as three- letter month names (Jan, Feb, …, Dec). Suggest how associative arrays in awk can be used to translate from three-letter month names to month numbers, and vice versa, to translate month numbers to three-letter month names.

So I thought I would use associative arrays in the format say the input of the month is in $1:

number_to_month["Jan"] = 1;
print number_to_month[$1]

しかし、私には、これは連想配列の力をうまく活用していないように見えます。さらに、配列内の各月を手動で初期化する必要があります。

他のオプションは何ですか?

score 6 · Accepted Answer

ここでは組み込みsplit関数が役に立ち、ループによって name-from-number バージョンを number-from-name にコピーできます。

BEGIN {
    split("Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec",month)
    for (i in month) {
        month_nums[month[i]]=i
    }
}
END {
    for (i in month) {
        print i "\t" month[i]
    }
    for (m in month_nums) {
        print m "\t" month_nums[m]
    }
}

BEGINブロックはその方法を示しています。次に、ENDブロックすると、それを確認できます。

（gawk 4.0.1を使用して）得られる出力は次のとおりです。

4       Apr
5       May
6       Jun
7       Jul
8       Aug
9       Sep
10      Oct
11      Nov
12      Dec
1       Jan
2       Feb
3       Mar
Feb     2
Sep     9
Jan     1
May     5
Apr     4
Oct     10
Dec     12
Nov     11
Jul     7
Mar     3
Aug     8
Jun     6

配列ループでアクセス順序を強制できないことから生じる通常のぎこちなさ (Heh! AWKwardness ) に注意してください。for

score 2 · Accepted Answer

アレイを手動で初期化したくない場合、1 つのオプションは次のとおりです。

echo | awk '{x=mktime("2013 01 01 0 0 0"); for(i=0;i<12;i++){s=strftime("%b",x+((31*i)*86400)); m[s]=i+1;n[i+1]=s;}}'

これにより、m と n の 2 つの配列が作成されます。m はインデックスが月名、値が月番号である配列で、n 配列はその逆です。

score 1 · Accepted Answer

$ cat tst.awk
BEGIN {
   mths="JanFebMarAprMayJunJulAugSepOctNovDec"

   name="Mar"; print name " -> " (match(mths,name)+2)/3
   name="Sep"; print name " -> " (match(mths,name)+2)/3

   nbr=3;      print nbr  " -> " substr(mths,(nbr*3)-2,3)
   nbr=9;      print nbr  " -> " substr(mths,(nbr*3)-2,3)
}

$ awk -f tst.awk
Mar -> 3
Sep -> 9
3 -> Mar
9 -> Sep

そして、順序付けられた出力を生成するように変更された @dmckee のスクリプトを次に示します。

$ cat tst2.awk
BEGIN {
    n = split("Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec",month)
    for (i in month) {
        month_nums[month[i]]=i
    }

    for (i=1; i<=n; i++) {
        print i "\t" month[i]
    }
    for (i=1; i<=n; i++) {
        m = month[i]
        print m "\t" month_nums[m]
    }
}
$ awk -f tst2.awk
1       Jan
2       Feb
3       Mar
4       Apr
5       May
6       Jun
7       Jul
8       Aug
9       Sep
10      Oct
11      Nov
12      Dec
Jan     1
Feb     2
Mar     3
Apr     4
May     5
Jun     6
Jul     7
Aug     8
Sep     9
Oct     10
Nov     11
Dec     12

score 0 · Accepted Answer

彼らがawkに言及するとき、私はこの月の詳細と整数マッピングが次のようなデータファイルに保持されていると推測します

1 JAN JANUARY jan
2 FEB FEBRUARY feb
...

等々

あなたはawkを使うことができます

awk '/JAN/ {print $1}' temp.txt

score 0 · Accepted Answer

いくつかのヘルパー関数を使用した別の例を次に示します。

awk '
    BEGIN { 
        j = 0
        for (i=1; i<=34; i+=3) {
            months[substr("JanFebMarAprMayJunJulAugSepOctNovDec",i,3)] = ++j
        }
    }
    function month2num(month) {
        return (month in months ? months[month] : -1)
    }
    function num2month(n) {
        for (month in months) {
            if (months[month] == n)
                return month
        }
        return ""
    }
    BEGIN {
        print "Jan: " month2num("Jan")
        print "Dec: " month2num("Dec")
        print "Foo: " month2num("Foo")
        print "3: " num2month(3)
        print "12: " num2month(12)
        print "14: " num2month(14)
    }
'

awk - Converting months between numeric and number using awk

5 に答える 5

Related