1

次の入力があります。

<nodes>
    <node>  
        <type>A</type>  
        <val>1000</val>  
    </node>  
    <node>  
        <type>B</type>  
        <val>2000</val>  
    </node>  
    <node>  
        <type>A</type>  
        <val>3000</val>  
    </node>  
</nodes>

私の目標は、一意の型のリストを取得し、それらの値をすべて合計することです。次の出力が得られます。 

<nodes>  
    <node>  
        <type>A</type>  
        <sum>10003000</sum>  
    </node>  
    <node>  
        <type>B</type>  
        <sum>2000</sum>  
    </node>  
</nodes>

(タイプ A の場合) 4000 の合計を期待していましたが、代わりに 10003000 を取得しています。

これが私のxsltです： 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">  
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>  
    <xsl:key name="type" match="/nodes/node/type/text()" use="." />
    <xsl:template match="/">
        <nodes>
            <xsl:for-each select="/nodes/node/type/text()[generate-id()=generate-id(key('type',.)[1])]">
                <node>
                    <xsl:variable name="t" select="."/>
                    <type><xsl:value-of select="$t"/></type>
                    <sum>
                        <xsl:for-each select="/nodes/node[type=$t]">
                            <xsl:value-of select="sum(number(Value))"/>
                        </xsl:for-each>
                    </sum>
                </node>
            </xsl:for-each>
        </nodes>
    </xsl:template>
</xsl:stylesheet>

探している結果を得るにはどうすればよいですか? また、合計される値の一部には、区切り記号としてコンマが含まれています (例: 1,000)。私の知る限り、 sum() はコンマを処理しません。これらの懸念にどのように対処すればよいですか?

4

1 に答える 1

0

置き換えるだけです：

<sum>
  <xsl:for-each select="/nodes/node[type=$t]">
    <xsl:value-of select="sum(number(Value))"/>
  </xsl:for-each>
</sum>

と:

<sum><xsl:value-of select="sum(/nodes/node[type=$t]/val)"/></sum>

完全な変換は次のとおりです。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kType" match="type" use="."/>

 <xsl:template match="type[generate-id()=generate-id(key('kType',.)[1])]">
  <type><xsl:value-of select="."/></type>
  <sum><xsl:value-of select="sum(key('kType',.)/../val)"/></sum>
 </xsl:template>
 <xsl:template match="text()"/>
</xsl:stylesheet>

この変換が提供された XML ドキュメントに適用されると、次のようになります。

<nodes>
    <node>
        <type>A</type>
        <val>1000</val>
    </node>
    <node>
        <type>B</type>
        <val>2000</val>
    </node>
    <node>
        <type>A</type>
        <val>3000</val>
    </node>
</nodes>

必要な正しい結果が生成されます。

<type>A</type>
<sum>4000</sum>
<type>B</type>
<sum>2000</sum>

更新：

OP には新しい要件が追加されました。数値にはコンマを含めることができます。

以下のソリューションは、2 パス変換を実行します。最初のパスは、任意のval/text()ノード内の数字以外の文字を削除します。

2 番目のパスは 1 番目のパスの結果に作用し、基本的には最初の質問に対する解です。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common" exclude-result-prefixes="ext">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:key name="kType" match="type" use="."/>

 <xsl:variable name="vrtfPass1">
  <xsl:apply-templates select="/*"/>
 </xsl:variable>

 <xsl:variable name="vPass1" select="ext:node-set($vrtfPass1)"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="/">
  <xsl:apply-templates mode="pass2" select=
   "$vPass1/*/*/type[generate-id()=generate-id(key('kType',.)[1])]"/>
 </xsl:template>

 <xsl:template match="val/text()[true()]">
  <xsl:value-of select="translate(., translate(.,'01234567890', ''), '')"/>
 </xsl:template>

 <xsl:template match="type" mode="pass2">
  <type><xsl:value-of select="."/></type>
  <sum><xsl:value-of select="sum(key('kType',.)/../val)"/></sum>
 </xsl:template>
</xsl:stylesheet>

この変換が次の XML ドキュメントに適用された場合 (提供されたものにカンマを追加):

<nodes>
    <node>
        <type>A</type>
        <val>1,000</val>
    </node>
    <node>
        <type>B</type>
        <val>2000</val>
    </node>
    <node>
        <type>A</type>
        <val>3000</val>
    </node>
</nodes>

必要な正しい結果が生成されます。

<type>A</type>
<sum>4000</sum>
<type>B</type>
<sum>2000</sum>
于 2013-02-24T06:08:19.167 に答える