0

私はgroovy/grailsが初めてで、基本的に次のように、1か月のすべての投稿を検索する基準検索を実行しようとしています:

def getUserMinutesForYear(User user, Date date){

    Date firstDate = new GregorianCalendar(date.year, Calendar.JANUARY, 1, 0, 0, 0).time
    Date lastDate = new GregorianCalendar(date.year, Calendar.DECEMBER, 31, 23, 59, 59).time

    def c = JobRegistration.createCriteria()

    def minutes = c.get {
        and{
            eq("user.id", user.id)
            between("job.happening", firstDate, lastDate)

        }

        projections {
            sum("minutesWorked")
        }
    }



    return minutes
}

ドメインクラスは

 class Job {

     String title
     String description
     Date   happening

     static hasMany = [registrations:JobRegistration]
 }


class User {
    static hasMany = [authorities: Role, registrations: JobRegistration]
    static belongsTo = Role
    String username
}

class JobRegistration {

    Job job
    User user

    Integer minutesWorked
    static belongsTo = [user:User,job:Job]

    static constraints = {
        user(blank: false)
        job(blank:false)
        minutesWorked(nullable :true)
    }

    String toString(){
        return user.userRealName
    }

}

さて、なぜこの例外が発生するのでしょうか?

org.codehaus.groovy.runtime.InvokerInvocationException: org.hibernate.QueryException: プロパティを解決できませんでした: job.happening of: JobRegistration

4

1 に答える 1

0

ジョブ関係をネストする必要があります (user で eq を使用することもできます):

def minutes = c.get {
    and{
            eq("user", user)
            job{
                between("happening", firstDate, lastDate)
            }

    }

    projections {
            sum("minutesWorked")
    }
}

乾杯

リー

于 2009-09-25T06:24:56.717 に答える