0

JSONファイルを複製したいだけです。現在、JSONファイルの読み取りにNsJSONを使用しています。これは私のコードです：

nsJSON::Set /file $DESKTOP\nsis\a.json
nsJSON::Serialize /format /file $DESKTOP\nsis\a_new.json

問題は：

"obj": [ "a", "b", "c" ]

になります：

"obj": [
            "a",
            "b",
            "c"
        ]

jsonコンテンツを元のファイル形式で保持する必要があります。NsJsonでそれを行うにはどうすればよいですか？方法がない場合、これを実行できる別のJSONパーサーを推奨できますか？

4

3 に答える 3

1

ファイルを複製する場合は、CopyFiles コマンドを使用します。

CopyFiles "$DESKTOP\nsis\a.json" "$DESKTOP\nsis\a_new.json"
于 2013-01-18T16:11:43.243 に答える
0

他のJSONパーサープラグインはないと思いますが、IMHOの問題は、有効なJSONだけでなく、特定の形式が必要なことです。

JSON パーサーを変更できない場合は、NSIS で JSON を後処理できると思います (このコードは、すべての種類の引用符やエスケープされた引用符を処理するわけではありません!):

Function PrettyOnelineJSON
Exch $0
Push $1
Push $2
Push $3
Push $4
StrCpy $1 "" ; In quote?
StrCpy $2 "" ; Prev. char.
StrCpy $3 "" ; Pos.
loop:
    StrCpy $4 $0 1 $3
    StrCmp $4 "" done
    IntOp $3 $3 + 1
    StrCmp $4 " " 0 +2
        StrCmp $4 $2 eatone ; Was this and the previous character a space?
    StrCpy $2 $4
    StrCmp $4 "$\n" eatone
    StrCmp $4 "$\r" eatone
    StrCmp $4 '"' 0 loop
    StrCmp $4 $1 +3
        StrCpy $1 $4
        Goto loop
    StrCpy $1 ""
    Goto loop
done:
    Pop $4
    Pop $3
    Pop $2
    Pop $1
    Exch $0
    Return
eatone:
    StrCmp $1 "" 0 loop ; In a quoted string?
    StrCpy $4 $0 "" $3
    IntOp $3 $3 - 1
    StrCpy $0 $0 $3
    StrCpy $0 $0$4
    Goto loop
FunctionEnd


Section

StrCpy $0 '"obj": [$\n            "a A  a   A",$\n            "b",$\n            "c"$\n        ]'
MessageBox mb_ok ORG=|$0|

Push $0
Call PrettyOnelineJSON
Pop $0

MessageBox mb_ok NEW=|$0|

SectionEnd
于 2013-01-21T17:50:23.243 に答える