0

  • 入力ファイル 1: file1.txt
    MH=919767, 918975
    DL= 919922
    HR=919891,919394,919812
    KR=919999,918888

  • 入力ファイル 2: file2.txt
    aec,919922783456,a5,b3,,,asf
    abc,918975583456,a1,b1,,,abf
    aeci,919998546783,a2,b4,,,wsf

  • 出力ファイル
    aec,919922783456,a5,b3, DL ,,asf
    abc,918975583456,a1,b1, MH ,,abf
    aeci,919998546783,a2,b4, NOMATCH ,,wsf

  • ノート

    • 入力ファイル1.txt-2番目のフィールド内の電話番号（入力ファイル2.txt-2番目のフィールド-最初の6桁のみ）を「=」で区切って比較する必要があります。電話番号の最初の 6 桁が一致する場合、OUTPUT にはファイル (入力ファイル 1) からの 2 桁のコードが含まれ、5 番目のフィールドに出力されます。
    • File1.txt には、複数の電話番号の頭文字を表す単一のコード(MH など) があります。
4

2 に答える 2

1

がある場合はGNU awk、次のことを試してください。次のように実行します。

awk -f script.awk file1.txt file2.txt

の内容script.awk:

BEGIN {
     FS="[=,]"
     OFS=","
}

FNR==NR {
    for(i=2;i<=NF;i++) {
        a[$1][$i]
    }
    next
}

{
    $5 = "NOMATCH"
    for(j in a) {
        for (k in a[j]) {
            if (substr($2,0,6) == k) {
                $5 = j
            }
        }
    }
}1

または、ここにワンライナーがあります：

awk -F "[=,]" 'FNR==NR { for(i=2;i<=NF;i++) a[$1][$i]; next } { $5 = "NOMATCH"; for(j in a) for (k in a[j]) if (substr($2,0,6) == k) $5 = j }1' OFS=, file1.txt file2.txt

結果：

aec,919922783456,a5,b3,DL,,asf
abc,918975583456,a1,b1,MH,,abf
aeci,919998546783,a2,b4,NOMATCH,,wsf

'old' がある場合はawk、次のことを試してください。次のように実行します。

awk -f script.awk file1.txt file2.txt

script.awk の内容:

BEGIN {
     # set the field separator to either an equals sign or a comma
     FS="[=,]"
     # set the output field separator to a comma
     OFS=","
}

# for the first file in the arguments list
FNR==NR {
    # loop through all the fields, starting at field two
    for(i=2;i<=NF;i++) {

        # add field one and each field to a pseudo-multidimensional array
        a[$1,$i]
    }

    # skip processing the rest of the code
    next
}


# for the second file in the arguments list
{
    # set the default value for field 5
    $5 = "NOMATCH"

    # loop though the array
    for(j in a) {

        # split the array keys into another array
        split(j,b,SUBSEP)

        # if the first six digits of field two equal the value stored in this array
        if (substr($2,0,6) == b[2]) {

            # assign field five 
            $5 = b[1]
        }
    }

# return true, therefore print by default
}1

または、ここにワンライナーがあります：

awk -F "[=,]" 'FNR==NR { for(i=2;i<=NF;i++) a[$1,$i]; next } { $5 = "NOMATCH"; for(j in a) { split(j,b,SUBSEP); if (substr($2,0,6) == b[2]) $5 = b[1] } }1' OFS=, file1.txt file2.txt

結果：

aec,919922783456,a5,b3,DL,,asf
abc,918975583456,a1,b1,MH,,abf
aeci,919998546783,a2,b4,NOMATCH,,wsf
于 2013-02-24T09:02:54.027 に答える
1

次のようなものを試してください：

awk '
  NR==FNR{
    for(i=2; i<=NF; i++) A[$i]=$1
    next
  } 
  {
    $5="NOMATCH"
    for(i in A) if ($2~"^" i) $5=A[i]
  } 
  1
' FS='[=,]' file1 FS=, OFS=, file2
于 2013-02-24T07:51:45.897 に答える