10

言語/ソフトウェア:

言語はVBAです。アプリケーションは、Access 2003 (Excel も使用できます) と Internet Explorer (Windows XP/Seven 上) です。

問題：

私が働いている企業のイントラネット サイトを開いて操作する Access マクロを開発しています。

新しい IE ウィンドウを作成してフォームにデータを入力することはできますが、リンクをクリックしたり、select 要素のオプションを選択したりしたときに開くポップアップなど、他の IE ウィンドウをインターセプトして操作できる必要があります。ページがロードされたとき。

4

1 に答える 1

5

タイトルからIEウィンドウを取得するために使用するコードを次に示します。私のユーザーの 1 人が、エラーが適切に捕捉されないという非常に奇妙な問題を抱えていたため、2 つの機能に分割されました。プライベート関数の本体をパブリック関数に移動できる可能性があります (おそらくそうなるでしょう)。

さらに、Microsoft Internet Controls への参照を設定する必要があります (これは、Windows のバージョンに応じて、shdocvw.dll または ieframe.dll のいずれかです)。簡単にするために、Microsoft HTML Object Library への参照を設定することをお勧めします。 IE オブジェクトを取得したら、DOM をトラバースします。

Function oGetIEWindowFromTitle(sTitle As String, _
                               Optional bCaseSensitive As Boolean = False, _
                               Optional bExact As Boolean = False) As SHDocVw.InternetExplorer

    Dim objShellWindows As New SHDocVw.ShellWindows
    Dim found As Boolean
    Dim startTime As Single

    found = False
    'Loop through shell windows
    For Each oGetIEWindowFromTitle In objShellWindows
        found = oGetIEWindowFromTitleHandler(oGetIEWindowFromTitle, sTitle, bCaseSensitive, bExact)
        If found Then Exit For
    Next

    'Check whether a window was found
    If Not found Then
        Set oGetIEWindowFromTitle = Nothing
    Else
        pauseUntilIEReady oGetIEWindowFromTitle
    End If

End Function

Private Function oGetIEWindowFromTitleHandler(win As SHDocVw.InternetExplorer, _
                                      sTitle As String, _
                                      bCaseSensitive As Boolean, _
                                      bExact As Boolean) As Boolean

    oGetIEWindowFromTitleHandler = False

    On Error GoTo handler
    'If the document is of type HTMLDocument, it is an IE window
    If TypeName(win.Document) = "HTMLDocument" Then
        'Check whether the title contains the passed title
        If bExact Then
            If (win.Document.title = sTitle) Or ((Not bCaseSensitive) And (LCase(sTitle) = LCase(win.Document.title))) Then oGetIEWindowFromTitleHandler = True
        Else
            If InStr(1, win.Document.title, sTitle) Or ((Not bCaseSensitive) And (InStr(1, LCase(win.Document.title), LCase(sTitle), vbTextCompare) <> 0)) Then oGetIEWindowFromTitleHandler = True
        End If
    End If
handler:
    'We assume here that if an error is raised it's because
    'the window is not of the correct type. Therefore we
    'simply ignore it and carry on.

End Function

上記のコードを次のように使用します。

Sub test()

    Dim ie As SHDocVw.InternetExplorer
    Dim doc As HTMLDocument 'If you have a reference to the HTML Object Library
    'Dim doc as Object 'If you do not have a reference to the HTML Object Library

    ' Change the title here as required
    Set ie = oGetIEWindowFromTitle("My popup window")
    Set doc = ie.Document

    Debug.Print doc.getElementsByTagName("body").Item(0).innerText

End Sub

ウィンドウのほぼすべてのプロパティ、またはドキュメントの内容からウィンドウを見つけることができます。これに苦労している場合は、コメントしてください:)。

于 2013-01-22T23:58:09.550 に答える