2

これらの文字列をRegWrite用に適切にフォーマットする方法を理解しようとしていますが、理解できませんでした。終了すると、スクリプトはレジストリのいくつかの領域を変更して、複数のExcel2010ブックが異なるウィンドウで開かれるようにします。

環境：
Windows 7 Professional x64
Excel 2010

Option Explicit
' =======================================================
' Purpose: This will let you open each Excel Spreadsheet in a seperate window.
' =======================================================

Const HKCR = &H80000000

dim objShell, objReg, strComputer

strComputer = "."

set objShell = WScript.CreateObject("WScript.Shell")
Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")

' objShell.RegDelete "HKCR\Excel.Sheet.12\shell\Open\ddeexec\"
objReg.DeleteKey HKCR, "Excel.Sheet.12\shell\Open\ddeexec"

objShell.RegWrite "HKCR\Excel.Sheet.12\shell\Open\command\", "C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE" "%1", "REG_SZ"
objShell.RegWrite "HKCR\Excel.Sheet.12\shell\Open\command\command", "xb'BV5!!!!!!!!!MKKSkEXCELFiles>VijqBof(Y8'w!FId1gLQ "%1"", "REG_MULTI_SZ"

set objShell = Nothing

問題1）何らかの理由で、ddeexecレジストリキーを削除できません。それにはサブキーがあり、いくつかの読書を通して、サブキーも使用しているキーを削除できないことがわかったobjShell.RegDeleteので、私は使用しようとしましたobjReg.DeleteKeyが、どちらも成功しませんでした。すべてのサブキーを個別に削除する必要のない回避策については、何も見つかりませんでした。

問題2）HKCR \ Excel.Sheet.12 \ shell \ open \ commandに書き込もうとしているテキストに、適切にエスケープできない引用符とスペースがたくさん含まれています。レジストリの値は次のようになります"C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE" "%1"

問題3）コマンドキーに入れようとしているクレイジーな文字列に「（」が含まれているため、エラー「）expected」が含まれています。問題2のように、正しくフォーマットするように試しました。 。レジストリの値は次のようになりますxb'BV5!!!!!!!!!MKKSkEXCELFiles>VijqBof(Y8'w!FId1gLQ "%1"

私はさまざまなものを使ってみまし& chr(34) &た""""が、まだ正しいコンボを思い付いていません。

ありがとう！

編集：最終的な解決策。

Option Explicit
' ============================================
' Purpose: This will let you open each Excel Spreadsheet in a seperate window.
' =======================================================

Const HKEY_CLASSES_ROOT = &H80000000

Dim strComputer, objReg, strKeyPath

' Create WMI registry object
strComputer = "."
Set objReg = GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\default:StdRegProv")

' Delete DDE stuff
strKeyPath = "Excel.Sheet.12\shell\Open\ddeexec"
DeleteSubKeys HKEY_CLASSES_ROOT, strKeyPath

' Modify launch commands
strKeyPath = "Excel.Sheet.12\shell\Open\command\"
objReg.SetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", """C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE"" ""%1"""
objReg.SetMultiStringValue HKEY_CLASSES_ROOT, strKeyPath, "command", Array("xb'BV5!!!!!!!!!MKKSkEXCELFiles>VijqBof(Y8'w!FId1gLQ", """%1""")

' =====================================================================
'        Sub: DeleteSubKeys
'       HKEY: The specific root Hive you're editing.
' strKeyPath: Path to specific Key under HKEY.
'    Purpose: Iterate through all subkeys under strKeyPath and delete them.
' http://technet.microsoft.com/en-us/magazine/2006.08.scriptingguy.aspx
' =====================================================================

Sub DeleteSubKeys(HKEY, strKeyPath)

    Dim arrSubkeys, strSubkey

    objReg.EnumKey HKEY, strKeyPath, arrSubkeys

    If IsArray(arrSubkeys) Then
        For Each strSubKey In arrSubkeys
            DeleteSubKeys HKEY, strKeyPath & "\" & strSubkey
        Next
    End If

    objReg.DeleteKey HKEY, strKeyPath
End Sub
4

1 に答える 1

3

問題 1:

すべてのサブキーを下から削除する必要があります。そのために再帰を使用します。

Sub DelKey(hive, key)
  rc = reg.EnumKey(hive, key, subkeys)
  If rc = 0 Then                         ' only proceed if there were no errors
    If Not IsNull(subkeys) Then
      For Each subkey In subkeys
        DelKey hive, key & "\" & subkey  ' <- recurse (descend before delete)
      Next
    End If
    reg.DeleteKey hive, key              ' at this point the key doesn't have
                                         ' subkeys anymore
  End If
End Sub

問題 2:

文字列内の二重引用符は、二重にしてエスケープする必要があります。

objShell.RegWrite "HKCR\Excel.Sheet.12\shell\Open\command\" _
  , """C:\Program Files (x86)\Microsoft Office\Office14\EXCEL.EXE"" ""%1""" _
  , "REG_SZ"

問題 3:

文書化さ れているようRegWriteに、タイプはサポートされていませんREG_MULTI_SZ。これを使用する必要がありますSetMultiStringValue。ここでも内側の二重引用符をエスケープする必要があります。

于 2013-01-23T18:58:27.673 に答える