0

私が（残念ながら）使用しなければならないソフトウェアは、複数のデータセット（「ドキュメント1」、「ドキュメント2」などを参照）を含むXMLファイルを生成しますが、ラッピング<document>タグで区切ることはありません。次のようになります。

<print>
    <section>
        <col1>*****</col1>
        <col2>Document 1</col2>
    </section>
    <section>
        <col1>Title</col1>
        <col2>Title 1</col2>
    </section>
    <section>
        <col1>Year</col1>
        <col2>2011</col2>
    </section>

    <section />

    <section>
        <col1>*****</col1>
        <col2>Document 2</col2>
    </section>
    <section>
        <col1>Title</col1>
        <col2>Title 2</col2>
    </section>
    <section>
        <col1>Year</col1>
        <col2>2012</col2>
    </section>

    <section />

    <section>
        <col1>*****</col1>
        <col2>Document 3</col2>
    </section>
    <section>
        <col1>Title</col1>
        <col2>Title 3</col2>
    </section>
    <section>
        <col1>Year</col1>
        <col2>2013</col2>
    </section>

    <section />

    ...

</print>

ご覧のとおり、すべての新しい「ドキュメント」は<col1>*****</col1>最初の<section></section>タグで始まり、空のタグで終わります（より具体的には、その後に続きます）<section />。

私がやりたいのは、各<col2>値を取り出してラッピングタグに入れることです。したがって、最終的に、ドキュメントの個別のデータセットを取得する必要があります。結果は次のようになります。

<print>

    <document>
        <docno>Document 1</docno>
        <title>Title 1</title>
        <year>2011</year> 
    </document>

    <document>
        <docno>Document 2</docno>
        <title>Title 2</title>
        <year>2012</year> 
    </document>

    <document>
        <docno>Document 3</docno>
        <title>Title 3</title>
        <year>2013</year> 
    </document>

</print>

したがって、すべての<col2>値を取得し、それらを新しい要素に入れて、<document>タグでラップする必要があります。次のXSLTで試してみましたが、部分的に成功しました（<col2>値を取得できます）が、<xsl:when>タグ内（値をラップしようとしています）では、タグがすぐに閉じられない<col2>ため、エラーがスローされます。<document>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" indent="yes"/>


    <xsl:template name="content">

        <xsl:if test="col1='*****'">
            <xsl:element name="docno">
                <xsl:value-of select="col2"/>   
            </xsl:element>
        </xsl:if>
        <xsl:if test="col1='Title'">
            <xsl:element name="title">
                <xsl:value-of select="col2"/>
            </xsl:element>
        </xsl:if>
        <xsl:if test="col1='Year'">
            <xsl:element name="year">
                <xsl:value-of select="col2"/>
            </xsl:element>
        </xsl:if>

    </xsl:template>


    <xsl:template  match="/">

        <xsl:element name="print">

        <xsl:for-each select="print/section">
            <xsl:choose>
                <xsl:when test="col1='*****'">
                    <xsl:element name="document">
                </xsl:when>
                <xsl:when test="not(col1/node())">
                    </xsl:element>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:call-template name="content"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each>

        </xsl:element>

    </xsl:template>
</xsl:stylesheet>

XSLTでは、条件付きでタグを開いたり閉じたりすることは不可能であることがわかりましたが、目標を達成するための別の解決策があると確信しています...私はそれを見つけるのにあまり経験がありません。誰かが私を正しい方向に向けることができますか？事前にどうもありがとうございました！

4

2 に答える 2

1

特にXSLT2.0を使用できる場合は、これを行うためのより洗練された方法がありますが<section>、すべての空の<section/>要素の間に3つの要素があることがわかっている場合は、次のような単純な方法を実行できます（XSLT 1.0互換）。

スタイルシート

<?xml version="1.0"?>

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="print">
    <xsl:copy>
      <!--
      Only apply the first <section> child of <print> and those <section> children
      whose first preceding <section> sibling is an empty <section/> element
      -->
      <xsl:apply-templates select="section[position() = 1
        or preceding-sibling::section[1][not(node())]]"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="section">
    <document>
      <!--
      Transform the <col2> child of this <section> into a <docno> elemen
      -->
      <xsl:apply-templates select="col2" mode="number"/>
      <!--
      Transform the <col2> element of the first following <section> sibling into
      a <title> element
      -->
      <xsl:apply-templates select="following-sibling::section[1]/col2" mode="title"/>
      <xsl:apply-templates select="following-sibling::section[2]/col2" mode="year"/>
    </document>
  </xsl:template>

  <xsl:template match="col2" mode="number">
    <docno>
      <xsl:value-of select="."/>
    </docno>
  </xsl:template>

  <xsl:template match="col2" mode="title">
    <title>
      <xsl:value-of select="."/>
    </title>
  </xsl:template>

  <xsl:template match="col2" mode="year">
    <year>
      <xsl:value-of select="."/>
    </year>
  </xsl:template>
</xsl:stylesheet>
于 2013-02-27T14:47:10.103 に答える
1

使用（XSLT 2.0の場合）

<xsl:template match="print">
  <xsl:for-each-group select="section" 
          group-starting-with="section[starts-with(col2, 'Document')]">   
   <document>
     <docno><xsl:value-of select="current-group()[1]/col2"/>
     ... etc ...
   </document>
  </xsl:for-each-group>
</xsl:template>
于 2013-02-27T16:57:08.620 に答える