delphi - Delphi 6でbase64をエンコードするには?

Question

Delphi6 で PDF ドキュメントを base64 にエンコードする必要があります。誰でも私を助けることができますか？

Answer 1

EncdDecdDelphi に付属のユニットを使用できます。必要な機能はEncodeStream. 入力用と出力用の 2 つのストリームを作成するだけです。ファイルを操作している場合は、TFileStreamインスタンスを作成する必要があります。

2 つのファイル ストリームを作成したら、必要なのは次のとおりです。

EncodeStream(InputStream, OutputStream);

Answer 2

unit base64;

interface

uses Classes;

function base64encode(f:TStream):string;

implementation

const
  Base64Codes:array[0..63] of char=
    'ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/';

function base64encode(f:TStream):string;
const
  dSize=57*100;//must be multiple of 3
var
  d:array[0..dSize-1] of byte;
  i,l:integer;
begin
  Result:='';
  l:=dSize;
  while l=dSize do
   begin
    l:=f.Read(d[0],dSize);
    i:=0;
    while i<l do
     begin
      if i+1=l then
        Result:=Result+
          Base64Codes[  d[i  ] shr  2]+
          Base64Codes[((d[i  ] and $3) shl 4)]+
          '=='
      else if i+2=l then
        Result:=Result+
          Base64Codes[  d[i  ] shr  2]+
          Base64Codes[((d[i  ] and $3) shl 4) or (d[i+1] shr 4)]+
          Base64Codes[((d[i+1] and $F) shl 2)]+
          '='
      else
        Result:=Result+
          Base64Codes[  d[i  ] shr  2]+
          Base64Codes[((d[i  ] and $3) shl 4) or (d[i+1] shr 4)]+
          Base64Codes[((d[i+1] and $F) shl 2) or (d[i+2] shr 6)]+
          Base64Codes[  d[i+2] and $3F];
      inc(i,3);
      if ((i mod 57)=0) then Result:=Result+#13#10;
     end;
   end;
end;

end.

Answer 3

INDYのTIdEncoderMIMEクラスを使用して、任意のファイルをエンコードできます。

知る限り、INDY 9 は Delphi 6 にプリインストールされていますが、INDY 10 は古い INDY 9 に対して多くの改善とバグ修正が行われているため、INDY バージョンを更新することをお勧めします。

コードは次のようになります。

uses IdCoder, IdCoder3to4, IdCoderMIME, IdBaseComponent;

procedure TForm1.Button1Click(Sender: TObject);
var
  SourceStr: TFileStream;
  Encoder: TIdEncoderMIME;
begin
  if OpenDialog1.Execute then
  begin
    SourceStr := TFileStream.Create(OpenDialog1.FileName, fmOpenRead);
    try
      Encoder := TIdEncoderMIME.Create(nil);
      try
        Memo1.Lines.Text := Encoder.Encode(SourceStr);
      finally
        Encoder.Free;
      end;
    finally
      SourceStr.Free;
    end;
  end;
end;