0

無効になっているチェックボックスにツールチップを表示できるようにする必要があります。ここでスタックオーバーフローや他の場所で見た解決策は、チェックボックスをグループでラップし、グループにツールチップを与えることです。これはうまくいきますが、私はこれを一般的にやろうとしています。

カスタム Checkbox コンポーネントにプロパティを設定し、その時点で、toolTip が設定された Group に Chexbox をラップできるようにしたいと考えています。

私の問題は、Checkbox ActionScript コードで、実行時にチェックボックスをグループ コンポーネントに追加する方法がわからないことです。チェックボックス クラスに showDisabledToolTip プロパティを追加しようとしましたが、それが設定されている場合は次のようにします。

var parent = this.parent;
    var gp:Group = new Group();
    gp.toolTip = this.toolTip;
    gp.addElement(this);
    if(parent is Group) {
        parent.addElement(gp);
    } else {
        parent.addChild(gp);
    }

その時点での私の主な問題は、this.parent が null であることです。それ以外に、これが本当にうまくいくかどうかさえわかりません。

助けていただければ幸いです。ありがとう！

4

1 に答える 1

0

CheckBox クラスを拡張し、内部に 2 つの新しい SkinStates (disabledWithTooltip および disabledWithTooltipSelected) を持つ新しい CheckBoxSkin を作成するソリューションを思いつきました。

拡張された Checkbox クラスは、新しい disabledWithTooltip プロパティを追加し、getCurrentSkinState メソッドと ButtonBase の mouseEventHandler をオーバーライドします。

カスタム CheckBox クラス


package components
{

    import flash.events.Event;
    import flash.events.MouseEvent;

    import mx.events.FlexEvent;

    import spark.components.CheckBox;

    [SkinState (disabledWithToolTip)]
    [SkinState (disabledWithToolTipSelected)]

    public class CustomCheckBox extends CheckBox
    {
        private var _disabledKeepToolTip:Boolean = false;

        public function CustomCheckBox()
        {
            super();
            this.addEventListener(FlexEvent.CREATION_COMPLETE, onCreationComplete, false, 0, true);
        }

        protected function onCreationComplete(ev:FlexEvent):void {
            //_storedState = this.currentState;
        }


        protected override function getCurrentSkinState():String {
            if(!_disabledKeepToolTip)
                return super.getCurrentSkinState();
            else {
                if(!selected)
                    return "disabledWithToolTip";
                else 
                    return "disabledWithToolTipSelected";
            }
        }

        protected override function mouseEventHandler(event:Event):void {
            var skinState:String = getCurrentSkinState();

            if(skinState != "disabledWithToolTip" && skinState != "disabledWithToolTipSelected") {
                super.mouseEventHandler(event);
            }
        }
        [Bindable]
        [Inspectable(category="General", enumeration="true,false", defaultValue="true")]
        public function get disabledKeepToolTip():Boolean {
            return _disabledKeepToolTip;
        }

        public function set disabledKeepToolTip(value:Boolean):void {

            _disabledKeepToolTip = value;

            this.invalidateSkinState();
        }

    }
}

(spark) CheckBoxSkin に基づいて新しいスキンを作成し、メタデータのホスト コンポーネントを変更します。

[HostComponent("components.CustomCheckBox")]

2 つの新しい skinStates を追加します

<s:State name="disabledWithToolTip" stateGroups="disabledStates" />
<s:State name="disabledWithToolTipSelected" stateGroups="disabledStates, selectedStates" />

使用例

<s:HGroup>
    <components:CustomCheckBox id="custom_chk" label="KeepTooltipCheckbox" skinClass="skins.CustomCheckBoxSkin" toolTip="See this tooltip"/>
    <s:CheckBox id="enable_chk" label="enable/disable" change="{custom_chk.disabledKeepToolTip = enable_chk.selected}"/>
</s:HGroup>

異なる場合は、独自のパッケージ構造を調整する必要があります...

于 2013-03-01T10:59:52.497 に答える