3

次のような XML があります。

<risk>
  <driver driverId="2">
    <vehicleUse>M</vehicleUse>
  </driver>
  <driver driverId="3">
    <vehicleUse>F</vehicleUse>
  </driver>
  <driver driverId="4">
    <vehicleUse>I</vehicleUse>
  </driver>
</risk>

XSLT (v1.0、.NET 実装) を使用して各 vehicleUse を数値に変換し、それらの数値の合計を取得しています。vehicleUses は、M=3、F=2、および I=1 として変換されます。さらに複雑なのは、ID が 3 のドライバーの場合、これらの値が 10 倍され、ドライバー 4 の場合は 100 倍されることです。したがって、上記の例では、合計は 3 + 20 + 100 = 123 になります。

XSLT ファイルでテンプレートを次のように定義しました。

<xsl:template name="getVehicleUseScore">
  <xsl:param name="driverId" />
  <xsl:param name="vehicleUse" />
  <!-- Implementation left out for brevity -->
</xsl:template>

次に、XSLT ファイルの残りの部分がテンプレートを呼び出します。

<xsl:template match="risk">
  <vehicleUseScore>
    <xsl:for-each select="driver">
      <xsl:call-template name="getVehicleUseScore">
        <xsl:with-param name="driverId" select="@driverId" />
        <xsl:with-param name="vehicleUse" select="vehicleUse" />
      </xsl:call-template>
    </xsl:for-each>
  </vehicleUseScore>
</xsl:template>

<xsl:template match="/">
  <xsl:apply-templates />
</xsl:template>

その結果、3、20、100 が連結された "320100" というテキストが得られます。これは、少なくとも getVehicleUseScore テンプレートが機能することを証明しています。

getVehicleUseScore の結果を sum() 関数に渡したいのですが、方法がわかりません。私は次のことを試しました;

<xsl:value-of select="sum(getVehicleUseScore(@driverId, vehicleUse))" />

しかし、XSLT コンパイラは、「getVehicleUseScore() は不明な XSLT 関数です」と述べています。

これを行う方法はありますか？

4

2 に答える 2

1

これを行うための短い XSLT 1.0 の方法を次に示します。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

 <xsl:template match="risk">
  <vehicleUseScore>
   <xsl:variable name="vrtfResult">
        <xsl:for-each select="driver">
          <xsl:call-template name="getVehicleUseScore">
            <xsl:with-param name="pdriverId" select="@driverId" />
            <xsl:with-param name="pvehicleUse" select="vehicleUse" />
          </xsl:call-template>
        </xsl:for-each>
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($vrtfResult)/*)"/>
  </vehicleUseScore>
 </xsl:template>

 <xsl:template name="getVehicleUseScore">
  <xsl:param name="pdriverId" />
  <xsl:param name="pvehicleUse" />
  <score>
   <xsl:variable name="vValue" select=
   "(($pvehicleUse='M')*3 + ($pvehicleUse='F')*2 + ($pvehicleUse='I')*1)"/>
   <xsl:variable name="vFactor" select=
   "1 +(9*($pdriverId=3)) + (99*($pdriverId=4))"/>

   <xsl:value-of select="$vValue*$vFactor"/>
  </score>
 </xsl:template>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、次のようになります。

<risk>
    <driver driverId="2">
        <vehicleUse>M</vehicleUse>
    </driver>
    <driver driverId="3">
        <vehicleUse>F</vehicleUse>
    </driver>
    <driver driverId="4">
        <vehicleUse>I</vehicleUse>
    </driver>
</risk>

必要な正しい結果が生成されます。

<vehicleUseScore>123</vehicleUseScore>

説明:

テンプレートの出力を変数にキャプチャする場合、この変数は RTF (結果ツリー フラグメント) 型であり、コンテンツにノード (テキスト ノードを除く) が含まれていない限り、そのコンテンツは XPath 式でナビゲートできません。

これを行うにはxxx:node-set()、RTF を通常のツリーに変換するために、その変数に対してベンダー依存の拡張関数を呼び出す必要があります。

ここでは、算術式でブール値が検出されるたびに数値に変換されるという事実、および定義による事実も使用します。

number(true()) = 1

と

number(false()) = 0
于 2013-01-25T22:18:19.320 に答える
1

もう少し長いですが、node-set()関数の使用を回避するもう 1 つのアプローチ (私は可能であればプロプライエタリ関数を避けたいと思っていますが、セミnode-set()プロプライエタリにすぎません) は、再帰を使用することです。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="risk">
    <vehicleUseScore>
      <xsl:call-template name="sumDriverScores">
        <xsl:with-param name="drivers" select="driver" />
      </xsl:call-template>
    </vehicleUseScore>
  </xsl:template>

  <xsl:template name="sumDriverScores">
    <xsl:param name="drivers" />

    <xsl:if test="not($drivers)">
      <xsl:text>0</xsl:text>
    </xsl:if>
    <xsl:if test="$drivers">
      <xsl:variable name="currentValue">
        <xsl:call-template name="getVehicleUseScore">
          <xsl:with-param name="driverId" select="$drivers[1]/@driverId" />
          <xsl:with-param name="vehicleUse" select="$drivers[1]/vehicleUse" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:variable name="sumRemainder">
        <xsl:call-template name="sumDriverScores">
          <xsl:with-param name="drivers" select="$drivers[position() > 1]" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="$currentValue + $sumRemainder"/>
    </xsl:if>
  </xsl:template>


  <xsl:template name="getVehicleUseScore">
    <xsl:param name="driverId" />
    <xsl:param name="vehicleUse" />
    <xsl:variable name="useFactor" select="translate($vehicleUse, 'MFI', '321')"/>
    <xsl:variable name="idFactor" 
                  select="1 + 9 * ($driverId = 3) +  99 * ($driverId = 4)"/>

    <xsl:value-of select="$useFactor * $idFactor"/>
  </xsl:template>
</xsl:stylesheet>

出力は次のとおりです。

<vehicleUseScore>123</vehicleUseScore>
于 2013-01-26T15:30:13.090 に答える