1

プログラムのほとんどのデータをロードするxml構造があります。この場合、xml で指定されたクラスをインスタンス化します。クラスの名前をxmlに記述し、インスタンス化してパラメーターを渡すことができると考えました。それほど簡単ではないことが判明しました！

私はこのようなコードを試しました:

            //special objects
        for each (o in xml.Objects[0].special) 
        { 
            p.x = o.@x;
            p.y = o.@y;
            s.x = o.@width;
            s.y = o.@height;
            trace(o.@classname);
            //var type:Class = o.@classname as Class;
            var type:Class = getDefinitionByName(String(o.@classname)) as Class;

            trace(type);
            objectArray.push(new type(p, s)); 
            trace("special");
        }

ご覧のとおり、xml-file の classname 属性にクラスの名前があります。getDefinitionByName で定義を取得できました (少なくとも次のトレースでは正しいクラス名が表示されます) が、それをインスタンス化して配列にプッシュしようとすると、エラーの山が発生します。

エラー #2136: SWF ファイル file:///Users/tuomas/Dropbox/Flash/ScorpionBox/bin-debug/ScorpionBox.swf に無効なデータが含まれています。

どうすればいいですか？

4

1 に答える 1

4

XML 型定義が によって取得された修飾名で構成されていると仮定してgetQualifiedClassName()、型をインスタンス化し、必要に応じてプロパティを適用します。

xml で定義された表示オブジェクトのインスタンス化の例:

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class XmlParser extends Sprite
    {
        public var xml:XML = <objects>
                                <object type="flash.display::Sprite" x="0" y="0" width="100" height="100" />
                                <object type="flash.display::MovieClip" x="0" y="0" width="100" height="100" />
                             </objects>;

        public function XmlParser()
        {
            for each (var object:XML in xml.children())
            {
                var type:Class = getDefinitionByName(object.@type) as Class;
                var instance:DisplayObject = new type();
                instance.x = object.@x;
                instance.y = object.@y;
                instance.width = object.@width;
                instance.height = object.@height;

                addChild(instance);
            }
        }
    }
}

また、XML にシリアル化されたときに Type オブジェクトを記述し、次のように XML の属性を繰り返してプロパティをオブジェクト インスタンスに適用することもできます。

package
{
    import flash.display.DisplayObject;
    import flash.display.Sprite;
    import flash.utils.getDefinitionByName;

    public class XmlParser extends Sprite
    {
        public var xml:XML = <objects>
                                <object type="flash.display::Sprite" x="0" y="0" width="100" height="100" />
                                <object type="flash.display::MovieClip" x="0" y="0" width="100" height="100" />
                             </objects>;

        public function XmlParser()
        {
            for each (var object:XML in xml.children())
            {
                var type:Class = getDefinitionByName(object.@type) as Class;
                var instance:DisplayObject = new type();
                addChild(instance);

                for each (var attribute:XML in object.@*)
                {
                    if(attribute.name() == "type") { continue; }

                    trace("setting: " + attribute.name() + " = " + attribute.toXMLString());
                    instance[attribute.name().toString()] = attribute.toXMLString();
                }
            }
        }
    }
}
于 2013-02-17T21:36:35.000 に答える