5

単純な SOAP XML メッセージをより拡張された SOAP XML メッセージに変換しています。ほぼ動作するようになりましたが、最後の 2 つの問題を修正できません。私の問題は次のとおりです。

  1. 要素の後のすべての要素は、CDATA セクションにある必要があります。「cdata-section-elements」を使用しようとしましたが、機能しません。
  2. 要素は次のようになります

私のソース XML ファイル:

<?xml version="1.0" encoding="utf-8"?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
  <SOAP-ENV:Header/>
  <SOAP-ENV:Body>
    <test>
      <element1>123</element1>
      <element2>123</element2>
    </test>
  </SOAP-ENV:Body>
</SOAP-ENV:Envelope>

私のXSLT：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions" xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" exclude-result-prefixes="fn xs SOAP-ENV">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

<!-- Special rule to match the document root only -->
<xsl:template match="/*">
    <s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope">
        <xsl:namespace name="a" select="'http://www.w3.org/2005/08/addressing'"/>
        <xsl:apply-templates select="@*|node()"/>
    </s:Envelope>
</xsl:template>

<!-- Expand soap header -->
<xsl:template match="SOAP-ENV:Header">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="a:Action" namespace="http://www.w3.org/2005/08/addressing">
            <xsl:attribute name="s:mustUnderstand" namespace="http://www.w3.org/2003/05/soap-envelope">1</xsl:attribute>
            <xsl:text>http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</xsl:text>
        </xsl:element>
    </xsl:element>
</xsl:template>

<!-- Change soap body -->
<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="cais:SendMessage" namespace="http://www.ortec.com/CAIS">
            <xsl:element name="cais:message" namespace="http://www.ortec.com/CAIS">
                <!-- copy the rest -->
                <xsl:apply-templates select="child::node()"/>
            </xsl:element>
            <xsl:element name="cais:commandName" namespace="http://www.ortec.com/CAIS">Import</xsl:element>
        </xsl:element>
    </xsl:element>
</xsl:template>

<!-- template for the copy of the rest -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

この XSLT で受信した間違った出力:

<?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:a="http://www.w3.org/2005/08/addressing" xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header>
    <a:Action s:mustUnderstand="1">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action>
  </s:Header>
  <s:Body>
    <cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS">
      <cais:message>
        <test xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
          <element1>123</element1>
          <element2>123</element2>
        </test>
      </cais:message>
      <cais:commandName>Import</cais:commandName>
    </cais:SendMessage>
  </s:Body>
</s:Envelope>

私の望ましい出力：

<?xml version="1.0" encoding="UTF-8"?>
<s:Envelope xmlns:a="http://www.w3.org/2005/08/addressing" xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header>
    <a:Action s:mustUnderstand="1">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action>
  </s:Header>
  <s:Body>
    <cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS">
      <cais:message>
        <![CDATA[
        <test>
          <element1>123</element1>
          <element2>123</element2>
        </test>
        ]]>
      </cais:message>
      <cais:commandName>Import</cais:commandName>
    </cais:SendMessage>
  </s:Body>
</s:Envelope>
4

2 に答える 2

8

次のように動作しますか?:

<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}" namespace="http://www.w3.org/2003/05/soap-envelope">
        <xsl:element name="cais:SendMessage" namespace="http://www.ortec.com/CAIS">
            <xsl:element name="cais:message" namespace="http://www.ortec.com/CAIS">
                <!-- copy the rest -->
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
                <xsl:apply-templates select="child::node()"/>
                <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
            </xsl:element>
            <xsl:element name="cais:commandName" namespace="http://www.ortec.com/CAIS">Import</xsl:element>
        </xsl:element>
    </xsl:element>
</xsl:template>

この方法で XSLT を変更し、サンプル入力で実行すると、次のようになります。

<s:Envelope xmlns:s="http://www.w3.org/2003/05/soap-envelope">
  <s:Header><a:Action s:mustUnderstand="1" xmlns:a="http://www.w3.org/2005/08/addressing">http://www.ortec.com/CAIS/IApplicationIntegrationService/SendMessage</a:Action></s:Header>
  <s:Body><cais:SendMessage xmlns:cais="http://www.ortec.com/CAIS"><cais:message>
  <![CDATA[
    <test xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/">
      <element1>123</element1>
      <element2>123</element2>
    </test>
  ]]>
  </cais:message>
  <cais:commandName>Import</cais:commandName></cais:SendMessage></s:Body>
</s:Envelope>

名前空間宣言はまだそこにありますが、それはあまり重要ではありません。

の名前空間宣言を本当に取り除きたい場合は<test>、ID テンプレートを次のように置き換えることができます。

  <xsl:template match="@* | node()" priority="-2">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="*">
    <xsl:element name="{name()}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>

動作することを確認しました。

余談ですが、事前に要素のプレフィックスと名前がわかっている場合は、xsl:elementornamespace属性を使用する必要はありません。要素で名前空間を宣言する場合xsl:spreadsheet:

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
                   xmlns:xs="http://www.w3.org/2001/XMLSchema" 
                   xmlns:fn="http://www.w3.org/2005/xpath-functions" 
                   xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" 
                   xmlns:s="http://www.w3.org/2003/05/soap-envelope"
                   xmlns:cais="http://www.ortec.com/CAIS"
                   exclude-result-prefixes="fn xs SOAP-ENV cais">

次に、これを行うことができます：

<xsl:template match="SOAP-ENV:Body">
    <xsl:element name="s:{local-name()}">
        <cais:SendMessage>
            <cais:message>
                <!-- copy the rest -->
                <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
                <xsl:apply-templates select="child::node()"/>
                <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
            </cais:message>
            <cais:commandName>Import</cais:commandName>
        </cais:SendMessage>
    </xsl:element>
</xsl:template>
于 2013-02-13T10:57:06.817 に答える
1

要素で使用copy-namespace="no"して、xsl:copy-of要素内の名前空間の境界を回避しtestます。

<xsl:template match="SOAP-ENV:Body">
 <xsl:element name="s:{local-name()}">
   <xsl:element name="cais:SendMessage">
   <xsl:element name="cais:message">
   <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
   <xsl:copy-of select="test" copy-namespaces="no"/>
   <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
  </xsl:element>
  <xsl:element name="cais:commandName"><xsl:text>Import</xsl:text>
</xsl:element>
  </xsl:element>
 </xsl:element>
</xsl:template>
</xsl:stylesheet>
于 2016-07-13T10:20:32.947 に答える