vba - Excel2010の入力ボックスを使用したコピーと貼り付け-VBA

Question

ヘルプが必要です。私はVBAの初心者で、単純なマクロから始めようとしています。しかし、それでも惨めに失敗します。私がやろうとしているのは、入力ボックスを使用して1つのワークシートから別のワークシートにコピーアンドペーストし、コピーする範囲を指定することだけです。これで、入力ボックスは次のようになりました。

Application.InputBox("Enter the range from which you want to copy : ", Type:=8)

しかし、別のワークシートのセルにコピーするには、何行が必要ですか？

馬鹿になってしまったことをあらかじめお詫び申し上げます。

Answer 1

これはあなたがしようとしていることですか？

Option Explicit

Sub Sample()
    Dim rngCopyFrom As Range

    On Error Resume Next
    Set rngCopyFrom = Application.InputBox("Enter the range from which you want to copy", Type:=8)
    On Error GoTo 0

    If Not rngCopyFrom Is Nothing Then
        '~~> Copy the range to say Cell A1 of Sheets("weekly raw")
        rngCopyFrom.Copy ThisWorkbook.Sheets("weekly raw").Range("A1")
    End If
End Sub

Answer 2

それを行う1つの方法は次のとおりです。

Sub CopyRange()
    Dim FromRange As Range
    Dim ToRange As Range

    Set FromRange = Application.InputBox("Enter the range from which you want to copy : ", Type:=8)
    Set ToRange = Application.InputBox("Enter the range to where you want to copy : ", Type:=8)

    FromRange.Copy ToRange
    'Or you can do it like this if you need some flexibility on Paste 
    'FromRange.Copy
    'ToRange.PasteSpecial xlPasteValues, xlPasteSpecialOperationNone
End Sub

Answer 3

サンプルコードは次のとおりです。

Option Explicit

Sub CopyStuff()

Dim x As Range
Dim y As Range

Set x = Application.InputBox("Select what copy using the mouse", Type:=8)
Set y = ActiveWorkbook.Sheets("Sheet2").Range("A1")

x.Copy y

End Sub