3

私はラップトップを 2 つのネットワーク環境 (職場と自宅) で使用しており、ネットワーク設定 (IP アドレス、サブネット マスク、デフォルト ゲートウェイ) が異なるため、家に帰るたびに、またオフィスに到着するたびにネットワーク設定を変更する必要があります。 ..設定を手動で変更する代わりにプログラムを実行するだけでよいように、設定を変更できるコードを書く方法はありますか?

少しグーグルしてこれを見つけましたが、ネットワークカード名が見つかりません。コードはIPアドレスとサブネットマスクのみを変更するようですが、デフォルトゲートウェイは変更しません..私は正しいですか?

ところで、皆さんが私の質問に答える際に Delphi プログラミングを使用できれば素晴らしいと思います (特に Delphi 7)。

4

1 に答える 1

7

あなたが指摘したように、この質問に投稿されたコードはデフォルト ゲートウェイを変更しません。そのためには、SetGatewaysメソッドも実行する必要があります。

ネットワーク アダプタの IP、マスク、およびデフォルト ゲートウェイを設定できる元のコードのこの修正版を試してください。

{$APPTYPE CONSOLE}

{$R *.res}

uses
  SysUtils,
  ActiveX,
  Variants,
  ComObj;

procedure  SetStaticIpAddress(const NetworkCard, IPAddress, Mask, GateWay :string);
const
  WbemUser    ='';
  WbemPassword='';
  WbemComputer='localhost';
  wbemFlagForwardOnly = $00000020;
var
  FSWbemLocator   : OLEVariant;
  FWMIService     : OLEVariant;
  FWbemObjectSet  : OLEVariant;
  FWbemObject     : OLEVariant;
  FOutParams      : OLEVariant;
  vIpAddress      : OLEVariant;
  vGateWays       : OLEVariant;
  vMask           : OLEVariant;
  oEnum           : IEnumvariant;
  iValue          : LongWord;
begin
  FSWbemLocator := CreateOleObject('WbemScripting.SWbemLocator');
  FWMIService   := FSWbemLocator.ConnectServer(WbemComputer, 'root\CIMV2', WbemUser, WbemPassword);

  FWbemObjectSet:= FWMIService.ExecQuery(Format('SELECT * FROM Win32_NetworkAdapterConfiguration Where Description="%s"',[NetworkCard]),'WQL',wbemFlagForwardOnly);
  oEnum         := IUnknown(FWbemObjectSet._NewEnum) as IEnumVariant;
  if oEnum.Next(1, FWbemObject, iValue) = 0 then
  begin
    vIpAddress   := VarArrayCreate([0, 0], varVariant);
    vIpAddress[0]:= IPAddress;
    vMask   := VarArrayCreate([0, 0], varVariant);
    vMask[0]:=  Mask;
    FOutParams:=FWbemObject.EnableStatic(vIpAddress, vMask);
    // 0 - Successful completion, no reboot required
    // 1 - Successful completion, reboot required
    Writeln(Format('EnableStatic ReturnValue  %s',[FOutParams]));

    vGateWays   := VarArrayCreate([0, 0], varVariant);
    vGateWays[0]:= GateWay;

    FOutParams:=FWbemObject.SetGateways(vGateWays);
    // 0 - Successful completion, no reboot required
    // 1 - Successful completion, reboot required
    Writeln(Format('SetGateways ReturnValue  %s',[FOutParams]));
  end
  else
  Writeln('Network card not found');
end;


begin
 try
    CoInitialize(nil);
    try
      SetStaticIpAddress('network device','192.168.1.1','255.255.255.0','192.168.1.2');
    finally
      CoUninitialize;
    end;
 except
    on E:EOleException do
        Writeln(Format('EOleException %s %x', [E.Message,E.ErrorCode]));
    on E:Exception do
        Writeln(E.Classname, ':', E.Message);
 end;
 Writeln('Press Enter to exit');
 Readln;
end.

注..ネットワークデバイス名を取得するには、ネットワーク接続リストを使用できます

ここに画像の説明を入力

于 2013-02-07T02:43:25.737 に答える