-1

次のコードを試しましたが、機能しません。1 つの文字列を取得し、その中に XSLT を記述して、XslCompiledTransform オブジェクトを読み込みます。

 <xsl:sequence select=
        "sum(//Item/(cost * related_id/Item/quantity))"/>

ソース XML:

<AML>
  <Item>
    <cost>
      40
    </cost>
    <related_id>
      <Item>
        <quantity>2</quantity>
      </Item>
    </related_id>
  </Item>
  <Item>
    <cost>
      50
    </cost>
    <related_id>
      <Item>
        <quantity>10</quantity>
      </Item>
    </related_id>
  </Item>
</AML>
4

1 に答える 1

0

コメントで述べたように、xsl:sequence使用しようとしている XPath 構文は XSLT 1.0 (XslCompiledTransform が使用する) では使用できませんが、再帰テンプレートを使用して式の合計を得ることができます。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" indent="yes"/>

  <xsl:template match="/">
    <xsl:call-template name="SumSet">
      <xsl:with-param name="items" select="/*/Item" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="SumSet">
    <xsl:param name="items" />

    <xsl:if test="$items">
      <xsl:variable name="currentValue">
        <xsl:apply-templates select="$items[1]" />
      </xsl:variable>
      <xsl:variable name="remainderSum">
        <xsl:call-template name="SumSet">
          <xsl:with-param name="items" select="$items[position() > 1]" />
        </xsl:call-template>
      </xsl:variable>

      <xsl:value-of select="$currentValue + $remainderSum"/>
    </xsl:if>
    <xsl:if test="not($items)">0</xsl:if>
  </xsl:template>

  <xsl:template match="Item">
    <xsl:value-of select="cost * related_id/Item/quantity"/>
  </xsl:template>
</xsl:stylesheet>

これを入力 XML で実行すると、結果は次のようになります。

580

それは一般的なアプローチですが、XslCompiledTransform を使用していると述べたので、msxsl:node-set()このタスクを少し簡略化するために使用できます。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:msxsl="urn:schemas-microsoft-com:xslt">
  <xsl:output method="text" indent="yes"/>

  <xsl:template match="/">
    <xsl:variable name="values">
      <xsl:apply-templates select="/*/Item" />
    </xsl:variable>

    <xsl:value-of select="sum(msxsl:node-set($values)/*)"/>
  </xsl:template>

  <xsl:template match="Item">
    <itemValue>
      <xsl:value-of select="cost * related_id/Item/quantity"/>
    </itemValue>
  </xsl:template>
</xsl:stylesheet>

これは580、入力 XML で実行したときにも値を生成します。

于 2013-02-07T13:10:05.190 に答える