2

CSSクラスを追加して、文字列（HTMLヘッダー）の最初の2つの単語を赤で強調表示する必要がありますtokenize。これが、現在私が見ているものです。これはどの程度正確に行うことができますか？可能であれば。

いくつかの擬似コード：

<xsl:for-each select="tokenize(title, '\s+')">
    // ......
    <xsl:attribute name="class">
        <xsl:text>className</xsl:text>
    </xsl:attribute>

</xsl:for-each>

結果の各単語を選択するにはどうすればよいですか？

ただし、tokenizeは解決策ではない場合があります。助けていただければ幸いです。

4

3 に答える 3

1

ここでtokenizeを使用することは可能です。特に、単一スペース以外の他の単語区切り文字を処理したい場合は、tokenizeを使用できます（tokenizeの2番目の引数では、正規表現を指定できます。

とにかく、あなたの場合、tokenizeの結果を変数に割り当ててから、最初の2つの単語に対して異なるアクションを実行する価値があるかもしれません。次のXSLTを試してください

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:template match="/*">
      <h1>
         <xsl:variable name="words" select="tokenize(title, ' ')"/>
         <span class="className">
            <xsl:value-of select="concat($words[1], ' ', $words[2])"/>
         </span>
         <xsl:for-each select="$words[position() &gt; 2]">
            <xsl:value-of select="concat(' ', .)"/>
         </xsl:for-each>
      </h1>
   </xsl:template>
</xsl:stylesheet>

例としてこのXMLに適用した場合

<data>
   <title>This is a test</title>
</data>

以下が出力されます

<h1>
   <span class="className">This is</span> a test
</h1>
于 2013-01-21T09:05:36.787 に答える
1

あなたは近くにいます。これが完全な変換です：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/*">
  <h1>
    <xsl:variable name="vWords" select="tokenize(., '\s+')"/>
    <span class="className">
      <xsl:value-of select="$vWords[not(position() gt 2)]" separator=" "/>
      <xsl:text> </xsl:text>
    </span>
      <xsl:value-of select="$vWords[position() gt 2]" separator=" "/>
  </h1>
 </xsl:template>
</xsl:stylesheet>

この変換がこのXMLドキュメントに適用される場合：

<t>Red cat and a mouse</t>

必要な正しい結果が生成されます。

<h1><span class="className">Red cat </span>and a mouse</h1>
于 2013-01-21T13:16:26.970 に答える
1

tokenize（）を使用することの欠点は、トークン間の区切り文字が失われることです。ここでのより良い解決策はxsl：analyze-stringです：

<xsl:analyze-string select="title" regex="\s+ (or whatever)">
  <xsl:matching-substring><xsl:value-of select="."/></xsl:matching-substring>
  <xsl:non-matching-substring>
    <xsl:choose>
      <xsl:when test="position() le 4">
         <span class="xxxx"><xsl:value-of select="."/></span>
      </xsl:when>
      <xsl:otherwise><xsl:value-of select="."/></xsl:otherwise>
   </xsl:choose>
 </xsl:non-matching-substring>
</xsl:analyze-string>

単語間の句読点を許可する正規表現を使用する場合、これにより句読点が失われることはありません。テストを逆にして、単語間の区切り文字ではなく単語に一致する正規表現を使用することもできます。

position（）le 4テストでは、シーケンスが単語または単語間の区切り文字で始まる可能性があるという事実が考慮されています。

于 2013-01-21T15:16:38.840 に答える