1

ルート要素内にposten要素の階層があります。

<gliederung>
    <posten id=".." order="1">
        <posten id=".." order"1">
            <posten id=".." order"1">
                 ...
            </posten>
            <posten id="AB" order"2">
                 ...
            </posten>
             ...
        </posten>
        <posten id=".." order"2">
             ...
        </posten>
        <posten id="XY" order"3">
             ...
        </posten>
     ....   
</gliederung>

各postenには、一意のIDと注文属性があります。次に、IDが「AB」の要素の前にIDが「XY」の要素を移動し、移動した要素「XY」の順序属性を「1.5」に変更する必要があります。

次のスクリプトで要素を移動することができました。

 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
 </xsl:template>

<xsl:template match="posten[@id='AB']">
     <xsl:copy-of select="../posten[@id='XY']"/>
     <xsl:call-template name="identity"/>
 </xsl:template>

<xsl:template match="posten[@id='XY']"/>

しかし、移動と注文属性値を「1.5」に変更する方法を組み合わせるにはどうすればよいでしょうか。

明らかな何かが欠けていると思います...

4

1 に答える 1

1

の代わりにcopy-of、テンプレートを使用してください

 <!-- almost-identity template, that does not apply templates to the
      posten[@id='XY'] -->
 <xsl:template match="node()|@*" name="identity">
     <xsl:copy>
        <xsl:apply-templates select="node()[not(self::posten[@id='XY'])]|@*"/>
    </xsl:copy>
 </xsl:template>

<xsl:template match="posten[@id='AB']">
     <!-- apply templates to the XY posten - this will copy it using the
          "identity" template above but will allow the specific template
          for its order attr to fire -->
     <xsl:apply-templates select="../posten[@id='XY']"/>
     <xsl:call-template name="identity"/>
 </xsl:template>

<!-- fix up the order value for XY -->
<xsl:template match="posten[@id='XY']/@order">
  <xsl:attribute name="order">1.5</xsl:attribute>
</xsl:template>

XYポステンがABポステンに対して正確にどこにあるかわからない場合（つまり、常にある../posten[@id='XY']か、場合によってはある可能性があります../../）、次のように定義できます。

<xsl:key name="postenById" match="posten" use="@id" />

<xsl:apply-templates select="../posten[@id='XY']"/>次に、をに置き換えます

<xsl:apply-templates select="key('postenById', 'XY')"/>
于 2013-02-22T12:30:40.397 に答える