3

私は次のようなステートメントを実行しています

DELETE FROM USER WHERE USER_ID=1;

SQLDeveloperで。

ユーザーは多くのテーブルで参照されているため（たとえば、ユーザーには順序、設定などがあります）、ON DELETE CASCADEをアクティブにして、すべての行を手動で削除する必要がないようにしました。ただし、開発中は、カスケード削除によって「自動的に」削除される行数とテーブル数を知りたいと考えています。

これを見つける方法はありますか？SQLステートメントによって、ログファイルから直接sqldeveloperで、または他のアイデアのいずれか？

4

1 に答える 1

3

これは sql%rowcount では不可能ですが、トリガー コードを記述すれば可能ですが、これは、監視するすべてのテーブルにトリガーが必要であることを意味します。また、トリガーは操作を少し遅くします。

例えば：

SQL> select * from one;

        ID
----------
         1
         2

SQL> select * from child_of_one;

        ID       O_ID
---------- ----------
         1          1
         2          1
         3          1
         4          2
         5          2
         6          2
         7          2
         8          2

パッケージ仕様にテーブル + カウントの配列を保持させたい:

SQL> create or replace package foo
  2  as
  3    type rowcount_tab is table of pls_integer index by varchar2(30);
  4    t_rowcount rowcount_tab;
  5  end foo;
  6  /

Package created.

これらのカウントをゼロにリセットするには、最上位テーブルのトリガーが必要です。

SQL> create or replace trigger one_biud
  2  before insert or update or delete
  3  on one
  4  declare
  5  begin
  6    foo.t_rowcount.delete;
  7  end;
  8  /

Trigger created.

これは、最上位テーブルから削除された配列にのみ関心があることを前提としています。foo.t_rowcount.delete('TABLE_NAME')そうでない場合は、代わりに各テーブルにトリガーが必要です。

関心のある各テーブルの各行トリガーの後、配列を設定します。

SQL> create or replace trigger one_aiudfer
  2  after insert or update or delete
  3  on one
  4  for each row
  5  declare
  6  begin
  7    if (foo.t_rowcount.exists('ONE'))
  8    then
  9      foo.t_rowcount('ONE') := nvl(foo.t_rowcount('ONE'), 0)+1;
 10    else
 11      foo.t_rowcount('ONE') := 1;
 12    end if;
 13  end;
 14  /

Trigger created.

SQL> create or replace trigger child_of_one_aiudfer
  2  after insert or update or delete
  3  on child_of_one
  4  for each row
  5  declare
  6  begin
  7    if (foo.t_rowcount.exists('CHILD_OF_ONE'))
  8    then
  9      foo.t_rowcount('CHILD_OF_ONE') := nvl(foo.t_rowcount('CHILD_OF_ONE'), 0)+1;
 10    else
 11      foo.t_rowcount('CHILD_OF_ONE') := 1;
 12    end if;
 13  end;
 14  /

Trigger created.

今、削除するときなど:

SQL> delete from one where id = 1;

1 row deleted.

SQL> declare
  2    v_table varchar2(30);
  3  begin
  4    v_table := foo.t_rowcount.first;
  5    loop
  6       exit when v_table is null;
  7             dbms_output.put_line(v_table || ' ' || foo.t_rowcount(v_table) || ' rows');
  8             v_table := foo.t_rowcount.next(v_table);
  9     end loop;
 10  end;
 11  /
CHILD_OF_ONE 3 rows
ONE 1 rows

PL/SQL procedure successfully completed.

SQL> delete from one where id = 2;

1 row deleted.

SQL> declare
  2    v_table varchar2(30);
  3  begin
  4    v_table := foo.t_rowcount.first;
  5    loop
  6       exit when v_table is null;
  7             dbms_output.put_line(v_table || ' ' || foo.t_rowcount(v_table) || ' rows');
  8             v_table := foo.t_rowcount.next(v_table);
  9     end loop;
 10  end;
 11  /
CHILD_OF_ONE 5 rows
ONE 1 rows
于 2013-01-21T13:46:50.143 に答える