perl - これをawkまたはshellで実装する方法は？

Question

入力ファイル1：

5 5 NA
NA NA 1
2 NA 2

入力ファイル2：

1 1 1
2 NA 2
3 NA NA
NA 4 4
5 5 5
NA NA 6

出力：

3 NA NA
NA 4 4
NA NA 6

目的は次のとおりです。file1で、セットに含まれていない各行の項目をNA設定し、次にfile2で、フィールドがこのセット内にある行を削除します。誰かがこれについてアイデアを持っていますか？

Answer 1

'NA'以外のアイテムを追加するには：

awk -f script.awk file1 file2

内容script.awk：

FNR==NR {
    for (i=1;i<=NF;i++) {
        if ($i != "NA") {
            a[$i]++
        }
    }
    next
}

{
    for (j=1;j<=NF;j++) {
        if ($j in a) {
            next
        }
    }
}1

結果：

3 NA NA
NA 4 4
NA NA 6

または、これがワンライナーです。

awk 'FNR==NR { for (i=1;i<=NF;i++) if ($i != "NA") a[$i]++; next } { for (j=1;j<=NF;j++) if ($j in a) next }1' file1 file2

Answer 2

あなたはこれを行うことができますgrep：

$ egrep -o '[0-9]+' file1 | fgrep -wvf - file2
3 NA NA
NA 4 4
NA NA 6

Answer 3

awkワンライナー：

 

awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2

あなたのデータで：

kent$  awk 'NR==FNR{for(i=1;i<=NF;i++)if($i!="NA"){a[$i];break;} next}{for(i=1;i<=NF;i++)if($i in a)next;}1' file1 file2
3 NA NA
NA 4 4
NA NA 6

Answer 4

値の列の位置が重要な場合：

awk '
  NR==FNR{
    for(i=1; i<=NF; i++) if($i!="NA") A[i,$i]=1
    next
  }
  {
    for(i=1; i<=NF; i++) if($i!=NA && A[i,$i]) next
    print 
  }
' file1 file2