0

次のような xslt があります。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:db="http://www.liquibase.org/xml/ns/dbchangelog"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="xml"  indent="yes" />
  <xsl:template match="/">    
      <xsl:for-each select="db:databaseChangeLog/db:changeSet"> 
          <xsl:if test="name(*[1])='createTable'">  
          <xsl:result-document  href="base/tables/{position()}_{name(*[1])}_{*[1]/@tableName}.xml">
           <databaseChangeLog 
                xmlns="http://www.liquibase.org/xml/ns/dbchangelog" 
                xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
                xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-2.0.xsd">

                <xsl:copy-of select="."/>                       

                <xsl:copy-of select="../db:changeSet[name(*[1])='createIndex' and *[1]/@tableName= current()/*[1]/@tableName ]" />

            </databaseChangeLog> 
        </xsl:result-document>      
        </xsl:if> 
      </xsl:for-each>     
  </xsl:template>

  <xsl:template match="@* | node()" mode="copy">
       <xsl:copy>
          <xsl:apply-templates select="@* | node()"/>
       </xsl:copy>
   </xsl:template>

    <xsl:template match="db:changeSet/@author" mode="copy">
        <xsl:attribute name="author">
            <xsl:value-of select="'sakhunzai'"/>
        </xsl:attribute>
    </xsl:template>

</xsl:stylesheet>

XML 部分ファイル

<changeSet author="xxx (generated)" id="1358259674512-26">
        <createIndex indexName="category_id" tableName="teams" unique="false">
            <column name="audience_id"/>
        </createIndex>
</changeSet>
<changeSet author="xxx (generated)" id="1358259674512-29">
    <createIndex indexName="id" tableName="users" unique="false">
        <column name="id"/>
        <column name="career_lead_id"/>
    </createIndex>
</changeSet>

changeSet の属性値 (author と id) をオーバーライドしたい。xsltの修正を手伝ってください。

すべて正常に動作していますが、@author 属性値はターゲット xml ファイルで変更されていません 注: xsltproc が失敗したため、saxon Java ベースのプロセッサに切り替えました。

java -jar /usr/local/liquibase/saxon/saxon9he.jar common.xml table.xslt

作業中の XSLT

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:db="http://www.liquibase.org/xml/ns/dbchangelog"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="xml"  indent="yes" />
  <xsl:template match="/">    
      <xsl:for-each select="db:databaseChangeLog/db:changeSet[db:createTable]"> 
          <xsl:result-document  href="base/tables/{position()}_{name(*[1])}_{*[1]/@tableName}.xml">
           <databaseChangeLog 
                xmlns="http://www.liquibase.org/xml/ns/dbchangelog" 
                xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
                xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-2.0.xsd">

                <xsl:apply-templates select="." mode="copy"/>                       

                <xsl:apply-templates select="../db:changeSet[db:createIndex and *[1]/@tableName= current()/*[1]/@tableName ]"  mode="copy"/>

            </databaseChangeLog> 
        </xsl:result-document>
      </xsl:for-each>     
  </xsl:template>

  <xsl:template match="node()" mode="copy">
      <xsl:copy>
          <xsl:attribute name="author">sakhunzai</xsl:attribute>
           <xsl:copy-of select="@id|node()"/>
      </xsl:copy>
   </xsl:template>

</xsl:stylesheet>
4

2 に答える 2

1

<xsl:copy-of />テンプレートは適用されません。正確なコピーを作成するだけです。この行を変更するのはどうですか

<xsl:template match="db:changeSet/@author">

これに：

<xsl:template match="db:changeSet/@author" mode="copy">

このテンプレートを追加:

<xsl:template match="@* | node()" mode="copy">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>

そして最後にこれを変更します：

<xsl:copy-of select="../db:changeSet[name(*[1])='createIndex' and *[1]/@tableName= current()/*[1]/@tableName ]">
    <xsl:copy-of select="."/>                       
</xsl:copy-of>

これに：

<xsl:apply-templates 
   select=="../db:changeSet[name(*[1])='createIndex' and *[1]/@tableName = current()/*[1]/@tableName]" 
   mode="copy" />

補足として、これは少し冗長に見えます。

<xsl:copy-of select="current()[name()='changeSet']">                        
    <xsl:copy-of select="."/>
</xsl:copy-of>

for-each ループにより、現在のノードには必ず「changeSet」という名前が付けられます。その部分にはこれで十分だと思います：

<xsl:copy-of select="." />

完全な XSLT:

<xsl:stylesheet xmlns:db="http://www.liquibase.org/xml/ns/dbchangelog"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml"  indent="yes" />
  <xsl:template match="/">    
      <xsl:for-each select="db:databaseChangeLog/db:changeSet"> 
          <xsl:if test="name(*[1])='createTable'">  
          <xsl:document href="base/tables/{position()}_{name(*[1])}_{*[1]/@tableName}.xml">
           <databaseChangeLog 
                xmlns="http://www.liquibase.org/xml/ns/dbchangelog" 
                xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
                xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-2.0.xsd">

                    <xsl:copy-of select="." />                        

                    <xsl:apply-templates select="../db:changeSet[name(*[1])='createIndex' and *[1]/@tableName= current()/*[1]/@tableName ]" mode="copy" />
            </databaseChangeLog> 
        </xsl:document>     
        </xsl:if> 
      </xsl:for-each>     
  </xsl:template>

  <xsl:template match="@* | node()" mode="copy">
     <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
     </xsl:copy>
  </xsl:template>

  <xsl:template match="db:changeSet/@author" mode="copy">
     <xsl:attribute name="author">
        <xsl:value-of select="'sakhunzai'"/>
      </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

XSLT は次のようにさらに改善できると思います。よろしければお試しください:

<xsl:stylesheet xmlns:db="http://www.liquibase.org/xml/ns/dbchangelog"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml"  indent="yes" />

  <xsl:template match="db:changeSet" />

  <xsl:template match="db:changeSet[db:createTable]">
    <xsl:document href="base/tables/{position()}_{name(*[1])}_{*[1]/@tableName}.xml">
      <databaseChangeLog
           xmlns="http://www.liquibase.org/xml/ns/dbchangelog"
           xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
           xsi:schemaLocation="http://www.liquibase.org/xml/ns/dbchangelog http://www.liquibase.org/xml/ns/dbchangelog/dbchangelog-2.0.xsd">

        <xsl:copy-of select="." />

        <xsl:apply-templates select="../db:changeSet[db:createIndex and *[1]/@tableName = current()/*[1]/@tableName ]" mode="copy" />
      </databaseChangeLog>
    </xsl:document>
  </xsl:template>

  <xsl:template match="@* | node()" mode="copy">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="db:changeSet/@author" mode="copy">
    <xsl:attribute name="author">
      <xsl:value-of select="'sakhunzai'"/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>
于 2013-01-17T13:15:04.267 に答える
1

xsl:copy-of 要素は、子要素を許可しません。xsltproc がスタイルシートを十分に検証していないようです。

于 2013-01-17T14:07:33.497 に答える