0

XHTMLテンプレートがあります。xhtmlファイルをxsltに動的に変換したい。これを行うための最良の方法は何ですか？以下にXHTMLコンテンツを記述しました

<div>
{:header:}
<br />
{:date:}
<p>
{:mailingattn:} <br />
{:facilityname:} <br />
{:facilitystreet:} <br />
{:facilitystreet2:} <br />
{:facilitycity:}, {:facilitystate:}  {:facilityzip:} <br />
{:facilitycountry:}
</p>

<p>
{:message:}
</p>

<p>
Sincerely,<br />
{:signature:}
</p>
{:footer:}
</div>
4

2 に答える 2

2

あなたの XHTML ファイルで使用されているマクロのセマンティクスは正確にはわかりませんが、次の変換により、同等の XSLT スタイルシートが生成されます。そうでない場合は、必要に応じて簡単に調整できます。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xs="http://www.w3.org/2001/XMLSchema">

    <xsl:template match="*">
        <xsl:copy>
            <xsl:copy-of select="@*"/>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/">
        <xsl:element name="xsl:stylesheet">
            <xsl:attribute name="version" select="'2.0'"/>
            <xsl:element name="xsl:template">
                <xsl:attribute name="match" select="'/*'"/>
                <xsl:apply-templates/>
            </xsl:element>
        </xsl:element>
    </xsl:template>

    <xsl:template match="text()">
        <xsl:variable name="regex">\{:([a-zA-Z0-9]*):\}</xsl:variable>
        <xsl:analyze-string select="." regex="{$regex}">
            <xsl:matching-substring>
                <xsl:element name="xsl:value-of">
                    <xsl:attribute name="select" select="regex-group(1)"/>
                </xsl:element>
            </xsl:matching-substring>
            <xsl:non-matching-substring>
                <xsl:value-of select="."/>
            </xsl:non-matching-substring>
        </xsl:analyze-string>
    </xsl:template>

</xsl:stylesheet>
于 2013-01-29T14:02:01.757 に答える
0

XProc と <p:template> の使用を検討しましたか?

http://www.w3.org/TR/xproc-template/#c.template

于 2013-01-29T13:07:47.857 に答える