2

次のようなデータがあります。

    my @homopol = (
                   ["T","C","CC","G"],  # part1
                   ["T","TT","C","G","A"], #part2
                   ["C","CCC","G"], #part3 ...upto part K=~50
                  );


    my @prob = ([1.00,0.63,0.002,1.00,0.83],
                [0.72,0.03,1.00, 0.85,1.00],
                [1.00,0.97,0.02]);


   # Note also that the dimension of @homopol is always exactly the same with @prob.
   # Although number of elements can differ from 'part' to 'part'.

私がやりたいことは

  1. 要素のすべての組み合わせを生成part1するpartK
  2. の対応する要素の積を求めます@prob。

したがって、最後に次の出力が得られることを願っています。

T-T-C  1 x 0.72 x 1 = 0.720
T-T-CCC     1 x 0.72 x 0.97 = 0.698
T-T-G  1 x 0.72 x 0.02 = 0.014
...
G-G-G  1 x 0.85 x 0.02 = 0.017
G-A-C  1 x 1 x 1 = 1.000
G-A-CCC     1 x 1 x 0.97 = 0.970
G-A-G  1 x 1 x 0.02 = 0.020

問題は、私の次のコードがループをハードコーディングすることによってそれを行うことです。の部分の数は@homopolさまざまで大きくなる可能性があるため (たとえば ~K=50)、同じ結果を得るには柔軟でコンパクトな方法が必要です。ありますか？Algorithm::Loopsを使用することを考えていましたが、それを達成する方法がわかりません。

use strict;
use Data::Dumper;
use Carp;


my @homopol = (["T","C","CC","G"],
               ["T","TT","C","G","A"],
               ["C","CCC","G"]);


my @prob = ([1.00,0.63,0.002,1.00,0.83],
            [0.72,0.03,1.00, 0.85,1.00],
            [1.00,0.97,0.02]);



my $i_of_part1 = -1;
foreach my $base_part1 ( @{ $homopol[0] } ) {
    $i_of_part1++;
    my $probpart1 = $prob[0]->[$i_of_part1];

    my $i_of_part2 =-1;
    foreach my $base_part2 ( @{ $homopol[1] } ) {
        $i_of_part2++;
        my $probpart2 = $prob[1]->[$i_of_part2];

        my $i_of_part3 = -1;
        foreach my $base_part3 ( @{ $homopol[2] } ) {
            $i_of_part3++;
            my $probpart3 = $prob[2]->[$i_of_part3];

            my $nstr = $base_part1."".$base_part2."".$base_part3;
            my $prob_prod = sprintf("%.3f",$probpart1 * $probpart2 *$probpart3);

            print "$base_part1-$base_part2-$base_part3 \t";
            print "$probpart1 x $probpart2 x $probpart3 = $prob_prod\n";

        }
    }
}
4

5 に答える 5

4

Set::CrossProductすべてのセットの外積を生成するイテレータを作成する をお勧めします。イテレータを使用するため、事前にすべての組み合わせを生成する必要はありません。むしろ、要求に応じてそれぞれを生成します。

use strict;
use warnings;
use Set::CrossProduct;

my @homopol = (
    [qw(T C CC G)],
    [qw(T TT C G A)],
    [qw(C CCC G)], 
);

my @prob = (
    [1.00,0.63,0.002,1.00],
    [0.72,0.03,1.00, 0.85,1.00],
    [1.00,0.97,0.02],
);

# Prepare by storing the data in a list of lists of pairs.
my @combined;
for my $i (0 .. $#homopol){
    push @combined, [];
    push @{$combined[-1]}, [$homopol[$i][$_], $prob[$i][$_]]
        for 0 .. @{$homopol[$i]} - 1;
};

my $iterator = Set::CrossProduct->new([ @combined ]);
while( my $tuple = $iterator->get ){
    my @h = map { $_->[0] } @$tuple;
    my @p = map { $_->[1] } @$tuple;
    my $product = 1;
    $product *= $_ for @p;
    print join('-', @h), ' ', join(' x ', @p), ' = ', $product, "\n";
}
于 2009-09-18T13:14:03.237 に答える
2

入力データを変更せずにAlgorithm::Loopsを使用するソリューションは次のようになります。

use Algorithm::Loops;

# Turns ([a, b, c], [d, e], ...) into ([0, 1, 2], [0, 1], ...)
my @lists_of_indices = map { [ 0 .. @$_ ] } @homopol;

NestedLoops( [ @lists_of_indices ], sub {
  my @indices = @_;
  my $prob_prod = 1; # Multiplicative identity
  my @base_string;
  my @prob_string;
  for my $n (0 .. $#indices) {
    push @base_string, $hompol[$n][ $indices[$n] ];
    push @prob_string, sprintf("%.3f", $prob[$n][ $indices[$n] ]);
    $prob_prod *= $prob[$n][ $indices[$n] ];
  }
  print join "-", @base_string; print "\t";
  print join "x", @prob_string; print " = ";
  printf "%.3f\n", $prob_prod;
});

しかし、構造を次のように変更することで、実際にはコードをより明確にすることができると思います

[ 
  { T => 1.00, C => 0.63, CC => 0.002, G => 0.83 },
  { T => 0.72, TT => 0.03, ... },
  ...
]

並列データ構造がなければ、インデックスを反復処理してから 2 つの異なる場所でそれらのインデックスを検索する代わりに、利用可能な基本シーケンスを単純に反復処理できるためです。

于 2009-09-18T08:57:22.067 に答える
0

なぜ再帰を使わないのですか？パラメータとして深さを渡し、関数がループ内で深さ + 1 でそれ自体を呼び出すようにします。

于 2009-09-18T07:17:36.923 に答える
-1

@homopol 配列 (N と言う) と同じ長さのインデックスの配列を作成して、どの組み合わせを見ているかを追跡することでそれを行うことができます。実際、この配列は基数 N の数値に似ており、要素は数字です。基数 N で連続した数値を書き留めるのと同じ方法で繰り返します。たとえば、(0 0 0 ... 0)、(0 0 0 ... 1)、...、(0 0 0 ... N- 1), (0 0 0 ... 1 0), ....

于 2009-09-18T07:18:40.667 に答える
-2

アプローチ 1: 指数からの計算

ホモポールの長さの積 (長さ 1 * 長さ 2 * ... * 長さ N) を計算します。次に、ゼロから積まで i を繰り返します。ここで、必要なインデックスは i % length1, (i / length1)%length2, (i / length1 / length2) % length3, ... です。

アプローチ 2: 再帰

私はそれに殴られました、nikieの答えを見てください。:-)

于 2009-09-18T07:25:38.140 に答える