3

私はERPのクリーンアップに取り組んでおり、未使用のユーザーとユーザーグループへの参照を削除する必要があります。外部キーの制約はたくさんあるので、すべての痕跡を本当に取り除くようにしたいのです！

特定の列名を持つデータベース内のすべてのテーブルを見つけるためのこの整然としたコードを見つけました。この場合、ユーザーグループを見てみましょう。

select table_name from information_schema.columns
where column_name = 'GROUP_ID'

結果を使用して、40以上のテーブルで未使用のIDを検索できます...しかし、これは面倒です。Unused_Groupしたがって、これを自動化して、これらすべてのテーブルをループし、列内で見つかった行を削除するクエリを作成したいと思いGROUP_IDます。

何かを削除する前に、既存のデータを視覚化したいので、文字列連結を使用して次のようなものを作成し始めました。

declare @group varchar(50) = 'Unused_Group'
declare @table1 varchar(50) = 'TABLE1'
declare @table2 varchar(50) = 'TABLE2'
declare @tableX varchar(50) = 'TABLEX'

select @query1 = 'SELECT ''' + rtrim(@table1)  + ''' as ''Table'', '''
+ rtrim(@group) + ''' = CASE WHEN EXISTS (SELECT GROUP_ID FROM ' + rtrim(@table1)
+ ' WHERE GROUP_ID = ''' + rtrim(@group) + ''') then ''MATCH'' else ''-'' end FROM '
+ rtrim(@table1)

select @query2 = [REPEAT FOR @table2 to @tableX]...

EXEC(@query1 + ' UNION ' + @query2 + ' UNION ' + @queryX)

これは私に結果を与えます：

TABLE1  |  Match
TABLE2  |  -
TABLEX  |  Match

これは私の目的のために機能し、他のコードを変更せずに任意のユーザーグループに対して実行できます。もちろんDELETE、これらの同じテーブルから簡単に適応できますが、ユーザーとユーザーの間で処理する必要がある75程度のテーブルでは管理できません。グループ。

動的SQLでこのリンクに遭遇しました。これは、今のところ私を怖がらせるほど強力で密度が高いものです...しかし、解決策はどこかにあるのではないかと思います。

私はFOR()JSや他の言語のループに非常に精通しており、これは適切に構造化された配列を備えた簡単なものですが、SQLではそれほど単純ではないようです（私はまだ学習中ですが、 FORおよびGOTOソリューションが利用可能です...）。理想的には、特定の列名を持つテーブルを検索するためにクエリを実行し、上記のように各テーブルをクエリし、一致するリストを吐き出してから、2番目の同様のスクリプトを実行して行を削除するスクリプトがあります。

誰かが私を正しい方向に向けるのを手伝ってもらえますか？

4

3 に答える 3

1

わかりました、これを試してみてください。3 つの変数があります。列、colValue、およびプレビュー。Column は、(Group_ID) の等価性をチェックしている列である必要があります。colValue は、探している値 (Unused_Group) であり、preview は、削除するものを表示するには 1 であり、削除するには 0 である必要があります。

Declare @column     Nvarchar(256),
        @colValue   Nvarchar(256),
        @preview    Bit

Set     @column     = 'Group_ID'        
Set     @colValue   = 'Unused_Group'
Set     @preview    = 1 -- 1 = preview; 0 = delete

If      Object_ID('tempdb..#tables') Is Not Null Drop Table #tables
Create  Table #tables (tID Int, SchemaName Nvarchar(256), TableName Nvarchar(256))

--      Get all the tables with a column named [GROUP_ID]
Insert  #tables
Select  Row_Number() Over (Order By s.name, so.name), s.name, so.name
From    sysobjects so
Join    sys.schemas s
        On  so.uid = s.schema_id
Join    syscolumns sc
        On  so.id = sc.id
Where   so.xtype = 'u'
And     sc.name = @column

Select  *
From    #tables

Declare @SQL Nvarchar(Max),
        @schema Nvarchar(256),
        @table Nvarchar(256),
        @iter Int = 1

--      As long as there are tables to look at keep looping
While   Exists (Select  1
                From    #tables)
Begin
        --      Get the next table record to look at
        Select  @schema = SchemaName,
                @table = TableName
        From    #tables
        Where   tID = @iter

        --      If the table we're going to look at has dependencies on tables we have not 
        --      yet looked at move it to the end of the line and look at it after we look 
        --      at it's dependent tables (Handle foreign keys)
        If      Exists (Select  1
                        From    sysobjects o
                        Join    sys.schemas s1
                                On  o.uid = s1.schema_id
                        Join    sysforeignkeys fk
                                On  o.id = fk.rkeyid
                        Join    sysobjects o2
                                On  fk.fkeyid = o2.id
                        Join    sys.schemas s2
                                On  o2.uid = s2.schema_id
                        Join    #tables t
                                On  o2.name = t.TableName Collate Database_Default
                                And s2.name = t.SchemaName Collate Database_Default
                        Where   o.name = @table
                        And     s1.name = @schema)
        Begin
                --      Move the table to the end of the list to retry later
                Update  t
                Set     tID = (Select Max(tID) From #tables) + 1
                From    #tables t
                Where   tableName = @table
                And     schemaName = @schema

                --      Move on to the next table to look at
                Set     @iter = @iter + 1
        End
        Else
        Begin
                --      Delete the records we don't want anymore
                Set     @Sql =  Case
                                When    @preview = 1 
                                Then    'Select * ' -- If preview is 1 select from table
                                Else    'Delete t ' -- If preview is not 1 the delete from table
                                End +
                                'From    [' + @schema + '].[' + @table + '] t
                                Where   ' + @column + ' = ''' + @colValue + ''''

                Exec    sp_executeSQL @SQL;

                --      After we've done the work remove the table from our list
                Delete  t
                From    #tables t
                Where   tableName = @table
                And     schemaName = @schema

                --      Move on to the next table to look at
                Set     @iter = @iter + 1

        End
End

これをストアド プロシージャに変換するには、上部の変数宣言を sproc の作成に変更するだけなので、削除できます...

Declare @column     Nvarchar(256),
        @colValue   Nvarchar(256),
        @preview    Bit

Set     @column     = 'Group_ID'        
Set     @colValue   = 'Unused_Group'
Set     @preview    = 1 -- 1 = preview; 0 = delete
...

そして、それを交換してください...

Create  Proc DeleteStuffFromManyTables (@column Nvarchar(256), @colValue Nvarchar(256), @preview Bit = 1)
As
...

そして、あなたはそれを呼び出すでしょう...

Exec    DeleteStuffFromManyTable 'Group_ID', 'Unused_Group', 1

コードが何をしているのかを理解できるように、コード全体にコメントを付けました。幸運を！

于 2013-02-11T21:37:15.263 に答える
0

可能であれば、参照整合性を追加し、カスケード削除を適用することを検討してください。データを削除する前にデータを視覚化することはできませんが、孤立した行を制御することはできます。

于 2013-02-11T21:30:52.913 に答える
0

あなたはINFORMATION_SCHEMAオブジェクトで正しい軌道に乗っています。クエリ エディターで以下を実行すると、値を持つ列を含むテーブルのステートメントが生成SELECTされます。DELETEGROUP_ID'Unused_Group'

-- build select DML to manually review data that will be deleted
SELECT 'SELECT * FROM [' + TABLE_SCHEMA + '].[' + TABLE_NAME + '] WHERE [GROUP_ID] = ''Unused_Group'';'
FROM INFORMATION_SCHEMA.COLUMNS
WHERE COLUMN_NAME = 'GROUP_ID';

-- build delete DML to remove data
SELECT 'DELETE FROM [' + TABLE_SCHEMA + '].[' + TABLE_NAME + '] WHERE [GROUP_ID] = ''Unused_Group'';'
FROM INFORMATION_SCHEMA.COLUMNS
WHERE COLUMN_NAME = 'GROUP_ID';

これは 1 回限りのクリーンアップ作業であるように思われ、特にデータを削除する前に確認する必要があるため、これを複雑にする価値はないと思います。

于 2013-02-11T20:59:59.653 に答える