12

ExcelなしのPCで起動できるため、プログラムからExcelOLEを使用できるかどうかをテストする必要があります。ネット上のコードサンプルは、Excelがインストールされていることを前提としていますが、インストールされていない場合はどうなりますか？

XLApp := CreateOleObject('Excel.Application');
try
  // Hide Excel
  XLApp.Visible := False;
  // Open the Workbook
  XLApp.Workbooks.Open(aPath);
  ...snip...
finally
  // Quit Excel
  if not VarIsEmpty(XLApp) then
  begin
    XLApp.Quit;
    XLAPP := Unassigned;
  end;
end;

Excelがインストールされているかどうかを確認するための正しいコードでしょうか？

//Try to create Excel OLE
try
  XLApp := CreateOleObject('Excel.Application');
except
  ShowMessage('Error opening Excel');
  Exit;
end;
4

1 に答える 1

17

Scalabiumのヒントに基づくコードを使用して、Excelが使用可能かどうかを確認できます。または次のようなもの：

uses ComObj, ActiveX;

function IsObjectAvailable(const ClassName: string): Boolean;
var
  ClassID: TCLSID;
begin
  Result := Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), 
    ClassID));
end;

次のコードを使用して、Excelが実行されているかどうかを確認することもできます。

function IsObjectActive(const ClassName: string): Boolean;
var
  ClassID: TCLSID;
  Unknown: IUnknown;
begin
  Result := False;
  if Succeeded(CLSIDFromProgID(PWideChar(WideString(ClassName)), ClassID)) then
    Result := Succeeded(GetActiveObject(ClassID, nil, Unknown));
end;

そして、いくつかの手順またはイベントで：

procedure TForm1.Button1Click(Sender: TObject);
begin
  if IsObjectAvailable('Excel.Application') then 
    ShowMessage('Excel is available');
  if IsObjectActive('Excel.Application') then 
    ShowMessage('Excel is running');
end;
于 2013-02-22T07:36:24.930 に答える