2

私は XSLT の初心者で、結果を達成するのに苦労しています。誰かが私を助けてくれる場合に備えてここに来ました。

次の XML があります。

<funds>
    <bags>
        <bag name="BAG_USD_MAIN" value="10.0" type="USD">
            <pockets>
                <pocket name="bank" value="7.5">
                <pocket name="award" value="2.5">
            </pockets>
         </bag>
        <bag name="BAG_USD_SAVINGS" value="290.75" type="USD">
            <pockets>
                <pocket name="bank" value="290.75">
            </pockets>
         </bag>
        <bag name="BAG_EUR_EXTRA" value="890.0" type="EUR">
            <pockets>
                <pocket name="bank" value="753.0">
                <pocket name="bank_eng" value="137.0">
            </pockets>
         </bag>
    </bags>
 </funds>

そして、私はそれをこのように変換できるようにしたいと思います:

<result>
    <total type="USD">375.0</total>
    <total type="EUR">890.0</total>
</result>

XSLTで可能ですか？

よろしくお願いします TS

4

2 に答える 2

3

XSLT 2.0を使用しているため、<xsl:for-each-group> 要素を使用して要素を @type でグループ化し、sum() を使用してグループ内の要素を合計できます。

次のスタイルシートは、あなたがしようとしていることを解決します:

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/>


    <!-- Match the bags element  -->
    <xsl:template match="bags">
        <result>
            <!-- Group each bag element by its type -->
            <xsl:for-each-group select="bag" group-by="@type">
                <!-- Use the current key to display the type attribute -->
                <total type="{current-grouping-key()}">
                    <!-- Sum all the elements from the current group -->
                    <xsl:value-of select="sum(current-group()/@value)" />
                </total>
            </xsl:for-each-group>
        </result>
    </xsl:template>

</xsl:stylesheet>

完全を期すために、XSLT 1.0ソリューションは Muenchian Grouping に基づいています。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" encoding="UTF-8" indent="yes"/>

    <!-- Index all bag elements withing bags element using their
         type attribute by using a key -->
    <xsl:key name="currency-key"
             match="/funds/bags/bag"
             use="@type" />

    <!-- Match bags element -->
    <xsl:template match="bags">
        <result>
            <!-- Match the first bag element for a specific group -->
            <xsl:apply-templates select="bag[generate-id() = generate-id(key('currency-key', @type)[1])]" />
        </result>
    </xsl:template>

    <xsl:template match="bag">
        <total type="{@type}">
            <!-- Sum all the elements from the @type group -->
            <xsl:value-of select="sum(key('currency-key', @type)/@value)" />
        </total>
    </xsl:template>

</xsl:stylesheet>
于 2013-02-27T13:08:08.877 に答える
0

はい。XSLTプロセッサは手元にありませんが、次のようなものを試してください。

<result>
  <xsl:for-each select="distinct-values(//bag/@type)">
    <total type="."><xsl:value-of select="sum(//bag[@type = .])"/></total>
  </xsl:for-each>
</result>

大量のデータについては、<xsl:for-each-group>代わりに使用を検討する必要があります。

于 2013-02-27T13:05:04.797 に答える